Как получить имя файла значка в папке для создания/обновления desktop.ini для папок?

Мне нужна помощь, чтобы вернуть имя файла, расположенного в папке.

Я читал другие вопросы, заданные несколько раз, и ответ, кажется, таков:

for /d %F in (*.*) do echo %~nxF

Хотя это, похоже, работает для всех остальных, когда я запускаю это в пакетном файле, у него есть исключение и говорится, что «~ nxF» в настоящее время не ожидается.

Я пытаюсь создать пакетный файл, который будет считывать имя файла значка, затем вводить конкретную информацию в desktop.ini и, наконец, создавать этот файл с соответствующими правами или атрибутами.

@echo off

set NAME=%~dp0
for %%* in (.) do set NAME=%%~n*

set FOLDERICO=%NAME%
set ICONSIZES=16 24 32 48 64 128 256
set FOLDERINI=Desktop.ini

attrib +s "%CD%"

if exist %FOLDERINI% attrib -s -h %FOLDERINI%

echo [.ShellClassInfo] > %FOLDERINI%
echo IconResource=\[Video]\[HD Films]\%FOLDERICO%\Icon\%FOLDERICO%.ico,0 >> %FOLDERINI%

if not "%2"=="" (
    echo FolderType=%2 >> %FOLDERINI%
)
attrib -a +s +h %FOLDERINI%

Я думаю, что код можно как-то улучшить, чтобы запускать его из корневого каталога, а не из конкретной папки.

EDIT: Обновлен мой файл, теперь он выглядит так:

@ECHO OFF

attrib +s "%CD%"
set ICODIR=%CD%\Icon\

for %%F in ("%ICODIR%"*.ico) do set ICO=%%~nxF
echo %ICO%

set ICOINI=Desktop.ini
if exist %ICOINI% attrib -s -h %ICOINI%

echo [.ShellClassInfo] > %ICOINI%
echo IconResource=%ICODIR:~2%%ICO%,0 >> %ICOINI%

if not "%2"=="" (
    echo FolderType=%2 >> %ICOINI%
)

attrib -a +s +h %ICOINI%

Pause

Который мне нужно поместить в цикл for, сканирующий каждый подкаталог корня.


command filenames batch-file
person Built on Sin    schedule 24.06.2013    source источник
comment
Помещая команду for в пакетный файл, вы должны использовать двойные знаки процента %%, а не только одиночные знаки процента %. Кроме того, /d предназначен только для каталогов. for %%F in (*.*) do echo %%~nxF См. Для /?   -  person David Ruhmann    schedule 24.06.2013
comment
Спасибо, я думаю, что это тот ответ, который мне был нужен. Я стараюсь обращаться к текстам и руководствам, когда могу, но чаще всего они меня больше смущают, чем помогают.   -  person Built on Sin    schedule 24.06.2013

Ответы (1)


arrow_upward
1
arrow_downward

Вот полностью прокомментированный пакетный код для создания или обновления desktop.ini для значка папки и, при необходимости, для типа папки либо для указанной папки, либо для всех папок в корневом каталоге текущего диска (или текущего каталога с удалением /комментарий одной строки).

Создать файл desktop.ini довольно просто, в чем можно убедиться, взглянув на код. Обновление существующего INI-файла для замены строк или добавления их при необходимости в нужный раздел гораздо сложнее при использовании только внутренних команд командного процессора Windows cmd.exe, который не предназначен для таких задач.

@echo off

rem CreateDesktopIni.bat [FolderName | FolderType] [FolderType]

rem This batch file can be started without any parameter to create or
rem update desktop.ini for all subfolders in root of current drive or
rem current working directory with removing or commenting one line in
rem code below, see comment below label AllFolders.

rem But the batch file can be also started with a folder name
rem to create or update file desktop.ini of this folder only.

rem Optionally it is possible to specify as only parameter a folder type
rem or append as second parameter after folder name the folder type.

rem The folder type can be one of the following strings (not verified):

