Flex, как получить неделю года для свидания?

Я не знаю о библиотеке, но эта функция даст вам индекс недели (с нуля).

function getWeek(date:Date):Number
{
  var days:Array = [31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31]; 
  var year:Number = date.fullYearUTC;
  var isLeap:Boolean = (year % 4 == 0) && (year % 100 != 0)
                       || (year % 100 == 0) && (year % 400 == 0); 
  if(isLeap)
    days[1]++;

  var d = 0;
  //month is conveniently 0 indexed.
  for(var i = 0; i < date.month; i++)
    d += days[i];
  d += date.dateUTC;

  var temp:Date = new Date(year, 0, 1);
  var jan1:Number = temp.dayUTC;
  /**
   * If Jan 1st is a Friday (as in 2010), does Mon, 4th Jan 
   * fall in the first week or the second one? 
   *
   * Comment the next line to make it in first week
   * This will effectively make the week start on Friday 
   * or whatever day Jan 1st of that year is.
   **/
  d += jan1;

  return int(d / 7);
}

Я просто хочу указать, что в приведенном выше решении есть ошибка.

for(var i = 0; i < date.month; i++)

должно быть

for(var i = 0; i < date.monthUTC; i++)

для правильной работы.

Тем не менее, спасибо за решение, оно мне очень помогло :)

Прежде чем d разделить на 7, его следует уменьшить на 1. В противном случае суббота перейдет на следующую неделю.

Возьмем, к примеру, 2011 год, 01.01.2011 — суббота. Это должна быть неделя в 0, а 08.01.2011 должна быть в неделе 1.

Если d не уменьшается, то 1+6=7/7=1, а 8+6=14/7=2. Так что это не правильно.

Я пытался использовать функцию Amarghosh, но у меня были проблемы со значениями UTC. И с первыми днями года тоже.

Поэтому я изменил настройку jan1 (в зависимости от воскресенья) и расчет последней недели.

Вот функция, которую я использую, основанная на функции Амаргоша:

public static function getWeek(date:Date):String
{
    var days:Array = [31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31]; 
    var year:Number = date.fullYear;
    var isLeap:Boolean = (year % 4 == 0) && (year % 100 != 0)
        || (year % 100 == 0) && (year % 400 == 0); 
    if(isLeap)
        days[1]++;

    var d:Number = 0;

    for(var i:int = 0; i < (date.month); i++){
        d += days[i];
    }

    d += date.date;

    var temp:Date = new Date(year, 0, 1);
    var jan1:Number = temp.day;
    if(jan1 == 0) // sunday
        jan1 = 7;
    d += jan1 - 1;


    var week:int = int((d-1) / 7);

    if(week == 0) // les premiers jours de l'année
        week = 52;

    return (week < 10 ? "0" : "") + week;

}