Функция CLEAN используется редко, поэтому о ней часто забывают.

CLEAN удаляет непечатаемые символы (ASCII от 0 до 31) из заданного текста. Вы можете использовать его в VBA:

myStr = Application.WorksheetFunction.Clean(myStr)

...или как функция рабочего листа Excel:

=CLEAN(A1)

Пример:

Sub cleanDemo()

    Dim mystr As String

    'populate string with linefeeds and carriage returns.
    'note: vbLf = chr(10): vbCr = chr(13) : vbCrLf = vbCr+vbLf
    mystr = "A" & vbLf & "B" & vbCr & "C" & vbCrLf & "D"

    'display string and it's length
    MsgBox mystr, , "myStr is " & Len(mystr) & " char long."

    'remove ASCII 0 through 31
    mystr = Application.WorksheetFunction.Clean(mystr)

    'display string and it's length
    MsgBox mystr, , "myStr is " & Len(mystr) & " char long."

End Sub

... возвращает:

Список всех символов в строке:

Процедура перечисляет символы и их коды, найденные в указанной строке:

Sub showAllChars(strIn as String)
'Lists all ASCII character codes used in the specified string.
'Adaptable to UNICODE by changing Asc to AscW and Chr to ChrW
Dim strIn As String, c As String, p As Long

For p = 1 To Len(strIn)
    c = Mid(strIn, p, 1)
    Debug.Print "Pos#" & p & ": Chr(" & Asc(c) & ") =[";
    Select Case Asc(c)
        Case 10
            Debug.Print "LF]", ;
        Case 13
            Debug.Print "CR]", ;
        Case Else
            Debug.Print c & "]", ;
    End Select
    If p / 5 = p \ 5 Then Debug.Print
Next p
Debug.Print "Done. (Length=" & Len(strIn) & ")"
End Sub

Пример вывода:

Pos#1: Chr(65) =[A]         Pos#2: Chr(66) =[B]         Pos#3: Chr(13) =[CR]        
Pos#4: Chr(67) =[C]         Pos#5: Chr(63) =[?]         Pos#6: Chr(68) =[D]         
Pos#7: Chr(17) =[]          Pos#8: Chr(69) =[E]         Pos#9: Chr(70) =[F]         
Pos#10: Chr(63) =[?]        Pos#11: Chr(71) =[G]        Pos#12: Chr(10) =[LF]       
Pos#13: Chr(72) =[H]        Pos#14: Chr(73) =[I]        Done. (Length=14)

Дополнительная информация:

• Office.com: ЧИСТЫЙ Функция (Excel/VBA)

• MSDN: WorksheetFunction.Clean Метод (взаимодействие)

• ascii.cl : Таблицы кодов ASCII

• MSDN: Функции Chr и ChrW< /strong> (Взаимодействие)

• MSDN: Функции Asc и AscW< /strong> (Взаимодействие)

• Википедия: ASCII

• Википедия: Управляющие (непечатаемые) символы