Не выводятся значения

Примерьте вот это:

use strict;
use warnings;

my @list_nums = qw(10 21 30 42 50 63 70);
ma_xi(@list_nums);

sub ma_xi
{
    my @list_ele = @_;
    my $set_val_max = '0'; my $set_val_min = '0';
    my $add_all_vals = '0';
    foreach my $each_ele(@list_ele)
    {
        $set_val_max = $each_ele if($set_val_max < $each_ele);
        $set_val_min = $each_ele if($set_val_min eq '0');
        $set_val_min = $each_ele if($set_val_min > $each_ele);
        $add_all_vals += $each_ele;
    }

    my $set_val_avg = $add_all_vals / scalar(@list_ele) + 1;

    print "MAX: $set_val_max\n";
    print "MIN: $set_val_min\n";
    print "TOT: $add_all_vals\n";
    print "AVG: $set_val_avg\n";

    #Return these values into array and get into the new sub routine's

}

Некоторые примечания

• Используйте много пробелов, чтобы разместить свой код. Я привел в порядок код Perl в вашем вопросе, чтобы мне было легче его читать, не меняя его семантику.

• Вы должны всегда use strict и use warnings 'all' в начале каждой программы Perl, которую вы пишете

• Никогда не используйте амперсанд & в вызове подпрограммы. В этом не было необходимости или желания со времен Perl 4 более двадцати пяти лет назад. Любой учебник, который говорит вам об обратном, неверен

• Использование <> в контексте списка (например, в качестве параметров вызова подпрограммы) прочитает весь файл и исчерпает дескриптор файла. После этого любые вызовы <> будут возвращать undef

• Вы должны использовать chomp для удаления новой строки из каждой строки ввода

• Вы объявляете $mymax в рамках подпрограммы max, но затем пытаетесь напечатать его в print_stat, где его нет. use strict и use warnings 'all' поймали бы эту ошибку за вас

• Ваша подпрограмма max возвращает максимальное рассчитанное значение, но вы никогда не используете это возвращаемое значение.

Ниже приведена исправленная версия вашего кода.

Обратите внимание, что я прочитал весь файл в массив @values, а затем проглотил их все сразу. В общем, лучше всего читать и обрабатывать ввод по одной строке за раз, что было бы вполне возможно здесь, но я хотел сказать как можно ближе к вашему исходному коду.

Я также сохранил возвращаемое значение из max в переменной $max, а затем передал его в print_stat. Нет смысла пытаться снова прочитать файл и передать все эти значения в print_stat, как это делает ваш код.

надеюсь, это поможет

use strict;
use warnings 'all';

my @values = <>;
chomp @values;

my $max = max(@values);
print_stat( $max );

sub max {
    my $mymax = shift;

    for ( @_ ) {
        if ( $_ > $mymax ) {
            $mymax = $_;
        }
    }

    return $mymax;
}

sub print_stat {
    my ($val) = @_;

    print $val, "\n";
}

Обновлять

Вот версия, которая вычисляет всю статистику, которую вы упомянули. Я не думаю, что подпрограммы помогут в этом случае, так как решение короткое и код не может быть повторно использован.

Обратите внимание, что я добавил данные в конец файла программы после __DATA__, что позволяет мне читать их из дескриптора файла DATA. Это часто удобно для тестирования

use strict;
use warnings 'all';

my ($n, $max, $min, $tot);

while ( <DATA> ) {

    next unless /\S/; # Skip blank lines

    chomp;

    if ( not defined $n ) {
        $max = $min = $tot = $_;
    }
    else {
        $max = $_ if $max < $_;
        $min = $_ if $min > $_;
        $tot += $_;
    }

    ++$n;
}

my $avg = $tot / $n;

printf "\$n   = %d\n",   $n;
printf "\$max = %d\n",   $max;
printf "\$min = %d\n",   $min;
printf "\$tot = %d\n",   $tot;
printf "\$avg = %.2f\n", $avg;


__DATA__
7
6
1
5
1
3
8
7

выход

$n   = 8
$max = 8
$min = 1
$tot = 38
$avg = 4.75