Мое решение основано на Rafael, поскольку оно копирует зависимости в каталог libs, который используется только Android. Однако я иду дальше, чтобы полностью разобрать упомянутые AAR для использования в Eclipse.

Файл сборки Gradle

Добавьте следующее в конец вашего Android-проекта build.gradle :

task copyJarDependencies(type: Copy) {
    description = 'Used for Eclipse. Copies all dependencies to the libs directory. If there are any AAR files it will extract the classes.jar and rename it the same as the AAR file but with a .jar on the end.'
    libDir = new File(project.projectDir, '/libs')
    println libDir
    println 'Adding dependencies from compile configuration'
    configurations.compile.filter {it.name.endsWith 'jar'}.each { File file -> moveJarIntoLibs(file)}
    println 'Adding dependencies from releaseCompile configuration'
    configurations.releaseCompile.filter {it.name.endsWith 'jar'}.each { File file -> moveJarIntoLibs(file)}
    println 'Adding dependencies from debugCompile configuration'
    configurations.debugCompile.filter {it.name.endsWith 'jar'}.each { File file -> moveJarIntoLibs(file)}
    println 'Adding dependencies from instrumentTestCompile configuration'
    configurations.instrumentTestCompile.filter {it.name.endsWith 'jar'}.each { File file -> moveJarIntoLibs(file)}
    println 'Extracting dependencies from compile configuration'
    configurations.compile.filter {it.name.endsWith 'aar'}.each { File file -> moveAndRenameAar(file) }
    println 'Extracting dependencies from releaseCompile configuration'
    configurations.releaseCompile.filter {it.name.endsWith 'aar'}.each { File file -> moveAndRenameAar(file) }
    println 'Extracting dependencies from debugCompile configuration'
    configurations.debugCompile.filter {it.name.endsWith 'aar'}.each { File file -> moveAndRenameAar(file) }
    println 'Extracting AAR dependencies from instrumentTestCompile configuration'
    configurations.instrumentTestCompile.filter {it.name.endsWith 'aar'}.each { File file -> moveAndRenameAar(file) }
}

void moveJarIntoLibs(File file){
    println 'Added jar ' + file
        copy{
            from file
            into 'libs'
        }
}

void moveAndRenameAar(File file){
    println 'Added aar ' + file
    def baseFilename = file.name.lastIndexOf('.').with {it != -1 ? file.name[0..<it] : file.name}

    // directory excluding the classes.jar
    copy{
        from zipTree(file)
        exclude 'classes.jar'
        into 'libs/'+baseFilename
    }

    // Copies the classes.jar into the libs directory of the expoded AAR.
    // In Eclipse you can then import this exploded ar as an Android project
    // and then reference not only the classes but also the android resources :D 
    copy{
        from zipTree(file)
        include 'classes.jar'
        into 'libs/' + baseFilename +'/libs'
        rename { String fileName ->
            fileName.replace('classes.jar', baseFilename + '.jar')
        }
    }
}

Создание с помощью Gradle

Бегать :

"gradle clean build"

Вы должны найти все зависимости и развернутые файлы AAR в каталоге libs. Это все, что нужно Eclipse.

Импорт в Eclipse

Вот тут-то и начинается настоящая польза. После того, как вы создали каталог libs на шаге gradle выше, вы заметите, что там тоже есть папки. Эти новые папки представляют собой развернутые зависимости AAR из вашего файла build.gradle.

Теперь самое интересное заключается в том, что когда вы импортируете свой существующий проект Android в Eclipse, он также обнаружит взорванные папки AAR как проекты, которые он также может импортировать!

1. Импортируйте эти папки в каталог libs вашего проекта, не импортируйте папки сборки, они создаются Gradle

2. Убедитесь, что вы выполнили Проект -> Очистить для всех добавленных вами проектов AAR. В рабочей области убедитесь, что каждый разнесенный проект AAR имеет следующее в project.properties:

target=android-<YOUR INSTALLED SKD VERSION GOES HERE>
android.library=true

3. Теперь в свой основной проект Android вы можете просто добавить ссылки на библиотеки с помощью ADT или просто отредактировать файл project.properties и добавить

android.libraries.reference.1=libs/someExplodedAAR/

4. Теперь вы можете щелкнуть правой кнопкой мыши основной проект Android и выбрать Запустить от имени -> Приложение Android.

Но что это вообще значит?

1. Ну, это означает, что вам не нужен исходный код для любой из ваших зависимостей Android AAR Gradle, чтобы ссылаться как на его классы, так и на ресурсы в Eclipse.

2. Приведенный выше скрипт сборки gradle берет файл AAR и подготавливает его для использования в Eclipse. Как только вы добавите его в свое рабочее пространство, вы готовы просто сосредоточиться на своем основном проекте Android.

3. Теперь вы можете отлаживать и разрабатывать с помощью Eclipse и развертывать с помощью ADT с зависимостями AAR, которые должным образом объединены в APK. Когда вам нужно сделать некоторые конкретные сборки, вы можете использовать gradle.

Наконец я нашел решение, которое работает для меня. Эта задача копирует зависимости в папку проектов libs.