rem CommonDocuments, Contacts, Documents, Music, MusicAlbum, MusicArtist,
rem MusicIcons, MyDocuments, MyMusic, MyPictures, MyVideos, PhotoAlbum,
rem Pictures, UseLegacyHTT, VideoAlbum, Videos

setlocal EnableExtensions DisableDelayedExpansion
set "FolderType=%~2"

rem Define the subfolder containing the icon for the folder.
set "IconFolder=Icon"

rem Is the batch file called with at least one parameter?
if "%~1" == "" goto AllFolders

rem Yes! It could be a folder name or the folder type.
if not exist "%~1" set "FolderType=%~1" & goto AllFolders

rem First parameter specifies a folder (most likely as not verified).
set "Folder=%~1"
rem Remove trailing backslash if there is one.
rem The batch file should not be called with just \ as folder path.
if "%Folder:~-1%" == "\" set "Folder=%Folder:~0,-1%"

rem Call subroutine to create or update the desktop file for this folder.
call :DesktopINI "%Folder%"
goto EndBatch

:AllFolders
rem Change working directory to root of current drive. Remove or comment
rem the next line to process instead all subfolders in current directory.
cd \
rem Call subroutine to create/update the desktop file for each subfolder.
for /F "eol=| delims=" %%I in ('dir /AD /B 2^>nul') do call :DesktopINI "%%I"
goto EndBatch


rem Subroutine to create or update the desktop file for a folder.

rem This subroutine first searches for the icon file and does nothing
rem if no icon file could be found in the defined subfolder because
rem the subfolder does not exist at all or there is no *.ico file.

rem After determining the icon file (first found *.ico file) with full path
rem including drive letter (remove character d for relative path without
rem drive letter in line with %%~dpnxI), this subroutine checks next for
rem existence of file desktop.ini (case-insensitive) in current folder.

rem desktop.ini with the two or three lines is simply created if this file
rem does not already exist and the user of the batch file has permissions
rem to create this file in the current folder.

rem For an already existing desktop.ini the necessary process to update it
rem is much more complex. All lines outside the section [.ShellClassInfo]
rem must be kept and are therefore just copied to a temporary file, except
rem empty lines ignored by command FOR. Also all lines within the section
rem [.ShellClassInfo] not starting with the string IconFile= or optionally
rem FolderType= (both case-insensitive) must be also simply kept by copying
rem them to the temporary file.

rem An existing line starting with IconFile= in section [.ShellClassInfo]
rem is not copied to temporary file, but instead this line is written to
rem the temporary file with determined icon file name with path.

rem An existing line starting with FolderType= in section [.ShellClassInfo]
rem is also not copied to temporary file, but instead this line is written
rem to the temporary file with folder type as specified on starting batch.

rem If section [.ShellClassInfo] was found and beginning of a new section is
rem detected because of a line starting with an opening square bracket and
rem the line with IconFile= and/or the line with FolderType= was not found
rem in this section during processing the existing desktop.ini, the lines
rem are written next to temporary file to insert them before continuing
rem with the next section.

rem Finally it could happen that section [.ShellClassInfo] is missing in
rem existing desktop.ini and must be therefore added to the file. And it
rem could be that this section exists at end of desktop.ini, but either
rem the line with IconFile= or with FolderType= or both are missing and
rem those lines must be therefore appended to the file.

rem The temporary file is next copied over the existing desktop.ini and
rem then deleted as not further needed. Finally the system and hidden
rem attributes are set on file desktop.ini and the system attribute is
rem set on the current folder as otherwise desktop.ini would be ignored.

:DesktopINI
set "Folder=%~1"

for %%I in ("%Folder%\%IconFolder%\*.ico") do (
    set "IconFile=%%~dpnxI"
    goto IconFound
)
goto :EOF

:IconFound
set "DesktopFile=%Folder%\desktop.ini"

