Как упростить алгебраические уравнения, представленные в виде списка списка

Один лайнер, похожий на то, что предложил joel76:

simplify(I,O) :-
    bagof([S,E],L^(bagof(C,member([C,E],I),L),sum_list(L,S)),O).

Внутренний bagof собирает C (коэффициенты), заданные E (показатели степени), результирующий список L суммируется в S, а в паре с E становится [S,E], элементом (мономом) O. Если вы опускаете спецификатор универсального количественного определения (то есть L^) вы получаете одиночные мономы при возврате.

Вы можете решить свою проблему следующим образом:

simplify(_,_,S,S,[]):- !.
simplify(L,I,Sum,NTot,[[I,S]|T]):-
    Sum =< NTot,
    findall(X,member([X,I],L),LO),
    length(LO,N),
    S1 is Sum + N,
    sum_list(LO,S),
    I1 is I+1,
    simplify(L,I1,S1,NTot,T).           

write_function([]).
write_function([[D,V]|T]):-
    write(' + '),write(V),write('x^'),write(D),
    write_function(T).

test:-
    L = [[3,1],[2,1],[1,0],[2,0]],
    length(L,N),
    simplify(L,0,0,N,LO), 
    LO = [[D,V]|T],
    write('f='),write(V),write('x^'),write(D),
    write_function(T).

Основным предикатом является simplify/5, который использует findall/3 для поиска всех коэффициентов с одинаковой степенью, а затем суммирует их, используя sum_list/2. Затем вы можете написать результат причудливым образом, используя write_function/1.

В SWI-Prolog вы можете использовать агрегат:

pred(>, [_,X], [_,Y]) :- X > Y.
pred(<, [_,X], [_,Y]) :- X < Y.
pred(=, [_,X], [_,X]).

simplify(In, Out) :-
    aggregate(set([S,X]), aggregate(sum(P), member([P,X], In), S), Temp),
    predsort(pred, Temp, Out).

Например :

?- simplify([[3,1],[2,1],[1,0],[2,0]], Out).
Out = [[5, 1], [3, 0]] ;
false.