Автоматизация сканирования и поиска имен таблиц/объектов в SAS

SQL-решение:

data product_20130603;
run;

data product_20130503;
run;

data product_20130703;
run;

%let campdate=20130601;

proc sql;
  select min(memname) into :datasetname from dictionary.tables 
  where libname='WORK' and upcase(scan(memname,1,'_'))='PRODUCT' and
  input(scan(memname,2,'_'),YYMMDD8.) ge input("&campdate.",YYMMDD8.);
quit;

Теперь у вас есть &datasetname, который вы можете использовать в операторе set, поэтому

данные мой_анализ; установить     (что бы вы ни делали); бежать;

Измените «WORK» на соответствующее имя библиотеки, и если есть какие-либо другие ограничения, добавьте их. Вы можете получить некоторые предупреждения о недопустимых датах, если у вас есть product_somethingnotadate, но это не должно иметь значения.

Как это работает: Dictionary.tables представляет собой список всех таблиц во всех именах библиотек, к которым вы обращались (то же самое, что и sashelp.vtable, но доступно только в PROC SQL). Сначала выбираются все строки, имя которых имеет дату, большую или равную дате окончания вашей кампании; затем он берет min(memname) из этого. Memname — это, конечно, строка, но в строках, которые идентичны, за исключением числа, вы все равно можете использовать min и получить ожидаемый результат.

Это, вероятно, не подходит для вашего приложения, однако я нахожу это очень полезным для наборов данных, которые у меня есть, поскольку они абсолютно должны существовать каждое воскресенье, и я оцениваю существование набора данных в начале моего кода. Если они не существуют, он отправляет электронное письмо нашим ИТ-специалистам, в котором сообщается, что файл отсутствует и его необходимо заново создать\восстановить.

%LET DSN = PRODUCTS_%SYSFUNC(PUTN(%SYSFUNC(INTNX(WEEK.2,%SYSFUNC(INPUTN(&MAX_ENDDATE.,YYMMDD8.)),0,END)),YYMMDDN8.));

С другими приведенными выше предложениями они дадут вам результаты только для существующих наборов данных, поэтому, если тот, который вы должны были использовать, был удален, он возьмет следующий и запустит задание независимо.

Во-первых, получить все возможные таблицы:

data PRODUCT_TABLES;
    set SASHELP.VTABLE (keep=libname memname);
    *get what you need, here i keep it simple;
    where lowcase(substr(memname,1,9))='products_';
run;

Затем отсортируйте его по дате, что легко сделать из-за формата имен ваших наборов данных.

proc sort data=PRODUCT_TABLES;
    by memname;
run;

Наконец, вам просто нужно получить первую запись, где дата достаточно велика.

data _NULL_;
    set PRODUCT_TABLES;
    *compare to your macro variable, note that i keep it as simple as possible and let SAS implicitly convert to numeric;
    if substr(memname,10,18)>=symgetn("max_enddate") then do;
        *set your match into a macro variable, i have put together the libname and memname here;
        call symput("selectedTable",cats(libname,'.',memname));
        stop; *do not continue, otherwise you will output simply the latest dataset;
    end;
run;

Теперь вы можете просто поместить переменную макроса, если хотите использовать соответствующий набор данных, например:

data SOME_TABLE;
    set &selectedTable.;
    /*DO SOME STUFF*/
run;