if not exist "%DesktopFile%" (
    echo [.ShellClassInfo]>"%DesktopFile%"
    if not exist "%DesktopFile%" goto :EOF
    echo Iconfile=%IconFile%>>"%DesktopFile%"
    if defined FolderType echo FolderType=%FolderType%>>"%DesktopFile%"
    %SystemRoot%\System32\attrib.exe +h +s "%DesktopFile%"
    %SystemRoot%\System32\attrib.exe +s "%Folder%"
    goto :EOF
)

set "IconLine="
set "ShellClassInfo="
set "UpdateComplete="
set "TempFile=%TEMP%\Desktop.tmp"
if exist "%TempFile%" del /F "%TempFile%"
if not defined FolderType (set "TypeLine=1") else set "TypeLine="
%SystemRoot%\System32\attrib.exe -h -s "%DesktopFile%"

(for /F "usebackq delims=" %%L in ("%DesktopFile%") do (
    set "LineOutput="
    if defined ShellClassInfo (
        for /F "delims==" %%V in ("%%L") do (
            if /I "%%V" == "IconFile" (
                echo Iconfile=%IconFile%
                set "IconLine=1"
                set "LineOutput=1"
            ) else if /I "%%V" == "FolderType" (
                if defined FolderType (
                    echo FolderType=%FolderType%
                    set "TypeLine=1"
                    set "LineOutput=1"
                )
            ) else (
                set "NewSection=1"
                for /F "eol=[" %%G in ("%%V") do set "NewSection="
                if defined NewSection (
                    if not defined IconLine echo Iconfile=%IconFile%
                    if not defined TypeLine echo FolderType=%FolderType%
                    set "ShellClassInfo="
                    set "UpdateComplete=1"
                )
            )
        )
    ) else if /I "%%L" == "[.ShellClassInfo]" (
        echo [.ShellClassInfo]
        set "ShellClassInfo=1"
        set "LineOutput=1"
    )
    if not defined LineOutput echo(%%L
)) >"%TempFile%"

if not defined UpdateComplete if not defined ShellClassInfo (
    echo [.ShellClassInfo]>>"%TempFile%"
    set "ShellClassInfo=1"
)

if defined ShellClassInfo (
    if not defined IconLine echo Iconfile=%IconFile%
    if not defined TypeLine echo FolderType=%FolderType%
) >>"%TempFile%"

move /Y "%TempFile%" "%DesktopFile%" >nul
if exist "%TempFile%" del "%TempFile%"

%SystemRoot%\System32\attrib.exe +h +s "%DesktopFile%"
%SystemRoot%\System32\attrib.exe +s "%Folder%"
goto :EOF

:EndBatch
endlocal

Желательно удалить все комментарии, которые являются строками, начинающимися с команды rem, для более быстрой обработки командного файла.

Командную строку cd \ необходимо удалить или закомментировать, если пакетный файл должен обрабатывать все вложенные папки текущей папки при запуске пакетного файла, а не вложенные папки текущего диска.

Параметр DIR /S может быть добавлен к dir /AD /B для обработки всего дерева каталогов текущей папки или текущего диска при запуске этого пакетного файла.

Переменная среды IconFolder может быть определена только с помощью . вместо Icon для поиска первого файла *.ico в самой папке, а не во вложенной папке Icon.

Чтобы понять, какие команды используются и как они работают, откройте окно командной строки, выполните в нем следующие команды , и очень внимательно прочитайте все страницы справки, отображаемые для каждой команды.

  • attrib /?
  • call /?
  • cd /?
  • del /?
  • dir /?
  • echo /?
  • endlocal /?
  • for /?
  • goto /?
  • if /?
  • move /?
  • rem /?
  • set /?
  • setlocal /?

Прочтите статью Microsoft о Использование операторов перенаправления команд для объяснения >, >> и 2>nul. Оператор перенаправления > должен быть экранирован символом вставки ^ в командной строке FOR с 2^>nul, чтобы он интерпретировался как буквальный символ, когда интерпретатор команд Windows обрабатывает эту командную строку перед выполнением команды FOR, которая выполняет встроенную командную строку dir в отдельном командном процессе, запущенном в фоновом режиме.

person Mofi    schedule 02.01.2015