Проблема с производительностью IdFTP при анализе всех файлов в каталоге и подкаталогах

Вы звоните ChangeDirUp() (возможно много раз?), а затем звоните ChangeDir(). Если directory является абсолютным путем, вы можете просто вызвать ChangeDir() один раз, чтобы сразу перейти к целевой папке и полностью избежать ChangeDirUp(). Рекурсивный цикл внутри findAllDirectoryFiles() использует абсолютные пути из RetrieveCurrentDir(), поэтому повторные вызовы ChangeDirUp() и ChangeDir() напрасны. Вы можете значительно сократить накладные расходы, не перемещаясь вверх и вниз по дереву папок без необходимости.

findAllDirectoryFiles() возвращает только что выделенный TIdFTPListItems, который вызывающая сторона должна освободить. Это само по себе, как правило, плохой выбор дизайна, но особенно в этом случае, потому что рекурсивный цикл вообще не освобождает эти вторичные объекты TIdFTPListItems, поэтому они утекают.

При добавлении файлов в вывод TIdFTPListItems вы добавляете только их имена файлов, а не их пути. Что хорошего в рекурсивном поиске файлов, если вызывающая сторона не знает, где был найден каждый файл? Или вас интересуют только имена файлов, а не пути?

Вы полностью игнорируете параметр deepness.

С учетом сказанного попробуйте что-то более похожее на это:

class procedure TATDFTPUtility.findAllDirectoryFiles(ftpClient: TIdFTP; const directory: String;var files: TIdFTPListItems; deepness: Integer = -1);
var
  I: Integer;
  baseDirectory: string;
  subDirectories: TStringList;
  item: TIdFTPListItem;
  localDirectoryListing: TIdFTPListItems;
begin
  try
    if directory <> '' then
      ftpClient.ChangeDir(directory);
    ftpClient.List;
  except
    Exit;
  end;
  baseDirectory := ftpClient.RetrieveCurrentDir;
  localDirectoryListing := ftpClient.DirectoryListing;
  subDirectories := nil;
  try
    for I := 0 to localDirectoryListing.Count - 1 do
    begin
      case localDirectoryListing[i].ItemType of
        ditFile: begin
          item := files.Add;
          item.Assign(localDirectoryListing[i]);
          // if you need the full path of each file...
          item.FileName := baseDirectory + '/' + item.FileName;
        end;
        ditDirectory: begin
          item := localDirectoryListing[i];
          if ((item.FileName <> '.') and (item.FileName <> '..')) and
             ((deepness = -1) or (deepness > 0)) then
          begin
            if subDirectories = nil then
              subDirectories := TStringList.Create;
            subDirectories.Add(baseDirectory + '/' + item.FileName);
          end;
        end;
      end;
    end;
    if subDirectories <> nil then
    begin
      if (deepness > 0) then Dec(deepness);
      for I := 0 to subDirectories.Count - 1 do begin
        findAllDirectoryFiles(ftpClient, subDirectories[I], files, deepness);
      end;
    end;
  finally
    subDirectories.Free;
  end;
end;

При вызове findAllDirectoryFiles() в первый раз вы можете установить directory в одно из следующих значений:

• пустая строка, чтобы начать поиск в текущем каталоге.

• подпапка, относящаяся к текущему каталогу.

• абсолютная папка, которая относится к корню сервера.

И установите deepness либо

• -1 для бесконечной рекурсии

• ›= 0, чтобы указать глубину рекурсии.

files := TIdFTPListItems.Create;
try
  TATDFTPUtility.findAllDirectoryFiles(ftpClient, 'desired directory', files, desired deepness);
  // use files as needed...
finally
  files.Free;
end;