Создайте атрибут xmlns в XML с помощью преобразования XSLT

Во-первых, в модели данных XSLT вы не хотите создавать узел атрибута, вы хотите создать узел пространства имен.

Узлы пространства имен обычно создаются автоматически: если вы создаете элемент или атрибут в определенном пространстве имен, требуемый узел пространства имен (и, следовательно, при сериализации, объявление пространства имен) автоматически добавляется процессором.

Если вы хотите создать узел пространства имен, в котором нет необходимости (потому что он не используется в имени какого-либо элемента или атрибута), тогда в XSLT 2.0 вы можете использовать пространство имен xsl :. Если вы застряли с XSLT 1.0, есть обходной путь, который включает в себя создание элемента в соответствующем пространстве имен и последующее копирование его узла пространства имен:

<xsl:variable name="ns">
  <xsl:element name="neil:dummy" namespace="{$param}"/>
</xsl:variable>
<process>
  <xsl:copy-of select="$ns/*/namespace::neil"/>
</process>

Майкл Кей дал вам правильный ответ, но, судя по вашим комментариям, вы не знаете, как использовать его в своей трансформации.

Вот полное преобразование:

 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common" exclude-result-prefixes="ext">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:param name="pNamespace" select="'neilghosh.com'"/>

 <xsl:variable name="vDummy">
   <xsl:element name="neil:x" namespace="{$pNamespace}"/>
 </xsl:variable>

 <xsl:template match="/*">
  <xsl:element name="process" namespace="http://example.com">
    <xsl:copy-of select="namespace::*"/>
    <xsl:copy-of select="ext:node-set($vDummy)/*/namespace::*[.=$pNamespace]"/>
  </xsl:element>
 </xsl:template>
 </xsl:stylesheet>

Когда это преобразование применяется к предоставленному XML-документу:

<test/>

Получен желаемый правильный результат:

<process xmlns="http://example.com" xmlns:neil="neilghosh.com" />

Объявления пространств имен в XML не являются атрибутами, даже если они выглядят как атрибуты. В XSLT 2.0 вы можете использовать <xsl:namespace name="neil" select="$myNameSpace" /> для динамического добавления объявления пространства имен в результирующее дерево, но эта функция недоступна в XSLT 1.0.

Не пытайтесь самостоятельно создавать атрибуты xmlns. Создайте пространства имен в XSLT, и они будут выполнены автоматически. Этот XSLT работает (протестирован с Saxon 9.4):

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:neil="neilghosh.com"    
xpath-default-namespace="http://example.com"
xmlns="http://example.com" version="2.0">

<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:param name="myDynamicNamespace" select="'http://neilghosh.com'"/>

<xsl:template match="/">
    <xsl:element name="process">   
        <xsl:namespace name="neil" select="$myDynamicNamespace"/>
    </xsl:element>
</xsl:template>
</xsl:stylesheet>

И дает следующий результат:

<?xml version="1.0" encoding="UTF-8"?>
<process xmlns="http://example.com" xmlns:neil="http://neilghosh.com"/>

Наконец-то получил обходной путь, который работал с моим XSLT-процессором (Oracle XML V2 Parser)

Мне пришлось преобразовать его в документ DOM, а затем сохранить этот DOM в файловая система вместо вывода непосредственно в StreamResult

Я использовал DOMResult в метод преобразования

Следующий фрагмент XSLT работал, но был дополнительный xmlns: xmlns = "http://www.w3.org/2000/xmlns/", который, вероятно, был поглощен Document и не отображался в окончательном выводе, когда я сохранял файловую систему.

 <process>    
      <xsl:attribute name="xmlns">
        <xsl:value-of select="'http://example.com'"/>
      </xsl:attribute> 
 <process>

Я знаю, что это не лучший способ сделать это, но с учетом ограничений синтаксического анализа это единственный выбор, который у меня сейчас есть.