FINDSTR и пропуск папок

Параметр FINDSTR /S заставляет его искать все папки, тем самым обходя цель вашего цикла FOR.

Стефан успешно диагностировал еще одну проблему с вашим кодом, касающуюся перенаправления с использованием перезаписи вместо режима добавления.

Но есть гораздо более простой способ получить желаемый результат. Просто позвольте FINDSTR выполнить поиск во всех папках и передайте результат дополнительному FINDSTR, чтобы удалить результаты, содержащие ненужные папки. Поскольку цикла нет, вы можете безопасно использовать режим owverwrite для перенаправления.

findstr /misl request "%basedir%\*" | findstr /liv "\\projects\\ \\archive\\" >"%basedir%\Projects\list.txt"

ИЗМЕНИТЬ

Приведенное выше простое решение потратит время на поиск папок, которые впоследствии будут исключены. Это может привести к потере драгоценного времени, если эти папки огромны.

Следующий сценарий не будет утруждать себя сканированием папок «%basedir%\Projects» или «%basedir%\Archive».

@echo off
setlocal EnableDelayedExpansion
set basedir=C:\folder

>"%basedir%\Projects\list.txt" (
  findstr /mil request "%basedir%\*"
  for /f "eol=: delims=" %%F in (
    'dir /a:d-h /b %basedir% ^| findstr /vixl "projects archive"'
  ) do findstr /smil request "%basedir%\%%F\*"
)

Если вы хотите пропустить все папки с именами «Проекты» или «Архив», независимо от того, где они находятся в дереве, то:

@echo off
setlocal EnableDelayedExpansion
set basedir=C:\folder

>"%basedir%\Projects\list.txt" (
  findstr /mil request "%basedir%\*"
  for /f "eol=: delims=" %%F in (
    'dir /s /a:d-h /b %basedir% ^| findstr /vir "[\\]projects[\\] [\\]archive[\\] [\\]projects$ [\\]archive$"'
  ) do findstr /mil request "%%F\*"
)

У меня была аналогичная проблема: мне нужно было использовать findstr для поиска всех файлов .js, кроме тех, что находятся в папке node_modules (т. е. я хотел искать свой код, но не код каких-либо импортированных модулей). Это команда, которую я использовал:

dir /S /B *.js | findstr /v /i node_modules | findstr /i /F:/ todo

Разбивая это:

• dir /S /B *.js выведет полный путь ко всем файлам .js в текущем каталоге и всех подкаталогах.
• findstr /v /i node_modules фильтрует этот список путей и удаляет все пути, содержащие строку «node_modules». (Флаг /v делает строки вывода findstr не совпадающими.)
• findstr /i /F:/ todo — «/F:/» указывает findstr принять список путей к файлам для поиска из консоли.

Таким образом, поиску подлежат только те файлы, которые проходят через фильтр «node_modules».

ваша проблема: при перенаправлении > вы каждый раз перезаписываете свой list.txt; последний раз, когда вы перезаписываете его пустой строкой. Вместо этого используйте >> (добавить в файл). Остальная часть вашего кода работает для меня.

В вашем коде есть пара моментов, которым трудно следовать. Вы хотите пропустить папки, но команда for /f %%g in ('dir /a:-h /b %basedir% получает все нескрытые имена, включая файлы и папки. В конце вы используете > для сохранения результатов, поэтому в этом файле сохраняется только вывод последнего findstr ... %%g. Вместо этого вы должны использовать >>, как указывает Стефан. Однако я до сих пор не понимаю, как вы получаете такой результат!

Я предлагаю вам изменить свой код, чтобы сделать его проще, чтобы его было легче отслеживать и обнаруживать возможные ошибки. Например:

setlocal EnableDelayedExpansion
set basedir=C:\folder
set omitfolders=\Projects\Archive\
cd %basedir%
for /D %%g in (*) do (
   if "!omitfolders:\%%g\=!" equ "%omitfolders%" (
       findstr /i /m /s /c:"request" %basedir%\%%g\*.* >> %basedir%\Projects\list.txt
   )
)

Команда if "!omitfolders:\%%g\=!" equ "%omitfolders%" проверяет, находится ли имя папки не в переменной omitfolders.