Включение синтаксиса в pdf-файл SAS ODS

Можно ли включить отправленный синтаксис или даже вывод файла журнала, когда ODS в PDF с использованием SAS?

Например, дайте этот простой код:

ods pdf file = "c:\temp\myPDF.pdf";
proc reg data = mydata;
model y = x;
run;
ods pdf close;

Я могу получить вывод регрессии и сопровождающий график в порядке. Но можно ли включить в PDF такую ​​прилагаемую команду?

proc reg data = mydata;
model y = x;
run;

sas sas-ods
person Penguin_Knight    schedule 10.10.2014    source источник

Ответы (1)


arrow_upward
6
arrow_downward

Это так, но для этого требуется пара обручей. К счастью, вы можете обернуть это в макросы, чтобы очистить свой код.

  1. Создайте временный fileref для хранения журнала.
  2. Запустите свой PDF и выведите журнал в файл.
  3. Напишите код.
  4. Остановить запись журнала в файл.
  5. Распечатать содержимое файла в PDF с помощью ODF TEXT=

Надеюсь это поможет

filename x temp;

ods pdf file="c:\temp\temp.pdf";
title "Cost of Power";
options source;
proc printto log=x;
run;

proc reg data=sashelp.cars;
model msrp = horsepower;
run;
quit;

proc printto;run;

title;
ods pdf startpage=now; /*Force a new page in the PDF*/

data _null_;
infile x;
input;
call execute("ods text='LOG: "||_infile_||"';");
run;

ods pdf close;

filename x ;
person DomPazz    schedule 10.10.2014