Итерация массива Awk для многомерных массивов

AWK подделывает многомерные массивы, объединяя индексы с символом, содержащимся в переменной SUBSEP (0x1c). Вы можете перебирать двумерный массив, используя split следующим образом (на основе примера в файле info gawk):

awk 'BEGIN { OFS=","; array[1,2]=3; array[2,3]=5; array[3,4]=8; 
  for (comb in array) {split(comb,sep,SUBSEP);
    print sep[1], sep[2], array[sep[1],sep[2]]}}'

Выход:

2,3,5
3,4,8
1,2,3

Однако вы можете перебирать массив с числовым индексом, используя вложенные циклы for:

for (i = 1; i <= width; i++)
    for (j = 1; j < = height; j++)
        print array[i, j]

Еще одна заслуживающая внимания информация из руководства GAWK:

Чтобы проверить, существует ли конкретная последовательность индексов в многомерном массиве, используйте тот же оператор (in), который используется для одномерных массивов. Запишите всю последовательность индексов в круглых скобках, разделенных запятыми, как левый операнд:

     (subscript1, subscript2, ...) in array

Gawk 4 добавляет массивы массивов. Из этой ссылки:

for (i in array) {
    if (isarray(array[i])) {
        for (j in array[i]) {
            print array[i][j]
        }
    }
    else
        print array[i]
}

Также см. Обход массивов массивов для получения информации о следующая функция, которая обходит массив массивов произвольного размера, в том числе зубчатые:

function walk_array(arr, name,      i)
{
    for (i in arr) {
        if (isarray(arr[i]))
            walk_array(arr[i], (name "[" i "]"))
        else
            printf("%s[%s] = %s\n", name, i, arr[i])
    }
} 

Нет, синтаксис

for(index1 in arr2) for(index2 in arr2) {
    print arr2[index1][index2];
}

не будет работать. Awk на самом деле не поддерживает многомерные массивы. Что он делает, если вы делаете что-то вроде

x[1,2] = 5;

заключается в объединении двух индексов (1 и 2) в строку, разделенную значением переменной SUBSEP. Если это равно "*", то у вас будет тот же эффект, что и

x["1*2"] = 5;

Значение по умолчанию SUBSEP — непечатаемый символ, соответствующий Ctrl+\. Вы можете увидеть это с помощью следующего скрипта:

BEGIN {
    x[1,2]=5;
    x[2,4]=7;
    for (ix in x) {
        print ix;
    }
}

Запуск этого дает:

% awk -f scriptfile | cat -v
1^\2
2^\4

Итак, в ответ на ваш вопрос — как выполнить итерацию многомерного массива — просто используйте один цикл for(a in b), но вам может потребоваться дополнительная работа, чтобы разделить a на части x и y.

Текущие версии gawk (gnu awk, по умолчанию в linux, и его можно установить где угодно) содержат настоящие многомерные массивы.

for(b in a)
   for(c in a[b])
      print a[b][c], c , b

См. также функцию isarray()

Я приведу пример того, как я использую это в своей работе, обрабатывая данные запроса. Предположим, у вас есть файл извлечения, полный транзакций по категориям продуктов и идентификаторам клиентов:

customer_id  category  sales
1111         parts     100.01
1212         parts       5.20
2211         screws      1.33
...etc...

Легко использовать awk для подсчета общего количества отдельных клиентов с покупкой:

awk 'NR>1 {a[$1]++} END {for (i in a) total++; print "customers: " total}' \ 
datafile.txt

Однако вычисление количества отдельных клиентов с покупкой в ​​каждой категории предлагает двумерный массив:

awk 'NR>1 {a[$2,$1]++} 
      END {for (i in a) {split(i,arr,SUBSEP); custs[arr[1]]++}
           for (k in custs) printf "category: %s customers:%d\n", k, custs[k]}' \
datafile.txt

Приращение custs[arr[1]]++ работает, потому что каждая пара категория/идентификатор_клиента уникальна как индекс ассоциативного массива, используемого awk.

По правде говоря, я использую gnu awk, который быстрее и может выполнять array[i][j], как упоминал Д. Уильямсон. Но я хотел быть уверен, что смогу сделать это в стандартном awk.

awk(1) изначально разрабатывался — частично — как средство обучения языку C, а многомерные массивы были и в C, и в awk(1) почти всегда. как таковой POSIX IEEE 1003.2 стандартизировал их.

Чтобы изучить синтаксис и семантику, создайте следующий файл с именем «test.awk»:

BEGIN {
  KEY["a"]="a";
  KEY["b"]="b";
  KEY["c"]="c";
  MULTI["a"]["test_a"]="date a";
  MULTI["b"]["test_b"]="dbte b";
  MULTI["c"]["test_c"]="dcte c";
}
END {
  for(k in KEY) {
    kk="test_" k ;
    print MULTI[k][kk]
  }
  for(q in MULTI) {
    print q
  }
  for(p in MULTI) {
    for( pp in MULTI[p] ) {
      print MULTI[p][pp]
    }
  }
}

и запустите его с помощью этой команды:

awk -f test.awk /dev/null

вы получите следующий вывод:

date a
dbte b
dcte c
a
b
c
date a
dbte b
dcte c

по крайней мере, в Linux Mint 18 Cinnamon 64-разрядная версия 4.4.0-21-универсальная #37-Ubuntu SMP