Изменение содержимого файла записи zipfile

Я хотел бы обновить содержимое текстового файла, расположенного внутри zip-файла.

Я не могу понять, как это сделать, и приведенный ниже код работает неправильно.

Спасибо за любую помощь!!

import java.util.zip.ZipFile
import java.util.zip.ZipEntry
import java.util.zip.ZipOutputStream

String zipFileFullPath = "C:/path/to/myzipfile/test.zip"

ZipFile zipFile = new ZipFile(zipFileFullPath) 
ZipEntry entry = zipFile.getEntry ( "someFile.txt" )

if(entry){
    InputStream input = zipFile.getInputStream(entry)
    BufferedReader br = new BufferedReader(new InputStreamReader(input, "UTF-8"))

    String s = null
    StringBuffer sb = new StringBuffer()

    while ((s=br.readLine())!=null){
         sb.append(s)
    }

    sb.append("adding some text..")


     ZipOutputStream out = new ZipOutputStream(new FileOutputStream(zipFileFullPath))
     out.putNextEntry(new ZipEntry("someFile.txt"));

     int length


     InputStream fin = new ByteArrayInputStream(sb.toString().getBytes("UTF8"))

     while((length = fin.read(sb)) > 0)
     {
            out.write(sb, 0, length)
     }             

     out.closeEntry()

}

groovy zipfile
person user955732    schedule 04.10.2014    source источник

Ответы (2)


arrow_upward
4
arrow_downward

Просто небольшие изменения в ответе @Opal, я только что:

  • использовали заводные методы, где это возможно
  • упакован в метод

Отличный фрагмент

void updateZipEntry(String zipFile, String zipEntry, String newContent){
    def zin = new ZipFile(zipFile)
    def tmp = File.createTempFile("temp_${System.nanoTime()}", '.zip')
    tmp.withOutputStream { os ->
        def zos = new ZipOutputStream(os)
        zin.entries().each { entry ->
            def isReplaced = entry.name == zipEntry
            zos.putNextEntry(isReplaced ? new ZipEntry(zipEntry) : entry)
            zos << (isReplaced ? newContent.getBytes('UTF8') : zin.getInputStream(entry).bytes )
            zos.closeEntry()
        }
        zos.close()
    }
    zin.close()
    assert new File(zipFile).delete()
    tmp.renameTo(zipFile)
}

Использование

updateZipEntry('/tmp/file.zip', 'META-INF/web.xml', '<foobar>new content!</foobar>')
person Nick Grealy    schedule 06.01.2015

arrow_upward
3
arrow_downward

Что именно не работает? Выбрасывается ли какое-либо исключение?

Насколько мне известно, ZIP-файл невозможно изменить на месте. Следующий скрипт перезаписывает файл и, если нужная запись обрабатывается - модифицирует его.

import java.util.zip.*

def zipIn = new File('lol.zip')
def zip = new ZipFile(zipIn)
def zipTemp = File.createTempFile('out', 'zip')
zipTemp.deleteOnExit()
def zos = new ZipOutputStream(new FileOutputStream(zipTemp))
def toModify = 'lol.txt'

for(e in zip.entries()) {
    if(!e.name.equalsIgnoreCase(toModify)) {
        zos.putNextEntry(e)
        zos << zip.getInputStream(e).bytes
    } else {
        zos.putNextEntry(new ZipEntry(toModify))
        zos << 'lollol\n'.bytes
    }
    zos.closeEntry()
}

zos.close()
zipIn.delete()
zipTemp.renameTo(zipIn)

ОБНОВЛЕНИЕ

Я был не прав. ZIP-файл можно изменить на месте, но ваше решение опустит другие файлы, которые были заархивированы. Выходной файл будет содержать только один единственный файл - файл, который Вы хотели изменить. Я также предполагаю, что ваш файл был поврежден из-за того, что вы не вызвали close() на out.

Ниже приведен немного измененный (более грувовый) скрипт You:

import java.util.zip.*

def zipFileFullPath = 'lol.zip'
def zipFile = new ZipFile(zipFileFullPath) 
def entry = zipFile.getEntry('lol.txt')

if(entry) {
   def input = zipFile.getInputStream(entry)
   def br = new BufferedReader(new InputStreamReader(input, 'UTF-8'))
   def sb = new StringBuffer()

   sb << br.text
   sb << 'adding some text..'

   def out = new ZipOutputStream(new FileOutputStream(zipFileFullPath))
   out.putNextEntry(new ZipEntry('lol.txt'))

   out << sb.toString().getBytes('UTF8')
   out.closeEntry()
   out.close()
}
person Opal    schedule 04.10.2014
comment
Спасибо за помощь Опал. Ваше первое решение выглядит великолепно, но по какой-то причине ничего не происходит, zip-файл вообще не меняется. - person user955732; 04.10.2014
comment
Zip-файл не удаляется. Временный файл выглядит нормально. - person user955732; 04.10.2014
comment
Я тестировал в Mac OS. Пожалуйста, дайте мне знать, если это решило проблему. Могу еще раз проверить. - person Opal; 05.10.2014
comment
zipIn.delete() возвращает false, не знаю, почему невозможно удалить этот файл. - person user955732; 05.10.2014
comment
Файл по-прежнему заблокирован кодом до вызова метода delete(). Почему? - person user955732; 05.10.2014
comment
Как я вижу, Вы используете ОС Win и удалить файл проблематично. См.: stackoverflow.com/questions/991489/i-cant-delete-a-file-in-java или stackoverflow.com/questions/13685592/… или stackoverflow.com/questions/16985453/…. Есть много вопросов и ответов по этой проблеме, которые кажутся отличными от первоначально заданного вопроса. - person Opal; 05.10.2014