Как применить этот VBA к нескольким файлам PPT в папке

Это мой пример кода для подпрограммы SelectHigestTextShape, но я не уверен, что он будет работать так, как вы хотите, для нескольких файлов. Причина в том, что он был разработан для ВЫБОРА объекта текстового поля в АКТИВНОЙ ПРЕЗЕНТАЦИИ с использованием АКТИВНОГО ПРОСМОТРА. Ничего из этого не существует, когда вы перебираете файлы в папке, поскольку вам нужно открывать каждый из них по очереди, но даже в этом случае какой смысл выбирать фигуру только для того, чтобы потом закрыть презентацию? Думаю, нам действительно нужно знать конечную цель. В типе пакетной обработки, которую вы пытаетесь использовать, было бы нецелесообразно вообще что-либо выбирать, поскольку для этого требуется, чтобы представление объекта было активным, что является кошмаром отладки и сильно замедляет все. Если вы хотите что-то сделать с конкретным объектом, гораздо лучше использовать ссылку на него, не требуя активного вида или даже активного окна (вы можете открывать каждый файл невидимо, обрабатывать его и затем закрывать).

В этом примере выполняется цикл по папке, открытие каждой найденной презентации (без окна), цикл по всем фигурам на всех слайдах, вывод количества слайдов и фигур на ближайшую панель, а затем закрытие файла:

' Loop through all PowerPoint files in a specified folder
' Open each and then loop through each shape of each slide
' Output a count of slides and shapes in immediate pane before closing the file
' Modified by Jamie Garroch of YOUpresent Ltd (http://youpresent.co.uk)
Sub LoopThroughPPTFiles()
  Dim oPres As Presentation, oSld As Slide, oShp As Shape
  Dim SldCount As Long, ShpCount As Long
  Dim MyFile As String
  Const MyFolder = "c:\testfolder\"
  On Error GoTo errorhandler
  MyFile = Dir(MyFolder)
  While (MyFile <> "")
    If Right(MyFile, 5) Like ".ppt*" Then
      Set oPres = Presentations.Open(FileName:=MyFolder & MyFile, ReadOnly:=msoTrue, Untitled:=msoFalse, WithWindow:=msoFalse)
      For Each oSld In oPres.Slides
        SldCount = SldCount + 1
        For Each oShp In oSld.Shapes
          ShpCount = ShpCount + 1
        Next
      Next
      Debug.Print oPres.Name & " has " & SldCount & " slide(s) and " & ShpCount & " shapes."
      SldCount = 0: ShpCount = 0
      oPres.Close
    End If
    MyFile = Dir
  Wend
  ' clean up
  Set oPres = Nothing: Set oSld = Nothing: Set oShp = Nothing
  Exit Sub
errorhandler:
  If Not oPres Is Nothing Then oPres.Close: Set oPres = Nothing
End Sub

Вы можете использовать это, чтобы затем изучить фигуры после строки «Для каждого oShp в oSld.Shapes», чтобы найти фигуру, расположенную выше всего на слайде, а затем обработать ее (не выбирая ее).