Возникли проблемы с сохранением вывода wmic csproduct get vendor / format: list | findstr / c = как переменная

Даже проще, чем использовать find или findstr и без проблемных 0x0D0D0A окончаний строк:

@Echo Off & SetLocal EnableExtensions
For /F Tokens^=6Delims^=^" %%G In (
    '%__APPDIR__%wbem\WMIC.exe CSProduct Get Vendor /Format:MOF 2^>NUL'
) Do Set "vendor=%%G"

Это решение также предотвращает нежелательные завершающие символы в строке имени поставщика, которые могут быть обычным явлением.

Существует известная wmic ошибка, поэтому вам нужно проанализировать wmic вывод, используя два вложенных цикла, например следующее:

FOR /F "tokens=1* delims==" %%s IN ('
    wmic csproduct get vendor /value ^| find "="
') DO for /F "tokens=*" %%i in ("%%t") do SET "vendor=%%i"

Здесь for петли

• %%s, чтобы получить значение vendor;
• %%i, чтобы удалить завершающий возврат каретки в возвращаемом значении (поведение wmic): каждая строка вывода заканчивается 0x0D0D0A (CR + CR + LF) вместо обычного 0x0D0A (CR + LF).

См. WMIC и FOR /F: Исправление для завершающего <CR> проблема

Ответ опубликован, чтобы продемонстрировать, что команда может быть назначена и выполнена как переменная, в отличие от ответа Neko, в соответствии с вопросом OP.

@Echo Off
Set Get.Vendor=^>"%TEMP%\Vendor.log" (wmic csproduct get vendor /value ^| 
findstr /c:=) ^&^& (For /F "UsebackQ Tokens=2* Delims==^EOL" %%A In ("%TEMP%\Vendor.log") Do For /F "Delims=" %%T In ("%%A") Do Set "Vendor=%%~T") ^&^& Echo.!Vendor!
Setlocal EnableDelayedExpansion
%Get.Vendor%
pause

Использование for %%i in (wmic csproduct get vendor /format:list ^| findstr/c=) do (set var=%%~I) Это означает, что переменная цикла for %%i становится выходом команды в цикле for, что позволяет вам установить другую переменную, переменную цикла for. Вам нужна вставка (^) перед | в цикле for, поскольку в противном случае команда выйдет из цикла for и не будет выполняться в цикле for. Вы также можете просто заключить команду в двойные кавычки ("), и вам не нужно будет экранировать конвейер. В результате выполнения команды %var% станет равным результату вашей команды wmic.

Последняя команда будет такой:

@echo off
for /f "tokens=* delims==" %%i in (' wmic csproduct get vendor /format:list ^| findstr /c:"=" ') do (set var=%%~i)
echo %var%
rem echoing var to make sure the variable is what you wanted

Вывод для меня:

Vendor=Microsoft Corporation

Если вы хотите, чтобы результат был конкретно Microsoft Corporation, вы можете добавить:

set var=%var:~7%

чтобы удалить первые 7 символов. Вы также можете изменить токены на 2* вместо *. :

for /f "tokens=2* delims==" %%j in (' wmic csproduct get vendor /format:list ^| findstr /c:"=" ') do (set var=%%~j)

Выходы:

Microsoft Corporation

Примечания:

В пакетных файлах, в отличие от PowerShell, вы не можете установить переменную как команду и сделать ее выходом, поэтому обычный способ установить выход команды в переменную использует цикл for. Кроме того, просто предпочтение, я бы предложил использовать переключатель /value, а не /format:list.

Проверено и у меня работает