Получить имя устройства из InitTable — взломать System.pas

UnitNames содержит несколько имен единиц. Это короткие строки Паскаля, объединенные в конкатенацию. Однако, как мы увидим, это не те имена, которые вам нужны.

Включите отладчик в InitUnits и оцените:

PAnsiChar(InitContext.InitTable.TypeInfo.UnitNames)

В моем простом тестовом проекте, консольном приложении, которое просто использует SysUtils, вы видите следующее:

#$F'System.SysUtils'#6'System'#$18'System.Internal.ExcUtils'#$F'System.SysConst'
#7'SysInit'#$10'System.Character'#$E'Winapi.Windows'#$E'System.UITypes'
#$C'System.Types'#$10'System.RTLConsts'#$C'Winapi.PsAPI'#$F'Winapi.SHFolder'
#$F'Winapi.ImageHlp‹À'

Первый символ — это длина строки. Они объединены одно за другим, всего InitContext.InitTable.TypeInfo.UnitCount имен. Для моего простого проекта InitContext.InitTable.TypeInfo.UnitCount оценивается как 13.

Однако эти имена не соответствуют инициализируемым модулям. В моем тестовом проекте InitContext.InitTable^.UnitCount имеет значение 18, и юниты инициализируются в совершенно другом порядке, чем указано выше. Я уверен, вы знаете, что SysInit всегда на первом месте. Как видно из вышеизложенного, он находится в середине списка. Таким образом, хотя InitContext.InitTable.TypeInfo.UnitNames дает вам список определенных модулей, он не имеет отношения ни к модулям, требующим инициализации, ни к порядку инициализации.

Итак, как я это прочитал, UnitNames не может вам здесь помочь. Я считаю, что вам нужно будет использовать подробный файл карты, чтобы расшифровать это. Вам нужно найти имя функции Table^[I].Init. Если бы вы использовали, например, madExcept, это было бы легко сделать.

Конечно, вы не сможете выполнить поиск внутри InitUnits. Вы столкнулись с ситуацией курицы и яйца. Возможно, вам потребуется инициализировать по крайней мере некоторые единицы, прежде чем вы начнете вести журнал.

Например, похоже, что вы пытаетесь выделить строковую переменную. Это не удастся, потому что распределитель кучи RTL не был инициализирован. Ваш код ведения журнала не может выполнять какое-либо динамическое выделение с использованием кучи RTL, если вы ожидаете вызвать его до инициализации RTL.

Мне все это кажется чрезмерным. Если бы я был тобой, я бы:

1. Идентифицируйте единицы по индексу при регистрации. То есть запишите значение I.
2. Используйте результаты своего профилирования, чтобы выяснить, какие индексы являются проблемными.
3. В отладчике используйте условную точку останова для останова при вызове TProc(P)(), связанного с индексом, который вы определили на предыдущем шаге.
4. Войдите в P, чтобы узнать, к какому отряду он прикреплен.

В общем, лучше НЕ полагаться на порядок конструкторов классов, секций инициализации, деструкторов классов и секций финализации.

В большом (1.2M LOC) проекте невозможно сделать вывод, какой порядок будет использовать Delphi.

Лучше всего провести рефакторинг кода, чтобы избежать таких зависимостей, или использовать побочный эффект шаблона Singleton (инициализировать при первой необходимости).

Тем не менее, если вам действительно нужно вывести заказ, вы можете вручную зарегистрировать все

• Записи раздела инициализации

• Записи раздела завершения

• конструкторы классов

• деструкторы классов

Один из безопасных способов сделать это — использовать Windows API — OutputDebugString().

Вы можете использовать следующий блок, чтобы помочь вам с ведением журнала

unit unt_Debug;
{$SCOPEDENUMS ON}

interface

uses
  // System
  System.SysUtils
  {$IFDEF MACOS}
  ,FMX.Types
  {$ELSE}
  ,Winapi.Windows
  {$ENDIF};

{$WARN SYMBOL_PLATFORM OFF}
/// <remarks>
/// Output debug string. Output debug string can be seen in Delphi
/// View|Debug Windows|Event Log or with 3-rd party programs such as
/// dbgview.exe from SysInternals (www.sysinternals.com)
/// </remarks>
procedure ODS(const Text: string);

procedure ReportClassConstructorCall(const C: TClass);

procedure ReportClassDestructorCall(const C: TClass);

procedure ReportInitializationSection(const UnitName: string);

procedure ReportFinalizationSection(const UnitName: string);

implementation

procedure ReportClassConstructorCall(const C: TClass);
begin
  ODS(Format('%0:s class constructor invoked.', [C.ClassName]));
end;

procedure ReportClassDestructorCall(const C: TClass);
begin
  ODS(Format('%0:s class destructor invoked.', [C.ClassName]));
end;

procedure ReportInitializationSection(const UnitName: string);
begin
  ODS(Format('Unit %0:s - entering Initialization section.', [UnitName]));
end;

procedure ReportFinalizationSection(const UnitName: string);
begin
  ODS(Format('Unit %0:s - entering Finalization section.', [UnitName]));
end;

procedure ODS(const Text: string);
begin
  {$IFDEF DEBUG}
  {$IFDEF MACOS}
  // http://stackoverflow.com/questions/12405447/outputdebugstring-with-delphi-for-macosunit unt_Debug;
   Log.d(Text);
  {$ENDIF}
  {$IFDEF LINUX}
  __write(stderr, AText, Length(AText));
  __write(stderr, EOL, Length(EOL));
  {$ENDIF}
  {$IFDEF MSWINDOWS}
  OutputDebugString(PWideChar(Text));
  {$ENDIF}
  {$ENDIF}
end;

{$WARN SYMBOL_PLATFORM ON}

end.

Его можно использовать, например, так:

unit Sample;

interface

type
  TSample = class
  public
    class constructor Create;
    class destructor Destroy;
  end;

implementation

uses
  unt_Debug;

class constructor TSample.Create;
begin
  ReportClassConstructorCall(TSample);
  // Do stuff
end;

class destructor TSample.Destroy;
begin
  ReportClassDestructorCall(TSample);
  // Do stuff
end;

initialization

  ReportInitializationSection(TSample.UnitName);
  // do stuff

finalization

  ReportFinalizationSection(TSample.UnitName);
  // do stuff

end.