Как сохранить пробелы при чтении текстового файла фиксированной длины

Зачем вообще возиться с регулярными выражениями, если у вас фиксированная ширина столбцов? Рассмотрим следующее:

<cfscript>

    line = "ab  12  xy 654   +1234    ";
    columnLengths = [4, 4, 3, 6, 1, 8];

    o = readFixedLine(line, columnLengths);

    function readFixedLine(line, columnLengths) {

        var cells = [];
        var offset = 1;

        for (length in columnLengths) {
            cells.add( mid(line, offset, length) );
            offset += length;
        }

        return cells;
    }

    // cells read (the dump doesn't display whitespaces)
    writeDump(o);
    /*
        whitespaces represented as asterisks
        [1] ab**
        [2] 12**
        [3] xy*
        [4] 654***
        [5] +
        [6] 1234****
    */

    // proving that whitespaces are kept
    for (entry in o) {
        writeOutput( len(entry) & "<br>" );
    }
    /*
        4
        4
        3
        6
        1
        8
    */

</cfscript>

Функция mid безотказна (в этом отношении), поэтому вам даже не нужно беспокоиться о пустых строках или отсутствующих столбцах. Однако fileReadLine обрезает конечные пробелы, так что вам здесь не повезло. Здесь может помочь только Java (прочитайте свой файл с помощью Stream или BufferedReader).

Спасибо @Alex за отличное решение. Java — это то, что нужно, и его метод очень функционален. Я просто хочу показать, как я реализовал его при построении запроса.

Осталось с массивом столбцов и строк, которые вы можете поместить в объект запроса с помощью QueryAddColumn. Мне пришлось возиться с длиной столбца, но метод java - это то, что нужно. Еще раз спасибо @Alex.

function formatTextFile(input){
        var fileReader = createObject("java","java.io.FileReader").init(input);
        var bufferedReader = createObject("java","java.io.BufferedReader").init(fileReader);
        var lineReader = createObject("java","java.io.LineNumberReader").init(bufferedReader);

        var columnLengths = [7,10,47,34,14,13,16,22,75,18,2];
        var rows = ArrayNew(2);
        var line = lineReader.readLine();
        //skip empty lines
        while(!structKeyExists(Local,"line")&&!len(trim(Local.line))){
            line = lineReader.readLine();
        }

        while(isDefined("line")){
            var cells = ArrayNew(1);
            var offset = 1;
            for(var i = 1; i<=ArrayLen(columnLengths); i++){
                cells.add(mid(line,offset,columnLengths[i]));
                offset+=columnLengths[i];
                ArrayAppend(rows[i],cells[i]);
            }
            line = lineReader.readLine();
        }
        return rows;        
    }

(Слишком долго для комментариев)

Примечание к исходному вопросу: пробел удаляется регулярным выражением, а не FileReadLine. Хотя лично я нахожу другое подходит гораздо более читабельно - технически это можно сделать с помощью регулярного выражения.

Например, вы можете создать выражение, которое соответствует всей строке, и использовать несколько подвыражений для соответствия желаемому количеству символов в каждом поле. Затем используйте сгенерированные обратные ссылки для создания строки с разделителями каналов, т.е. \1|\2|\3 ....

Код: Протестировано с помощью CF11

// ^ - starting with
// $ - ending with
// ( ) - subexpression or capturing group
// \1 - backreference, 1 corresponds to first subexpression
result = REReplace(line1
           ,"^(.{7})(.{10})(.{47})(.{34})(.{14})(.{13})(.{15})(.{22})(.{28})(.{18})(.{2})\s+$"
           , "\1|\2|\3|\4|\5|\6|\7|\8|\9|\10|\11"
        );

Пример данных:

A1     B         C                                              D                                 E             F            G              H                     I                           J                 K   
A2     B         C                                              D                                 E             F            G              H                     I                           J                 K   
A3     B         C                                              D                                 E             F            G              H                     I                           J                 K  

Если вы выгрузите результаты и проверите len() каждого поля, вы увидите, что пробелы сохранены. Так что проблема в исходном выражении.

for (currValue in listToArray(line1, "|")) {
    writeOutput("<br>["& len(currValue) &"] "& currValue );
}

Результаты:

[7 ] A1     |
[10] B         |
[47] C                                              |
[34] D                                 |
[14] E             |
[13] F            |
[15] G              |
[22] H                     |
[28] I                           |
[18] J                 |
[2 ] K |