Delphi WebBroker/ISAPI против многопоточности

Я пытаюсь немного поработать после ответа продюсера.

Чтобы не удерживать ответы по времени, я пытаюсь выполнить эту работу в потоке.

Этот поток создает DataModule и выполняет определенные действия (отправляет электронные письма, обрабатывает операции с файлами и т. д.), но выполнение блокирует основной поток.

Я не использую переменные или любые другие взаимодействия с основным потоком. Я не вижу ничего, что может выдавать блоки.

Кто-нибудь может помочь?

Код темы:

unit wdm_Thread;  

interface

uses
    System.SysUtils, System.Classes, Web.HTTPApp, Web.HTTPProd, Web.DSProd,Data.DB, Data.Win.ADODB;

type
    TwdmThread = class(TDataModule)  
        dbConnection: TADOConnection;  
        spVisualizador: TADOStoredProc;  
        spVisualizadorProc: TADOStoredProc;  
        spVisualizadorProcFim: TADOStoredProc;  
        spVisualizadorProcInicio: TADOStoredProc;  
        ppVisualizadorOn: TDataSetPageProducer;  
        spVisualizadorMiniProc: TADOStoredProc;  
    end;  

    colaboreThread = class(TThread)  
    private  
        FDataModule: TwdmThread;  
        FPreviewPath: String;  
        FSessionID: String;  
        FUniqueID: String;  
        FUniqueIDVersao: String;  
    public  
        procedure Execute(); override;  
        class procedure Thumbnail(APreviewPath, ASessionID, AUniqueID, AUniqueIDVersao: String);  
    end;   

implementation  

uses  
    WinAPI.Windows, WinAPI.ActiveX;  

{%CLASSGROUP 'System.Classes.TPersistent'}  

{$R *.dfm}  

{ threadThumbnail }  

procedure colaboreThread.Execute;  
begin  
    try  
        FDataModule := TwdmThread.Create(nil);  
        with FDataModule do  
        begin  
            spVisualizador.Parameters[1].Value := FSessionID;  
            spVisualizador.Parameters[2].Value := FUniqueID;  
            spVisualizador.Parameters[3].Value := FUniqueIDVersao;  
            spVisualizador.Parameters[4].Value := False;  
            spVisualizador.Open();  

            if spVisualizador.RecordCount > 0 then  
            try  
                DeleteFile(PWideChar(FPreviewPath + FUniqueIDVersao + spVisualizador.FieldByName('Extensao').AsString));  

                CopyFile(PWideChar(spVisualizador.FieldByName('ArmazenamentoCaminho').AsString + FUniqueIDVersao), PWideChar(FPreviewPath + FUniqueIDVersao + spVisualizador.FieldByName('Extensao').AsString), true);  

                spVisualizadorMiniProc.Parameters[1].Value := FSessionID;  
                spVisualizadorMiniProc.Parameters[2].Value := FUniqueID;  
                spVisualizadorMiniProc.Parameters[3].Value := FUniqueIDVersao;  
                spVisualizadorMiniProc.Parameters[4].Value := FPreviewPath;  
                spVisualizadorMiniProc.ExecProc();  
            finally  
                DeleteFile(PWideChar(FPreviewPath + FUniqueIDVersao + spVisualizador.FieldByName('Extensao').AsString));  
        end  
    end;  
  finally  
    FreeAndNil(FDataModule);  
  end;  

end;  

class procedure colaboreThread.Thumbnail(APreviewPath, ASessionID, AUniqueID, AUniqueIDVersao: String);  
begin  
  with colaboreThread.Create(True) do  
  begin  
    FreeOnTerminate := True;  
    FPreviewPath := APreviewPath;  
    FSessionID := ASessionID;  
    FUniqueID := AUniqueID;  
    FUniqueIDVersao := FUniqueIDVersao;  
    if FUniqueIDVersao = '' then FUniqueIDVersao := FUniqueID;  

    Execute();  
  end;  
end;  

initialization  
  CoInitializeEx(NIL, COINIT_MULTITHREADED or COINIT_SPEED_OVER_MEMORY);  

end.

Реализация WebModule:

...

procedure TwdmColaboreUP.wdmTopWebUploadwaiUploadAction(Sender: TObject;
  Request: TWebRequest; Response: TWebResponse; var Handled: Boolean);  
begin  
  colaboreThread.Thumbnail(FPreviewPath, FSessionID, FArquivoUniqueID, FArquivoUniqueIDVersao);  
end;  

...

multithreading delphi blocking isapi webbroker
person adam9k    schedule 23.11.2012    source источник
comment
Как мы можем угадать без надлежащего объяснения или кода?   -  person jachguate    schedule 23.11.2012
comment
Спасибо за внимание. Я не ставлю коды на первое место, но я сделал это сейчас.   -  person adam9k    schedule 23.11.2012

Ответы (1)


arrow_upward
3
arrow_downward

Вы вызываете Execute в потоке, но не должны вызывать его напрямую. Вы запускаете поток, используя Resume (или опуская параметр Suspended в его конструкторе). Затем в фоновом режиме будет запущен метод Execute.

Если вы запускаете Execute самостоятельно, как сейчас, он запускается в основном потоке, как и любой другой метод.

  with colaboreThread.Create(True) do  
  begin  
    FreeOnTerminate := True;  
    FPreviewPath := APreviewPath;  
    FSessionID := ASessionID;  
    FUniqueID := AUniqueID;  
    FUniqueIDVersao := FUniqueIDVersao;  
    if FUniqueIDVersao = '' then FUniqueIDVersao := FUniqueID;  

    // Execute();  <--- Not this

    Resume; // <--- but this
  end;
person GolezTrol    schedule 23.11.2012
comment
Теперь работает идеально... Большое спасибо! - person adam9k; 23.11.2012