Коробчатая диаграмма по группам, а также определяемая пользователем диаграмма рассеяния (маркеры для подмножества значений)

Итак - я думаю, что здесь есть решение, но я не уверен, насколько оно общее. Конечно, это работает только для двухэлементной коробчатой ​​диаграммы.

Проблема, с которой вы столкнулись прямо сейчас, заключается в том, что тип оси по умолчанию для диаграммы рассеяния является линейным, а не дискретным, в то время как коробчатая диаграмма по умолчанию является дискретной. Это всегда будет беспорядочно, если вы настроите это таким образом, хотя теоретически вы могли бы вычислить точную разницу и построить ее. Вы также можете использовать функцию аннотирования, хотя она будет иметь ту же проблему.

Однако, если вы настроили диаграмму рассеяния для использования дискретной оси, вы можете использовать опцию discreteoffset, чтобы выровнять все правильно - более или менее. К сожалению, невозможно использовать group на диаграмме рассеяния, чтобы указать SAS разместить соответствующий маркер на соответствующей диаграмме, поэтому по умолчанию все заканчивается в центре дискретной оси; поэтому вам нужно будет использовать здесь два отдельных графика, один для a и один для b, один с отрицательным смещением, а другой - с положительным.

Преимущество discreteoffset в том, что это должно быть постоянное значение для любой двухгрупповой блочной диаграммы, если вы не измените ширину прямоугольника; независимо от того, насколько велик фактический график, величина дискретного смещения должна быть одинаковой (поскольку это процент от общей ширины блока, назначенного для этого значения).

Некоторые моменты, которые следует учитывать, включают в себя наличие шести элементов в вашей коробчатой ​​диаграмме вместо трех (так что избавьтесь от group и просто укажите шесть разных значений visnum, a_1 b_1 и т. Д.); это будет гарантировать, что каждая диаграмма направлена ​​прямо по центру дискретной оси (тогда ваша диаграмма рассеяния будет иметь дискретное смещение 0). Вы также можете рассмотреть возможность создания собственного коробочного графика; например, рассчитайте свой собственный IQR, а затем используйте графики высоких и низких значений, чтобы нарисовать квадраты и нарисовать усы с помощью аннотации, а затем построить диаграмму рассеяния всех различных выбросов (а не только ваших «нормальных»).

Вот код, который, кажется, работает для вашего конкретного примера и, надеюсь, будет работать в большинстве аналогичных случаев (с двумя полосами). Для 3 столбцов это, вероятно, тоже просто (1 столбец имеет смещение 0, два других, вероятно, около +/- 0,25). Помимо этого, вам придется проводить больше вычислений, чтобы выяснить, где будут находиться ящики, но в целом SAS будет довольно хорошо распределять их одинаково, поэтому обычно это будет довольно просто.

proc sql;
  create table labstruct
    (  mygroup         char(3) label='Treatment Group'
     , myvisitnum      num     label='Visit number'
     , myvisitname     char(8) label='Visit name'
     , labtestname     char(8) label='Name of lab test'
     , labseed         num     label='Lab measurement seed'
     , lablow          num     label='Low end of normal range'
     , labhigh         num     label='High end of normal range'
    )
  ;
  insert into labstruct
    values('A', 1,  'Day 1',  'Test XYZ', 48, 40, 60)
    values('A', 5,  'Week 1', 'Test XYZ', 50, 40, 60)
    values('A', 10, 'Week 2', 'Test XYZ', 52, 40, 60)
    values('B', 1,  'Day 1',  'Test XYZ', 52, 40, 60)
    values('B', 5,  'Week 1', 'Test XYZ', 50, 40, 60)
    values('B', 10, 'Week 2', 'Test XYZ', 48, 40, 60)
  ;
quit;

