Как получить новые строки при выводе текста для XML-документа MSXML2 в VBA?

Вы можете просто заменить каждый экземпляр ">" на ">" & vbCrLf с помощью функции Replace перед записью файла на диск.

Или вы можете просто сохранить XML на диск как есть и открыть его с помощью Firefox или IE, которые должны выделить для вас синтаксис.

Не знаю, нашли ли вы подходящее решение / обходной путь, но я рассматривал эту проблему в msxml, и кто-то предложил использовать MXXMLWriter. Вы можете направить вывод через синтаксический анализатор SAX (SAXXMLReader) и подключить к нему MXXMLWriter, как описано здесь. Несколько нелепо повторно анализировать xml, чтобы отформатировать его, когда вы знаете, что в DOMDocument есть вся информация, необходимая для отступа, но она у вас есть.

На самом деле у меня еще не было времени на изучение, но, по-видимому, вы можете использовать MXXMLWriter, не подключенный к SAX-ридеру, для создания XML - вместо использования DOMDocment - и заставить его делать отступы по мере продвижения. См. Инструкции здесь.

Просто написал подпрограмму VBA, которая делает отступ для XML-документа перед его сохранением. Отступы похожи на то, что я вижу при форматировании в Visual Studio. Возможно, его следует расширить, чтобы обрабатывать не только подэлементы и CDatas.

Sub IndentXml(xml As IXMLDOMElement, Optional depth As Integer)
    If IsMissing(depth) Then
        depth = 0
    End If

    Dim txt As IXMLDOMText

    If Not (xml.OwnerDocument.DocumentElement Is xml) Then
        Set txt = xml.OwnerDocument.createTextNode(vbNewLine & String(depth, vbTab))
        xml.ParentNode.InsertBefore txt, xml
    End If

    Dim child As IXMLDOMNode
    Dim hasElements As Boolean
    hasElements = False
    For Each child In xml.ChildNodes
        If child.NodeType = NODE_ELEMENT Then
            IndentXml child, depth + 1
            hasElements = True
        ElseIf child.NodeType = NODE_CDATA_SECTION Then
            Set txt = xml.OwnerDocument.createTextNode(vbNewLine & String(depth + 1, vbTab))
            xml.InsertBefore txt, child
            hasElements = True
        End If
    Next

    If hasElements Then
        Set txt = xml.OwnerDocument.createTextNode(vbNewLine & String(depth, vbTab))
        xml.appendChild txt
    End If
End Sub

Может быть, вам стоит взглянуть на бесплатное программное обеспечение ChilKat Xml вместо ужасного MSXML и упростить себе жизнь . Я помню, как боролся с отступом и форматированием в MSXML, и знаю, как это расстраивает.

Удачи.

Спасибо, Дарт Юрский за ваш код. Очень кстати!

В моем собственном коде второй блок «If» споткнулся о том, что «xml.ParentNode» был Nothing. Для своих целей я изменил следующую строку с:

If Not (xml.OwnerDocument.DocumentElement Is xml) Then

to:

If depth > 0 Then

Это отлично сработало для того, что мне нужно, поэтому подумал, что поделюсь им.