Не удалось установить выбранное свойство списка ListBox с несколькими столбцами в пользовательской форме Excel VBA

Я не могу проверить элемент в многоколоночной пользовательской форме ListBox. Строка lstPreConditionLogic.Selected(lstPreConditionLogic.ListCount) = True выдает следующую ошибку:

Ошибка выполнения «380»: не удалось установить выбранное свойство. Недопустимое значение свойства

Я попытался установить значение -1 , checked, но это не сработало.

Код VBA

Private Function FillPreConditionLogicList()
    Dim varTemp             As Variant
    Dim intLoop             As Integer
    Dim strExpression       As String
    Dim PreConditionLogic   As clsPreConditionLogic

    With lstPreConditionLogic
        .ColumnCount = 3
        .ListStyle = fmListStyleOption
        .MultiSelect = fmMultiSelectMulti
        strExpression = TrimBlank(shtExpressionEditor.Range("rngExpText").Offset(, 1).Value)
        For intLoop = 0 To mDicPreConditionLogic.Count - 1
            Set PreConditionLogic = mDicPreConditionLogic.Items(intLoop)
            .AddItem
            .List(intLoop, 0) = PreConditionLogic.Name
            .List(intLoop, 1) = PreConditionLogic.StartEnclosure
            .List(intLoop, 2) = PreConditionLogic.EndEnclosure
            varTemp = GetEnclosedString(strExpression, PreConditionLogic.StartEnclosure, PreConditionLogic.EndEnclosure)
            If varTemp <> "" Then
                lstPreConditionLogic.Selected(lstPreConditionLogic.ListCount) = True '//Gives Error
                strExpression = varTemp
            End If
        Next
    End With
End Function

excel vba multiple-columns userform checkedlistbox
person Sujoy    schedule 16.01.2019    source источник

Ответы (1)


arrow_upward
2
arrow_downward

Вы должны вычесть -1 из .ListCount …

lstPreConditionLogic.Selected(lstPreConditionLogic.ListCount - 1) = True

Поскольку статистика индекса списка считается 0, но, например, если ListCount = 5, то индекс этих 5 записей будет 0, 1, 2, 3, 4, что означает, что последний действительный индекс .ListCount - 1.

person Pᴇʜ    schedule 16.01.2019