Динамическое изменение заголовка SiteMapNode

У нас есть веб-сайт, который использует стандартную карту сайта по умолчанию с обрезкой безопасности следующим образом:

<siteMap defaultProvider="default" enabled="true">
  <providers>
    <add siteMapFile="~/Web.sitemap" securityTrimmingEnabled="true" name="default" type="System.Web.XmlSiteMapProvider, System.Web, Version=2.0.0.0, Culture=neutral, PublicKeyToken=b03f5f7f11d50a3a" />
  </providers>
</siteMap>

Все очень хорошо, но пришел запрос на изменение Title одного узла на основе некоторых внутренних критериев. Казалось бы, простая вещь, но, видимо, нет.

Попытка 1 – обработка события SiteMapResolve. Кажется, не имеет значения, где обрабатывается это событие, я показал его в Global.asax просто потому, что это было одно из мест, где я его пробовал, и оно сработало.

Public Class Global_asax
    Inherits System.Web.HttpApplication

    Sub Application_BeginRequest(ByVal sender As Object, ByVal e As EventArgs)
        AddHandler SiteMap.SiteMapResolve, AddressOf SiteMapResolve
    End Sub

    Sub Application_EndRequest(ByVal sender As Object, ByVal e As EventArgs)
        RemoveHandler SiteMap.SiteMapResolve, AddressOf SiteMapResolve
    End Sub

    Private Shared Function SiteMapResolve(ByVal sender As Object, ByVal e As SiteMapResolveEventArgs) As SiteMapNode

        Dim node As SiteMapNode = SiteMap.CurrentNode
        If IsThisTheNodeToChange(node) Then
            node = node.Clone()
            node.Title = GetNodeTitle()
        End If
        Return node

    End Function

End Class

Это работало нормально при переходе на соответствующую страницу, но, к сожалению, часть навигации по сайту включает поле со списком, данные которого привязаны к карте сайта, например:

<asp:SiteMapDataSource ID="siteMapDataSource" runat="Server" ShowStartingNode="false" StartFromCurrentNode="false" StartingNodeOffset="1" />
<asp:DropDownList ID="pageMenu" runat="Server" AutoPostBack="True" DataSourceID="siteMapDataSource" DataTextField="Title" DataValueField="Url" />

При отображении этого меню событие SiteMapResolve не срабатывает ни для какого содержимого, поскольку текущим узлом является страница, на которой определено меню. В результате в меню отображается бессмысленный заголовок из физического файла карты сайта, а не правильный заголовок.

Попытка 2. Написание собственного поставщика карты сайта. Я не хотел дублировать все поведение по умолчанию, поэтому я попытался получить от поставщика по умолчанию следующим образом.

Public Class DynamicXmlSiteMapProvider
    Inherits XmlSiteMapProvider

    Private _dataFixedUp As Boolean = False

    Public Overrides Function GetChildNodes(ByVal node As SiteMapNode) As SiteMapNodeCollection

        Dim result As SiteMapNodeCollection = MyBase.GetChildNodes(node)
        If Not _dataFixedUp Then
            For Each childNode As SiteMapNode In result
                FixUpNode(childNode)
            Next
        End If
        Return result

    End Function

    Private Sub FixUpNode(ByVal node As SiteMapNode)

        If IsThisTheNodeToChange(node) Then
            node.ReadOnly = False
            node.Title = GetNodeTitle()
            node.ReadOnly = True
            _dataFixedUp = True
        End If

    End Sub

End Class

Это не работает, потому что GetChildNodes не вызывается очень часто при навигации по сайту.

Попытка 3. Попробуйте исправить данные сразу после их загрузки в память, а не при доступе к ним.

Public Class DynamicXmlSiteMapProvider
    Inherits XmlSiteMapProvider

    Private _dataFixInProgress As Boolean = False
    Private _dataFixDone As Boolean = False

    Public Overrides Function BuildSiteMap() As SiteMapNode

        Dim result As SiteMapNode = MyBase.BuildSiteMap()
        If Not _dataFixInProgress AndAlso Not _dataFixDone Then
            _dataFixInProgress = True
            For Each childNode As SiteMapNode In result.GetAllNodes()
                FixUpNode(childNode)
            Next
            _dataFixInProgress = False
            _dataFixDone = True
        End If
        Return result

    End Function

    Private Sub FixUpNode(ByVal node As SiteMapNode)

        If IsThisTheNodeToChange(node) Then
            node.ReadOnly = False
            node.Title = GetNodeTitle()
            node.ReadOnly = True
        End If

    End Sub

End Class

Кажется, это работает. Однако меня беспокоит вызов GetAllNodes в методе BuildSiteMap. Мне просто кажется неправильным рекурсивно извлекать все данные в память только для того, чтобы исправить одно значение. Кроме того, я не могу контролировать, когда вызывается BuildSiteMap. Я бы предпочел что-то более похожее на Попытку 1, которая вызывается по требованию, когда данные узла впервые требуются.

Попытка 4 (НОВАЯ) – аналогична попытке 2, но переопределяет все виртуальные элементы, связанные с чтением данных (CurrentNode, FindSiteMapNode, FindSiteMapNodeFromKey, GetChildNodes, GetCurrentNodeAndHintAncestorNodes, GetCurrentNodeAndHintNeighborhoodNodes, GetParentNode , GetParentNodeRelativeToCurrentNodeAndHintDownFromParent, GetParentNodeRelativeToNodeAndHintDownFromParent, HintAncestorNodes, HintNeighborhoodNodes), чтобы попытаться где-то перехватить чтение динамического узла.

Это не сработало. Я помещаю операторы отладки во все переопределенные члены, и кажется, что ни один из них вообще не вызывается при привязке данных к раскрывающемуся списку. Единственное объяснение, которое я могу придумать, это то, что все узлы считываются в память за один раз во время вызова BuildSiteMap, так что SiteMapNode не попадает в класс провайдера при перечислении дочерних узлов.

У кого-нибудь есть лучшие предложения?