vsvars32.bat в Visual Studio 2017

VS2017 страдает от очень серьезного нарушения мозгового кровообращения при выборе места установки. Самая чертовски глупая вещь, которую они сделали, - это сделали название редакции (Professional, Enterprise, возможно Community) частью пути. Это затрудняет надежный возврат инструментов с одной машины на другую.

Существует одна переменная среды, которая я думаю может решить проблему: переменная VSAPPIDDIR хранит путь к папке, в которой установлена ​​IDE (devenv.exe). Итак, если вы хотите запустить vcvars32.bat из события сборки, вы должны использовать

   call "%vsappiddir%..\..\VC\Auxiliary\Build\vcvars32.bat" x86

Обратите внимание, что это vc, а не vs, vsvars32.bat больше не существует. Вы могли бы предпочесть «Командную строку разработчика:

   call "%vsappiddir%..\tools\vsdevcmd.bat"

Но, судя по вашей ссылке, вы действительно хотите запустить утилиту editbin.exe:

   "%vsappiddir%..\..\VC\Tools\MSVC\14.10.25017\bin\HostX86\x86\editbin.exe" args...

Номер версии 14.10.25017 тоже не доставляет никакой радости, никакого реального понимания того, как это будет меняться от одного обновления к другому. Вероятно, так и будет.

Я знаю, что на вопрос (хорошо) дан ответ, но я хотел бы поделиться, как я решил проблему, в надежде, что это поможет людям поискать в Google решение.

@echo off

set INSTALLPATH=

if exist "%programfiles(x86)%\Microsoft Visual Studio\Installer\vswhere.exe" (
  for /F "tokens=* USEBACKQ" %%F in (`"%programfiles(x86)%\Microsoft Visual Studio\Installer\vswhere.exe" -version 15.0 -property installationPath`) do set INSTALLPATH=%%F
)

echo INSTALLPATH is "%INSTALLPATH%"

REM Save current dir for later
pushd %CD%

if NOT "" == "%INSTALLPATH%" (
  call "%INSTALLPATH%\Common7\Tools\VsDevCmd.bat"
) else (
  goto ERROR_NO_VS15
)

:WORK
REM Retrieve the working dir and proceed
popd
echo Doing work in %CD%
svcutil this_is_just_an_example
goto END

:ERROR_NO_VS15
echo Visual Studio 2017 Tools Not Available!

:END
echo Processing ends.

Небольшое объяснение приведенного выше сценария.

vswhere.exe - это однофайловый собственный исполняемый файл, который вы можете загрузить или распространить вместе со своими средами сборки и развертывания, чтобы найти Visual Studio или другие продукты, установленные с новым установщиком для Visual Studio 2017 (из vswhere wiki)

Начиная с Visual Studio 15.2 (предварительная версия 26418.1) vswhere.exe устанавливается в% ProgramFiles (x86)% \ Microsoft Visual Studio \ Installer (используйте% ProgramFiles% в 32-разрядной программе до Windows 10). Это фиксированное местоположение, которое будет сохраняться (как указано здесь)

Это позволяет разработчикам запрашивать несколько важных функций установки Visual Studio 2017 (и более поздних версий). Кроме того, этот инструмент был разработан для того, чтобы на одном компьютере можно было установить различные разновидности Visual Studio (Community Edition, Professional, ...).

Вы можете найти несколько примеров использования здесь.

Что касается сценария, то первая актуальная часть

if exist "%programfiles(x86)%\Microsoft Visual Studio\Installer\vswhere.exe" (
  for /F "tokens=* USEBACKQ" %%F in (`"%programfiles(x86)%\Microsoft Visual Studio\Installer\vswhere.exe" -version 15.0 -property installationPath`) do set INSTALLPATH=%%F
)

Запрашивает vswhere путь установки Visual Studio 2017 (-версия 15.0) и задает переменную с именем INSTALLPATH.

Следует отметить, что в 32-битной ОС вы должны использовать% programfiles% вместо% programfiles (x86)%.

Из-за этой проблемы , сценарий сохраняет текущий каталог для последующего использования.