Настройка производительности Neo4j

Вам не нужна обратная зависимость, достаточно только одной!

Для импорта настройте вашу кучу (neo4j-wrapper.conf) на 12G, настройте кеш страницы (neo4j.properties) на 10G.

Попробуйте это, это должно быть сделано за несколько минут.

create constraint on (p:Persons2) assert p.viewerId is unique;
create constraint on (p:Companies2) assert p.viewedId is unique;

USING PERIODIC COMMIT 10000
LOAD CSV WITH HEADERS FROM "file:/home/hadoopuser/Neo-input " AS row
FIELDTERMINATOR '\t'
MERGE (p2:Persons2 {viewerId: row.viewerId});

USING PERIODIC COMMIT 10000
LOAD CSV WITH HEADERS FROM "file:/home/hadoopuser/Neo-input " AS row
FIELDTERMINATOR '\t'
FOREACH (viewedId IN split(row.viewedId, ",") |
  MERGE (c2:Companies2 {viewedId: viewedId}));

USING PERIODIC COMMIT 10000
LOAD CSV WITH HEADERS FROM "file:/home/hadoopuser/Neo-input " AS row
FIELDTERMINATOR '\t'
WITH row, split(row.viewedId, ",") AS viewedIds
MATCH (p2:Persons2 {viewerId: row.viewerId})
UNWIND viewedIds AS viewedId
MATCH (c2:Companies2 {viewedId: viewedId})
MERGE (p2)-[:Friends]->(c2);

Для слияния отношений, если у вас есть компании, которые имеют от сотен тысяч до миллионов просмотров, вы можете использовать это вместо этого:

USING PERIODIC COMMIT 10000
LOAD CSV WITH HEADERS FROM "file:/home/hadoopuser/Neo-input " AS row
FIELDTERMINATOR '\t'
WITH row, split(row.viewedId, ",") AS viewedIds
MATCH (p2:Persons2 {viewerId: row.viewerId})
UNWIND viewedIds AS viewedId
MATCH (c2:Companies2 {viewedId: viewedId})
WHERE shortestPath((p2)-[:Friends]->(c2)) IS NULL
CREATE (p2)-[:Friends]->(c2);

Что касается вашего запроса?

Чего вы хотите достичь, извлекая перекрестные продукты между всеми людьми и всеми компаниями на глубине до 3 уровней? Это могут быть триллионы путей?

Обычно вы хотите знать это для отдельного человека или компании.

Обновите свой запрос

Например. Для 123456, Лица, которые все просматривали эту компанию, 12345,23456, тогда какие компании просматривали эти лица 12345 123456,23456,987653 23456 23456,123456,234567, тогда мне нужно дать рекомендацию компании -123456 как 23456,987653, 23456,234567 Отличие от результата (окончательный результат) 23456,987653,234567

match (c:Companies2)<-[:Friends]-(p1:Persons2)-[:Friends]->(c2:Companies2)
where c.viewedId = 123456
return distinct c2.viewedId;

для всех компаний это может помочь:

match (c:Companies2)<-[:Friends]-(p1:Persons2)
with p1, collect(c) as companies
match (p1)-[:Friends]->(c2:Companies2)
return c2.viewedId, extract(c in companies | c.viewedId);