О смешивании сопрограмм Пролога (заморозить/2, когда/2) и DCG

В моем предыдущем ответе на недавний вопрос "Тест двоичного дерева поиска Prolog — сравнение родительских узлов нежелательных родителей", я предложил смешать lazy_chain/2, который использует prolog-coroutining ...

:- use_module(library(clpfd)).

lazy_chain(Zs, R_2) :-
   (  var(R_2)                  -> instantiation_error(R_2)
   ;  clpfd:chain_relation(R_2) -> freeze(Zs, lazy_chain_aux(Zs,R_2))
   ;  otherwise                 -> domain_error(chain_relation, R_2)
   ).

lazy_chain_aux([], _).
lazy_chain_aux([Z0|Zs], R_2) :-
   freeze(Zs, lazy_chain_aux_(Zs,R_2,Z0)).

lazy_chain_aux_([], _, _).
lazy_chain_aux_([Z1|Zs], R_2, Z0) :-
   call(R_2, Z0, Z1),
   freeze(Zs, lazy_chain_aux_(Zs,R_2,Z1)).

... вместе с dcg in_order//1 ...

in_order(nil) --> [].
in_order(node(X,L,R)) --> in_order(L), [X], in_order(R).

... вот так:

?- lazy_chain(Zs, #<),
   phrase(in_order(node(1,nil,nil)), Zs).
Zs = [1,23].

Есть ли простой способ "вставить" lazy_chain в phrase/3 так что его область действия ограничена частью последовательности, описанной in_order//1?

Прямо сейчас я получаю...

?- lazy_chain(Zs, #<),
   phrase(in_order(node(1,nil,nil)), Zs0,Zs).
Zs0 = [1|Zs], freeze(Zs, lazy_chain_aux(Zs,#<)).

... который (конечно) может дать сбой при дальнейшем создании экземпляра Zs:

?- lazy_chain(Zs, #<),
   phrase(in_order(node(1,nil,nil)), Zs0,Zs),
   Zs = [3,2,1].
false.

Как я могу обойти это и ограничить lazy_chain частью список различий?


prolog prolog-coroutining dcg list-difference
person repeat    schedule 15.01.2016    source источник

Ответы (2)


arrow_upward
2
arrow_downward

Тем временем я придумал следующий хак:

lazy_chain_upto(R_2, P_2, Xs0, Xs) :-
   (  var(R_2)                  -> instantiation_error(R_2)
   ;  clpfd:chain_relation(R_2) -> when((nonvar(Xs0) ; ?=(Xs0,Xs)),
                                        lazy_chain_upto_aux(Xs0,Xs,R_2)),
                                   phrase(P_2, Xs0, Xs)
   ;  otherwise                 -> domain_error(chain_relation, R_2)
   ).

lazy_chain_upto_aux(Xs0, Xs, _) :-
   Xs0 == Xs,
   !.
lazy_chain_upto_aux([], _, _).
lazy_chain_upto_aux([X|Xs0], Xs, R_2) :-
   when((nonvar(Xs0) ; ?=(Xs0,Xs)), lazy_chain_upto_prev_aux(Xs0,Xs,R_2,X)).

lazy_chain_upto_prev_aux(Xs0, Xs, _, _) :-
   Xs0 == Xs,
   !.
lazy_chain_upto_prev_aux([], _, _, _).
lazy_chain_upto_prev_aux([B|Xs0], Xs, R_2, A) :-
   call(R_2, A, B),
   when((nonvar(Xs0) ; ?=(Xs0,Xs)), lazy_chain_upto_prev_aux(Xs0,Xs,R_2,B)).

Исходя из этого, мы могли бы определить in_orderX//1 следующим образом:

in_orderX(T) --> lazy_chain_upto(#<, in_order(T)).

Пример запроса, показанный в вопросе...

?- phrase(in_orderX(node(1,nil,nil)), Zs0,Zs), Zs = [3,2,1].
Zs0 = [1,3,2,1], Zs = [3,2,1].

... теперь все в порядке, но все же интересно: оно того стоит?

person repeat    schedule 15.01.2016

arrow_upward
0
arrow_downward

Я не вижу никакой проблемы в смешивании сопрограммы и DCG. DCG — это всего лишь перевод правил DCG H --> B в некоторые обычные правила Пролога H' :- B'. Любая проводка ограничения может быть заключена в {}/1.

Вот пример из Quines:

% eval(+Term, +List, -Term, +Integer)
eval([quote,X], _, X) --> [].
eval([cons,X,Y], E, [A|B]) -->
   step,
   eval(X, E, A),
   eval(Y, E, B).
eval([lambda,X,B], E, [closure,X,B,E]) --> [].
eval([X,Y], E, R) -->
   step,
   {neq(X, quote), sto(B)},
   eval(X, E, [closure,Z,B,F]),
   {sto(A)},
   eval(Y, E, A),
   eval(B, [Z-A|F], R).
eval(S, E, R) -->
   {freeze(S, is_symbol(S)), freeze(E, lookup(S, E, R))}.

Вы можете сделать то же самое для lazy_chain_upto//2. Для начала вы можете определить первое предложение lazy_chain_upto//2 следующим образом:

lazy_chain_upto(R_2, P_2) -->
   (  {var(R_2)}                  -> {instantiation_error(R_2)}
   ;  {clpfd:chain_relation(R_2)} -> /* ?? */
   ;  {otherwise}                 -> {domain_error(chain_relation, R_2)}
   )

В части /* ?? */ вы также можете извлечь выгоду из DCG-ified предиката lazy_chain_upto_aux//1. Конечно, я предполагаю, что перевод DCG понимает (->) и (;)/2.

Пока

person Mostowski Collapse    schedule 28.02.2016