Обнаружение идентификатора флажка, который был отмечен

Вы можете добавить обработчики событий для флажков, которые вы хотите во время выполнения. Используйте предложение Where для фильтрации по имени, если это применимо. Этот код делает это в form_load.

Внутри обработчика вы можете привести sender к локальной переменной, которая представляет установленный флажок, если хотите.

Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    For Each checkBox In Me.Controls.OfType(Of CheckBox)().Where(Function(cb As CheckBox) cb.Name.Contains("CheckBox"))
        AddHandler checkBox.CheckedChanged, AddressOf checkboxCheckedChanged
    Next
End Sub

Private Sub checkboxCheckedChanged(sender As Object, e As EventArgs)
    Dim myCheckbox As CheckBox = DirectCast(sender, CheckBox)
    Dim c As Boolean = myCheckbox.Checked
    Dim n As String = myCheckbox.Name
    ' etc.
End Sub

ИЗМЕНИТЬ

Как указал Neolisk, это не учитывает вложенные элементы управления, то есть элементы управления внутри контейнеров в форме. Этот метод расширения возвращает все эти элементы управления:

<Extension()> _
Public Function ChildControls(Of T As Control)(ByVal parent As Control) As List(Of T)
    Dim result As New List(Of Control)
    For Each ctrl As Control In parent.Controls
        If TypeOf ctrl Is T Then result.Add(ctrl)
        result.AddRange(ctrl.ChildControls(Of T)())
    Next
    Return result.ToArray().Select(Of T)(Function(arg1) CType(arg1, T)).ToList()
End Function

И вместо этого сделайте этот цикл в form_load:

    For Each checkBox In Me.ChildControls(Of CheckBox).Where(Function(cb As CheckBox) cb.Name.Contains("CheckBox"))
        AddHandler checkBox.CheckedChanged, AddressOf checkboxCheckedChanged
    Next

Используйте аргумент sender в обработчике событий.

Private Sub CheckBox1_CheckedChanged(sender As Object, e As EventArgs) _
                                                 Handles CheckBox1.CheckedChanged
  'DirectCast(sender, CheckBox).Name ?
End Sub