Построить структуру XML из атрибутов в одном узле

У меня есть следующий источник XML:

<element not-relevant="true" bold="true" superscript="true" subscript="false" text="stuff"/>

В любом порядке мне нужно перебирать определенные атрибуты (т.е. только те, которые связаны с HTML, который я создаю: полужирный/надстрочный/нижний индекс и т. д.), и когда один из этих атрибутов оценивается как «истина», выводить вложенные элементы чтобы получить следующий вывод:

<strong>
    <sup>
        stuff
    </sup>
</strong>

У меня такое ощущение, что мне нужно использовать какую-то рекурсию, например следующую (без бесконечного цикла, конечно):

<xsl:template match="element">
    <xsl:call-template name="content">
        <xsl:with-param name="text" select="@text"/>
    </xsl:call-template>
</xsl:template>

<xsl:template name="content">
    <xsl:param name="text"/>
    <xsl:choose>
        <xsl:when test="@bold = 'true'">
            <strong>
                <xsl:copy>
                    <xsl:call-template name="content">
                        <xsl:with-param name="text" select="$text"/>
                    </xsl:call-template>
                <xsl:copy>
            </strong>
        </xsl:when>
        <xsl:when test="@subscript = 'true'">
            <sub>
                <xsl:copy>
                    <xsl:call-template name="content">
                        <xsl:with-param name="text" select="$text"/>
                    </xsl:call-template>
                <xsl:copy>
            </sub>
        </xsl:when>
        <xsl:when test="@superscript = 'true'">
            <sup>
                <xsl:copy>
                    <xsl:call-template name="content">
                        <xsl:with-param name="text" select="$text"/>
                    </xsl:call-template>
                <xsl:copy>
            </sup>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$text" disable-output-escaping="yes"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

Любые идеи? Я ищу самое чистое решение XSLT 2.0 и ценю помощь.

Спасибо,


xml xslt xslt-2.0
person Aaron    schedule 23.09.2014    source источник

Ответы (1)


arrow_upward
6
arrow_downward

Это хороший вариант использования для <xsl:next-match/>:

<xsl:template match="element" priority="1">
  <xsl:value-of select="@text" />
</xsl:template>

<xsl:template match="element[@superscript = 'true']" priority="2">
  <sup><xsl:next-match/></sup>
</xsl:template>

<xsl:template match="element[@subscript = 'true']" priority="3">
  <sub><xsl:next-match/></sub>
</xsl:template>

<xsl:template match="element[@bold = 'true']" priority="4">
  <strong><xsl:next-match/></strong>
</xsl:template>

Когда вы применяете шаблоны к элементу element, он сначала запускает соответствующий шаблон с наивысшим приоритетом, и если этот шаблон использует next-match, он делегирует следующий наивысший приоритет и т. д. Ваш пример element в вопросе соответствует первому, второму и четвертому шаблонам. выше, поэтому сначала будет выбран «полужирный» шаблон, затем будет делегирован «верхний индекс» и, наконец, общий element, в результате чего получится <strong><sup>stuff</sup></strong>.

Как видно из этого примера, именно номера приоритетов определяют порядок вложенности — если бы приоритеты второго и четвертого шаблонов поменялись местами, вместо этого вы получили бы <sup><strong>stuff</strong></sup>.

person Ian Roberts    schedule 23.09.2014