Базовый преобразователь двоичного кода в восьмеричный

Я бы обычно использовал строковые или символьные массивы и битовую арифметику для таких преобразований. Например:

function Int2Oct(invalue: integer): ShortString;
  const
    tt: array[0..7] of char = ('0', '1', '2', '3', '4', '5', '6', '7');
  var
    tempval: integer;
  begin
    Result := '';
    tempval := invalue;
    if tempval = 0 then
      Result := '0'
    else
      while (tempval <> 0) do
        begin
          Result := tt[(tempval and $7)] + Result;
          tempval := (tempval shr 3);
        end;
  end;

Кажется, работает за короткий промежуток времени, пока я его тестировал, если вы не ожидаете, что он будет обрабатывать отрицательные числа. Изменить: теперь он обрабатывает ноль.

Вот функция, которая работает примерно так же, как функция itoa библиотеки времени выполнения C, преобразуя положительное целочисленное значение (Cardinal в Delphi) в указанное основание счисления от 2 до 36. Она была протестирована в Delphi 2007 и XE4.

type
  TRadixRange = 2..36;

function ConvertIntToBase(value : Cardinal; Radix : TRadixRange) : string;
const
  Digits: array[0..35] of Char = ('0', '1', '2', '3',
                                  '4', '5', '6', '7',
                                  '8', '9', 'A', 'B',
                                  'C', 'D', 'E', 'F',
                                  'G', 'H', 'I', 'J',
                                  'K', 'L', 'M', 'N',
                                  'O', 'P', 'Q', 'R',
                                  'S', 'T', 'U', 'V',
                                  'W', 'X', 'Y', 'Z');
var
  nIndex : Integer;
begin
  Result := '';
  repeat
    nIndex := value mod radix;
    Result := Digits[nIndex] + Result;
    Value := Value div radix;
  until Value = 0;
end;

Ради интереса я решил написать функцию для «отмены» преобразования (преобразования из другой системы счисления обратно в десятичную (база 10)). Она также смоделирована (очень слабо) после функции C RTL atoi, за исключением того, что она требует, чтобы вы передавали систему счисления передаваемого числа.

function ConvertBaseToInt(const Value: string; const Radix: TRadixRange): Cardinal;
var
  i: Integer;
  Increment: Byte;
begin
  Result := 0;
  for i := 1 to Length(Value) do
  begin
    case Value[i] of
      '0'..'9': Increment := Ord(Value[i]) - Ord('0');
      'A'..'Z',
      'a'..'z': Increment := Ord(Value[i]) - Ord('A') + 10;
    else
      Increment := 0;
    end;
  end;
  Result := Result * Radix + Increment;
end;

Обратите внимание, что ConvertIntToBase был протестирован со многими числовыми входными данными, но я могу проверить только те основания, которые поддерживает калькулятор Windows в режиме программирования (двоичное (по основанию 2), восьмеричное (по основанию 8), десятичное (по основанию 10, которое я не тестировал) и hex (основание 16)), так как у меня нет калькулятора, который будет поддерживать другие значения системы счисления, и я не хочу выполнять эту работу вручную. ;-)

ConvertBaseToInt был протестирован путем передачи тестовых значений ConvertIntToBase и подтверждения того, что то, что входило в одно, было тем, что возвращалось из другого; IOW, что число, преобразованное в двоичное с помощью ConvertIntToBase, приведет к тому же числу при обратном прогоне через ConvertBaseToInt.

Вы можете проверить это с чем-то подобным в консольном приложении:

var
  TempStr: string;
  Reversed: Integer;
  i: Integer;
  Base: Byte;
const
  FmtStr = 'Value (base %d): %d  %s and back %d';
begin
  for i := 0 to 16 do
  begin
    for Base in [2, 8, 16] do  
    begin
      // Test bin, oct, and hex for a range of values from 0..65536
      TempStr := ConvertIntToBase(1 shl i, Base);
      Reversed := ConvertBaseToInt(TempStr, Base);
      Writeln(Format(FmtStr, [Base, 1 shl i, TempStr, Reversed]));
    end;
  end;
  Readln;
end.

program project1;

uses
    SysUtils, StrUtils;

begin
    // StrToInt function supports constants syntax: 
    // & - octal notation
    // $ - hexadecimal notation
    // % - binary notation
    Writeln(StrToInt('123'));
    Writeln(StrToInt('&173'))
    Writeln(StrToInt('$7B'));
    Writeln(StrToInt('%01111011'));

    // There are three functions for converting integer value to decimal, hexadecimal and binary notation
    Writeln(IntToStr(123));
    Writeln(IntToHex(123, 2));
    Writeln(intToBin(123, 8));

    Readln;
end.

Для других баз очень полезен ответ Кена Уайта.

Но в модуле StrUtils такие функции уже есть:

Dec2Numb
Synopsis: Convert a decimal number to a string representation, using given a base.
Declaration: function Dec2Numb(N: LongInt;Len: Byte;Base: Byte) : string
Visibility: default
Description: Dec2Numb converts N to its representation using base Base. The resulting string is left-padded
with zeroes till it has length Len. Base must be in the range 2-36 to be meaningful, but no checking
on this is performed.
Errors: If Base is out of range, the resulting string will contain unreadable (non-alphanumeric) characters.


Numb2Dec
Synopsis: Converts a string representation of a number to its numerical value, given a certain base.
Declaration: function Numb2Dec(S: string;Base: Byte) : LongInt
Visibility: default
Description: Numb2Dec converts the number in string S to a decimal value. It assumes the number is represented
using Base as the base. No checking is performed to see whether S contains a valid number using
base Base.
Errors: None.