Что в Perl означает if (s/^\+//)?

Они оба являются регулярными выражениями. Вы можете прочитать о них на страницах perlre и perlretut. Вы можете поиграть с ними на http://www.rubular.com/r/CEtqZ3YUIi.

Они оба неявно что-то делают с $_. Вероятно, вокруг ваших строк кода без переменной цикла есть while или foreach. В этом случае $_ становится этой переменной цикла. Например, он может содержать текущую строку файла, который читается.

1. Если текущее значение $_ содержит знак + (плюс) в качестве первого символа в начале строки, #do somehting.
2. В противном случае, если он содержит знак - (минус), #do another thing.

В случае 1. он также заменяет этот знак + ничем (т.е. удаляет его). Однако он не удаляет - в 2..

Давайте посмотрим на объяснение с помощью YAPE::Regex::Explain.

use YAPE::Regex::Explain;
print YAPE::Regex::Explain->new(qr/^\+/)->explain();

Вот. Не очень полезный в нашем случае, но, тем не менее, хороший инструмент. Обратите внимание, что части (?-imsx и ) — это то, что подразумевает Perl по умолчанию. Они всегда там, если вы не измените их.

The regular expression:

(?-imsx:^\+)

matches as follows:

NODE                     EXPLANATION
----------------------------------------------------------------------
(?-imsx:                 group, but do not capture (case-sensitive)
                         (with ^ and $ matching normally) (with . not
                         matching \n) (matching whitespace and #
                         normally):
----------------------------------------------------------------------
  ^                        the beginning of the string
----------------------------------------------------------------------
  \+                       '+'
----------------------------------------------------------------------
)                        end of grouping
----------------------------------------------------------------------

Обновление: как отметил Микко Л. в комментариях, вам, возможно, следует реорганизовать/изменить этот фрагмент кода. Хотя он, вероятно, делает то, что должен, я считаю, что было бы неплохо сделать его более читабельным. Тот, кто написал это, очевидно, не заботился о вас как о более позднем сопровождающем. Я предлагаю вам это сделать. Вы можете изменить его на:

# look at the content of $_ (current line?)
if ( s/^\+// )
{
  # the line starts with a + sign,
  # which we remove!

  #do something
}
elsif ( m/^-/ )
{
  # the line starts witha - sign
  # we do NOT remove the - sign!

   #do another thing
}

Это регулярные выражения, используемые для сопоставления с образцом и замены.

Вы должны прочитать концепцию, но что касается вашего вопроса:

s/^\+//

Если строка начинается с плюса, удалите этот плюс ("s" означает "заменить") и верните true.

/^-/

Истинно, если строка начинается с минуса.

Этот код эквивалентен

if ($_ =~ s/^\+//) {  # s/// modifies $_ by default
   #do something
}
elsif ($_ =~ m/^-/) {  # m// searches $_ by default
   #do another thing
}

s/// и m// являются операторами, подобными кавычкам регулярных выражений. Вы можете прочитать о них в perlop.

Другие ответы дали краткое описание того, как работает код, но не так много, почему. Вот простой пример того, почему можно использовать такую ​​логику.

#!/usr/bin/env perl

use strict;
use warnings;

my $args = {};

for ( @ARGV ) {
  if ( s/^no// ) {
    $args->{$_} = 0;
  } else {
    $args->{$_} = 1;
  }
}

use Data::Dumper;
print Dumper $args;

Когда вы вызываете скрипт, например

./test.pl hi nobye

Вы получаете

$VAR1 = {
          'hi' => 1,
          'bye' => 0
        };

Ключ представляет собой строку, однако, если ему предшествует no, удалите его (чтобы получить рассматриваемый ключ) и вместо этого установите значение 0.

Пример OP немного сложнее, но следует той же логике.

• если ключ начинается с +, удалите его и сделайте что-нибудь
• если ключ начинается с -, не удаляйте его и сделайте что-нибудь еще