task copyDependencies(type: Copy) 
{
    description = 'Copy depencies to libs. Useful for Eclipse'
    libDir = new File(project.projectDir, '/libs')
    println libDir
    println 'Adding dependencies from compile configuration'
    for(file in configurations.compile) 
    {
        println 'Added ' + file
        copy 
        {
            from file
            into libDir
        }
    }
    println 'Adding dependencies from releaseCompile configuration'
    for(file in configurations.releaseCompile)
    {
        println 'Added ' + file
        copy
        {
            from file
            into libDir
        }
    }
    println 'Adding dependencies from debugCompile configuration'
    for(file in configurations.debugCompile)
    {
        println 'Added ' + file
        copy
        {
            from file
            into libDir
        }
    }

    println 'Adding dependencies from instrumentTestCompile configuration'
    for(file in configurations.instrumentTestCompile)
    {
        println 'Added ' + file
        copy
        {
            from file
            into libDir
        }
    }
}

Следующая задача Gradle просто объединяет зависимости Gradle в путь к классам eclipse. Добавьте его в build.gradle и вызовите с помощью gradle gradleDep2EclipseClasspath.

  import groovy.xml.StreamingMarkupBuilder
  task gradleDep2EclipseClasspath() {
     description "Merge gradle dependencies into the eclipse class path"

     def files = ["compile", "releaseCompile", "debugCompile", "instrumentTestCompile"]
       .collect {project.configurations[it].files}
       .inject([] as Set) {result, files -> result + files}
       .asList()
       .unique()
       .grep {! [email protected]().contains("android-support")}

      def classpath = new XmlParser().parse(file(".classpath"))
      def libs = classpath.grep {it.'@gradle-dependency' == "true"}
      libs.each {classpath.remove(it)}

      files.collect {file ->
         new Node(null, "classpathentry", [
           "path": file.toString(),
           "kind": "lib",
           "exported": "true",
           "gradle-dependency": "true"
         ])
      }.each {classpath.append(it)}

      file(".classpath").withWriter {writer ->
         writer << new StreamingMarkupBuilder().bind { mkp.xmlDeclaration() }
         def printer = new XmlNodePrinter(new PrintWriter(writer))
         printer.print(classpath)
      }
   }

Благодаря решению JavaJedi я создал еще один, используя аннотации ввода/вывода Gradle. Он основан на тех же принципах, но более универсален в использовании (например, вы можете легко определить новые задачи типа CopyJars или ExtractAars) и позволяет Gradle решать, нужно ли копирование файлов или нет.

Вот мое решение, основанное на всех предыдущих решениях от @JavaJedi и @gubaer.

Шаг 1

Добавьте задачу copyAars в build.gradle. Он распаковывает и копирует зависимости AAR в специальную папку «deps», а не в «libs», чтобы избежать конфликтов с Android Studio и/или другими плагинами и задачами Gradle. После этого все разнесенные AAR должны быть вручную импортированы как проекты библиотеки Android и добавлены в качестве зависимостей к основному проекту в Eclipse. Это модифицированное решение от @JavaJedi.

task copyAars << {
    configurations.compile.filter { it.name.endsWith 'aar' }.each { File file -> copyAndRenameAar(file) }
}

void copyAndRenameAar(File file) {
    println 'Added aar ' + file
    def baseFilename = file.name.lastIndexOf('.').with { it != -1 ? file.name[0..<it] : file.name }

    // directory excluding the classes.jar
    copy {
        from zipTree(file)
        exclude 'classes.jar'
        into "deps/aars/exploded/" + baseFilename
    }

    // Copies the classes.jar into the libs directory of the expoded AAR.
    // In Eclipse you can then import this exploded aar as an Android project
    // and then reference not only the classes but also the android resources
    copy {
        from zipTree(file)
        include 'classes.jar'
        into "deps/aars/exploded/" + baseFilename + "/libs"
        rename { String fileName -> fileName.replace('classes.jar', baseFilename + '.jar') }
    }
}

Шаг 2

Добавьте задачу eclipseClasspath в build.gradle. Зависимости JAR добавляются другим способом. Они фильтруются и добавляются непосредственно в файл .classpath, поэтому автоматически становятся доступными в основном проекте Eclipse. Это модифицированное решение от @gubaer. Он включает только JAR-файлы, исключая AAR-файлы и только из «компилируемой» конфигурации, но вы можете легко добавить больше конфигураций.

task eclipseClasspath << {
    def classpath = new XmlParser().parse(file(".classpath"))
    def libs = classpath.grep { it.'@gradle-dependency' == "true" }
    libs.each { classpath.remove(it) }

    configurations.compile.filter { it.name.endsWith 'jar' }
    .collect { file ->
        new Node(null, "classpathentry", [
            "path": file.toString(),
            "kind": "lib",
            "exported": "true",
            "gradle-dependency": "true"
        ])
    }
    .each { classpath.append(it) }

    file(".classpath").withWriter { writer ->
        writer << new groovy.xml.StreamingMarkupBuilder().bind { mkp.xmlDeclaration() }
        def printer = new XmlNodePrinter(new PrintWriter(writer))
        printer.print(classpath)
    }
}

Шаг 3

Установите http://marketplace.eclipse.org/content/java-source-attacher плагин в Eclipse. После этого вы сможете щелкнуть правой кнопкой мыши на каждом JAR и выбрать «Прикрепить исходный код Java». По моему опыту, для зависимостей Gradle это работает в 99% случаев.