Прыжок назад на 1000 строк

В x86 вам не нужна каскадная последовательность переходов, так как jmp может перепрыгнуть через весь сегмент. Просто условный переход, такой как jne, имеет ограниченный диапазон. Таким образом, вы можете изменить ошибочный условный переход на комбинацию безусловного ближнего перехода и условного короткого перехода:

Например, изменить

.MODEL small
.STACK 1000h

.CODE
main:

top:
    mov ax, 1
    jmp bottom


ORG 1000h               ; A big block between top and bottom

bottom:
    cmp ax, 0

    je top              ; **Error** Relative jump out of range by 0F85h bytes

    mov ax, 4C00h       ; Return 0
    int 21h

END main

to

.MODEL small
.STACK 1000h

.CODE
main:

top:
    mov ax, 1
    jmp bottom


ORG 1000h               ; A big block between top and bottom

bottom:
    cmp ax, 0

    jne skip            ; Short conditional jump
    jmp top             ; Near unconditional jump
    skip:

    mov ax, 4C00h       ; Return 0
    int 21h

END main

TASM может сделать это автоматически за вас. Поместите «ПРЫЖКИ» в начале (или там, где вам это нужно) файла:

JUMPS

.MODEL small
.STACK 1000h

.CODE
main:

top:
    mov ax, 1
    jmp bottom


ORG 1000h               ; A big block between top and bottom

bottom:
    cmp ax, 0

    je top              ; TASM will change this line to a JNE-JMP combination

    mov ax, 4C00h       ; Return 0
    int 21h

END main

В наборе инструкций 80386 (ISA) есть инструкция для почти условного перехода. Если ваш эмулятор поддерживает ISA 80386 (DOSBox поддерживает), вы можете указать TASM использовать его. Вставьте директиву .386:

.MODEL small
.386                    ; Use 80386 instruction set
.STACK 1000h

.CODE
main:

top:
    mov ax, 1
    jmp bottom


ORG 1000h               ; A huge block between top and bottom

bottom:
    cmp ax, 0

    je top              ; Correct jump because of '.386'

    mov ax, 4C00h       ; Return 0
    int 21h

END main