Как добавить многочлены в Prolog?

Несколько замечаний:

Старайтесь избегать дизъюнкций (;)/2 в начале. Они нуждаются в специальном отступе, чтобы быть читаемыми. И они усложняют чтение одного правила, подумайте обо всех дополнительных (=)/2 целях, которые вам нужно написать и отслеживать.

Тогда я не уверен, что вы можете предположить о своих полиномах. Можете ли вы предположить, что они написаны в канонической форме?

И для вашей программы: рассмотрите заголовок вашего первого правила:

add_poly(+A1*x^B1+P1,+A2*x^B2+P2,+A3*x^B3+P3):-

Я обобщу некоторые аргументы:

add_poly(+A1*x^B1+P1,_,_):-

и некоторые подтермины:

 add_poly(+_+_,_,_):-

Это соответствует:

add_poly(+(+(_),_),_,_) :-

Не уверен, что тебе это нравится.

Таким образом, это правило применяется только к терминам, начинающимся с префикса +, за которым следует инфикс +. По крайней мере, в ваших примерных данных не было префикса +.

Также обратите внимание, что +-оператор левоассоциативен. Это означает, что 1+2+3+4 ассоциируется слева:

?- write_canonical(1+2+3+4).
+(+(+(1,2),3),4)

Итак, если у вас есть термин 0+3*x^3+2*x^4, первое, что вы «видите», это _+2*x^4. Термины слева вложены глубже.

Для вашего фактического вопроса (как остановиться) - вам нужно будет явно проверить, что крайний левый подтермин является целым числом, используйте integer/1 - или, возможно, термин (*)/2 (это зависит от ваших предположений).

Я предполагаю, что полиномы, о которых вы говорите, находятся в 1 переменной и с целыми показателями.

Здесь процедура работает с нормальной полиномиальной формой: полином может быть представлен в виде списка (суммы) факторов, где (целочисленный) показатель степени неявно представлен позицией.

:- [library(clpfd)].

add_poly(P1, P2, Sum) :-
    normalize(P1, N1),
    normalize(P2, N2),
    append(N1, N2, Nt),
    aggregate_all(max(L), (member(M, Nt), length(M, L)), LMax),
    maplist(rpad(LMax), Nt, Nn),
    clpfd:transpose(Nn, Tn),
    maplist(sumlist, Tn, NSum),
    denormalize(NSum, Sum).

rpad(LMax, List, ListN) :-
    length(List, L),
    D is LMax - L,
    zeros(D, Z),
    append(List, Z, ListN).

% the hardest part is of course normalization: here a draft

normalize(Ts + T, [N|Ns]) :-
    normalize_fact(T, N),
    normalize(Ts, Ns).
normalize(T, [N]) :-
    normalize_fact(T, N).

% build a list with 0s left before position E
normalize_fact(T, Normal) :-
    fact_exp(T, F, E),
    zeros(E, Zeros),
    nth0(E, Normal, F, Zeros).

zeros(E, Zeros) :-
    length(Zeros, E),
    maplist(copy_term(0), Zeros).

fact_exp(F * x ^ E, F, E).
fact_exp(x ^ E, 1, E).
fact_exp(F * x, F, 1).
fact_exp(F, F, 0).

% TBD...
denormalize(NSum, NSum).

контрольная работа:

?- add_poly(0+2*x^3, 0+1*x^3+2*x^4, P).
P = [0, 0, 0, 3, 2]

ответ все еще в нормальной форме, нужно написать denormalize/2...