Emacs hl-line: изменить цвет локально

Обычно я позволяю hl-line немного темнее текущего фона. Это хорошо работает при редактировании буферов. Однако в некоторых буферах, таких как повестка дня организации и групповой буфер Gnus, я хотел бы использовать более элегантный цвет (вместо курсора).

Чтобы быть конкретным, я хотел бы изменить цвет строки hl в строке gnus-hl, не затрагивая цвет строки hl в других буферах.

(add-hook 'gnus-summary-mode-hook 'gnus-hl-line)
(add-hook 'gnus-group-mode-hook 'gnus-hl-line)

(defun gnus-hl-line ()
  (hl-line-mode 1)
  (set (make-local-variable 'line-move-visual) nil)
  (setq cursor-type nil))

Спасибо,

Окончательное решение с использованием предложения Фила. В большинстве случаев он использует нейтральную линию hl, но иногда заметна жирная линия hl, например. в повестке дня Gnus и Org

;; From emacs-wiki:
(defun shade-color (intensity)
  "print the #rgb color of the background, dimmed according to intensity"
  (interactive "nIntensity of the shade : ")
  (apply 'format "#%02x%02x%02x"
         (mapcar (lambda (x)
                   (if (> (lsh x -8) intensity)
                       (- (lsh x -8) intensity)
                     0))
                 (color-values (cdr (assoc 'background-color (frame-parameters)))))))

;; Default hl
(global-hl-line-mode t)
(make-variable-buffer-local 'global-hl-line-mode)
(set-face-background hl-line-face (shade-color 08))  

(defface hl-line-highlight-face
  '((t :inherit highlight))
  "Face for highlighting the current line with `hl-line-fancy-highlight'."
  :group 'hl-line)

(defun hl-line-fancy-highlight ()
  (set (make-local-variable 'hl-line-face) 'hl-line-highlight-face)
  ;;    (set (make-local-variable 'line-move-visual) nil)
  ;;    (set (make-local-variable 'cursor-type) nil)
  (setq global-hl-line-mode nil)
  (hl-line-mode))

(add-hook 'org-agenda-mode-hook 'hl-line-fancy-highlight)
(add-hook 'gnus-summary-mode-hook 'hl-line-fancy-highlight)
(add-hook 'gnus-group-mode-hook 'hl-line-fancy-highlight)

line cursor emacs
person Rasmus    schedule 20.04.2012    source источник
comment
Не могли бы вы объяснить, где в коде можно установить интенсивность и цвет для org-agenda, gnus-summary и gnus-group соответственно? Спасибо!   -  person Alexander Shcheblikin    schedule 28.06.2016

Ответы (1)


arrow_upward
5
arrow_downward

hl-line-face — это переменная, содержащая лицо, используемое для hl-line-mode, поэтому мы можем сделать эту переменную локальной в буфере в этих режимах и назначить ей новое пользовательское лицо.

Вы можете создать новое лицо следующим образом:

(defface gnus-hl-line
  '((t :inherit hl-line))
  "Face for highlighting the current line with `gnus-hl-line'."
  :group 'hl-line)

и настройте его с помощью M-x customize-face RET gnus-hl-line RET

Затем добавьте это в свою функцию gnus-hl-line (перед вызовом hl-line-mode было бы наиболее разумно).

(set (make-local-variable 'hl-line-face) 'gnus-hl-line)
person phils    schedule 20.04.2012