data labdata;
  set labstruct;

  * Put normal range outliers on 2nd axis, manually separate groups on 2nd axis *;
  select (mygroup);
    when ('A') a_scatternum = myvisitnum;  /* Note the separate names now, but no added +/- 1 */
    when ('B') b_scatternum = myvisitnum;
    otherwise;
  end;

  * Make more obs from the seeds above *;
  label labvalue = 'Lab measurement';
  do repeat = 1 to 20;
    labvalue = labseed + 6*rannor(3297);

    * Scatter plot ONLY normal range outliers *;
    if labvalue < lablow or labvalue > labhigh 
       then scattervalue = labvalue;
    else scattervalue = .;

    output;
  end;
  drop repeat labseed;
run;

proc sgplot data=labdata noautolegend;  /* suppress auto-legend */
  block x=myvisitnum block=myvisitname / 
        nofill 
        lineattrs=(color=lightgray);
  vbox labvalue / 
       category=myvisitnum
       group=mygroup
       outlierattrs=(symbol=square) name="boxplot"; /* Name for keylegend */
  scatter x=a_scatternum y=scattervalue /     /* Now you have two of these - and no need for an x2axis */
       group=mygroup discreteoffset=-0.175
        jitter
       ;  
  scatter x=b_scatternum y=scattervalue /
       group=mygroup discreteoffset=0.175
        jitter
       ;
  keylegend "boxplot" / position=bottom type=marker;  /* Needed to make a custom keylegend or else you have a mess with three plots in it */
run;

Спасибо за понимание! Я застрял на одном и том же разъединении между дискретной осью прямоугольной диаграммы и реальной осью диаграммы рассеяния. Оказывается, с SAS 9.4 диаграммы разброса могут обрабатывать «категории», как vbox, но SAS называет это осью x, а не категорией. Этот пример SAS 9.4 a> также помог мне его взломать (естественно, сразу после того, как я сдался :).

Обновленный код: «Категория» из VBOX - это «x» для SCATTER. Обратите внимание, что ширина кластера по умолчанию для VBOX и SCATTER различна, 0,7 и 0,85 соответственно, поэтому я должен явно установить для них одно и то же значение:

proc sql;
  create table labstruct
    (  mygroup         char(3) label='Treatment Group'
     , myvisitnum      num     label='Visit number'
     , myvisitname     char(8) label='Visit name'
     , labtestname     char(8) label='Name of lab test'
     , labseed         num     label='Lab measurement seed'
     , lablow          num     label='Low end of normal range'
     , labhigh         num     label='High end of normal range'
    )
  ;
  insert into labstruct
    values('A', 1,  'Day 1',  'Test XYZ', 48, 40, 60)
    values('A', 5,  'Week 1', 'Test XYZ', 50, 40, 60)
    values('A', 10, 'Week 2', 'Test XYZ', 52, 40, 60)
    values('B', 1,  'Day 1',  'Test XYZ', 52, 40, 60)
    values('B', 5,  'Week 1', 'Test XYZ', 50, 40, 60)
    values('B', 10, 'Week 2', 'Test XYZ', 48, 40, 60)
  ;
quit;

data labdata;
  set labstruct;

  * Make more obs from the seeds above *;
  label labvalue = 'Lab measurement';
  do repeat = 1 to 20;
    labvalue = labseed + 6*rannor(3297);

    * Scatter plot ONLY normal range outliers *;
    if labvalue < lablow or labvalue > labhigh 
       then scattervalue = labvalue;
    else scattervalue = .;

    output;
  end;
  drop repeat labseed;
run;

proc sgplot data=labdata;
  block x=myvisitnum block=myvisitname / 
        nofill 
        lineattrs=(color=lightgray);
  vbox labvalue / 
       category=myvisitnum
       group=mygroup
       groupdisplay=cluster
       clusterwidth=0.7
       outlierattrs=(symbol=square);
  scatter x=myvisitnum y=scattervalue /
       group=mygroup
       groupdisplay=cluster
       clusterwidth=0.7
       jitter;
  keylegend / 
       position=bottom type=marker;
run;

Еще раз спасибо за то, что так быстро вернули меня в нужное русло!