Включение хэшей в хэши в Perl

Добро пожаловать в Perl. Надеюсь, вы хорошо проведете время, изучая и используя его.

К делу, с чего начать? Мне есть что сказать здесь.

Во-первых, загружать данные путем оценки файлов излишне рискованно. Если вы просто хотите сериализовать данные, попробуйте JSON :: XS или YAML или даже Возможность хранения. Если вам нужен файл конфигурации, на CPAN есть много-много модулей, которые помогают с этой задачей. Ознакомьтесь с Config :: Any.

Если вы хотите создать структуры данных для загрузки через eval (что на самом деле не очень хорошая идея), Data: : Dumper генерирует Perl-код, необходимый для создания любых структур данных, которые вы ему скармливаете. Основная причина, по которой я упоминаю об этом, заключается в том, что он гораздо более полезен в качестве средства отладки, чем сериализатор.

Теперь, когда об этом позаботились, если вы хотите загрузить файл и оценить его (опять же, не лучшая идея почти во всех случаях), вам следует посмотреть на do или требуется.

my $stuff = do 'address.pl';

Но не делай этого. String eval - это инструмент, который обычно лучше не использовать. В 99% случаев, если вы планируете использовать строку eval, остановитесь и подумайте о другом способе решения проблемы. Do - это неявный eval, поэтому он тоже считается.

Perl дает вам множество инструментов для выполнения рискованной и мощной магии. Большая часть того, чтобы стать квалифицированным программистом на Perl, заключается в понимании того, что является рискованным, почему и когда имеет смысл их использовать. Не ждите, что Perl будет баловать вас забором и воротами, чтобы вы были в безопасности. Серьезно подумайте о том, чтобы взять копию Эффективное программирование на Perl или Рекомендации по Perl. Когда вы новичок, многое пролетит над вашей головой при первом чтении, но любая книга может стать отличным справочником по мере вашего роста и обучения.

Следующая тема, чего вы, черт возьми, пытаетесь достичь с помощью всех этих экранированных цитат? У меня голова болит, когда я смотрю на это! В Perl есть несколько очень, очень хороших операторов цитирования, которые вы можно использовать, чтобы никогда не возиться с экранированием кавычек в ваших буквальных строках.

=> или жирная запятая автоматически помещает в кавычки левую часть (LHS), как если бы это были только буквы и цифры. Но использование кавычек и отступлений делает вещи действительно изворотливыми.

Когда вы говорите \'address\' => {}, Perl видит это как \, оператор "получения ссылки", применяемый к строковому литералу. В данном случае это незавершенный строковый литерал, потому что вы никогда не предлагаете неэкранированный ' после первого.

Если ваша цель - использовать 'address', кавычки и прочее в качестве хеш-ключа, вы можете сделать это:

my %foo = ( "'address'" => 'blah' );

Если вам не нужны кавычки, что кажется гораздо более обычным вариантом использования, просто выполните:

my %foo = ( address => 'blah' );

Переходим к сообщениям об ошибках, которые вы получали! Если вы узнаете, что все они означают, в Perl появятся довольно приятные сообщения об ошибках. До тех пор может быть немного сложно понять их значение. К счастью, Perl поставляется со скриптом под названием splain: удобный инструмент, который более подробно объясняет сообщения об ошибках. Вы также можете использовать модуль диагностика, чтобы автоматически получать такие же расширенные сообщения об ошибках.

Если бы я писал это, я бы сделал что-нибудь в этом роде:

gen_schema_files.pl - файл для записи файлов схемы JSON. Вы можете вручную редактировать свои схемы, если хотите. Вы также можете настроить вывод, чтобы он был красивее, если хотите улучшить читаемость.

#!/usr/bin/perl

use JSON::XS;
use File::Spec;

use constant BASEDIR => '.';

# Key is the file name, value is the data to put into the file.
my %schemata = (
    'address.json' => {
        address => {
            street => { __type => 'String' },
            unit => {
                __type => 'String',
                __validation_function => { is_a_number => '' },
                __schema_constraints  => { is_not_null => ''  }
            },
            suburb => { __type => 'String' },
            __type => 'ARRAY'
        },
    },

    'person_contact.json' => {
         firstname => { __type => 'String' },
         lastname =>  { __type => 'String' },

         # Use a special key to indicate that additional files should be 
         # loaded into this hash.
         INCLUDE  => [qw( address.json )], 
     },

     # And so forth
);

for my $schema ( keys %schemata ) {
    my $path = File::Spec->catfile( BASEDIR, $schema );

    open my $fh, '>', $path
        or die "Error opening '$path' for writing - $!\n";

    print $fh encode_json $schemata{$schema};
}

load_schemas.pl - это код, который загружает схемы и делает разные вещи. Моя только заряжается. Понятия не имею, что вы делаете с данными ...

#!/usr/bin/perl
use strict;
use warnings;

use Data::Dumper;

use JSON::XS;
use File::Spec;

use constant BASEDIR => '.';


my $schema = load_schema( 'person_contact.json' );

print Dumper $schema;


sub load_schema {
    my $file = shift;

    my $path = File::Spec->catfile( BASEDIR, $file );

    open my $fh, '<', $path
        or die "Error opening file '$path' - $!\n";

    my $json = join '', <$fh>; # reads a list of lines and cats them into one string.
                               # One way to slurp out of many.

    my $schema = decode_json( $json );

    # Handle the inclusion stuff:

    if( exists $schema->{INCLUDE} ) {
        # Copy the files to load into an array.
        my @loadme = @{$schema->{INCLUDE}};
        # delete the magic special include key.
        delete $schema->{INCLUDE};

        # Load each file and copy it into the schema hash.
        for my $load ( @loadme ) {
            my $loaded = load_schema( $load );

            # This is a bit of weird syntax.
            # We are using a hash slice assignment to copy the loaded data into the existing hash.
            # keys and values are guaranteed to come out in the same (random) order as each other.
            # the @{$foo}{blahbhal} is how you dereference a hash reference as a slice.
            @{$schema}{keys %$loaded} = values %$loaded;
        }
    }

    return $schema;
}

Я замалчивал некоторые вещи, но я попытался оставлять комментарии с достаточным количеством терминов (словарный запас или даже жаргон, если хотите), чтобы вы могли выполнять эффективный поиск.

В приведенном выше коде есть пара недостатков. Он не выполняет никаких проверок на наличие круговых включений (он будет работать долгое время и в конечном итоге заполнит память и вылетит - не очень хорошо). Выбор волшебного ключа может быть неудачным. И, вероятно, есть еще кое-что, о чем я еще даже не подумал.

Perldoc - потрясающий ресурс, но его так много, что нужно время, чтобы научиться находить нужные вещи. Взгляните на Поваренную книгу Perl Data Structures и Руководство по массивам массивов. Как новичок, я обнаружил, что в разделе Perl-функции по категориям perlfunc быть невероятно полезным.

Думаю, я остановлюсь сейчас, когда я написал более чем достаточно текста, чтобы ослепить обычного человека. Я надеюсь, что эта диссертация окажется для вас полезной. Еще раз добро пожаловать и добрый вечер (пожалуйста, выберите свое местное время, когда найдете этот ответ).