Построение большого текстового файла, содержащего матрицу, с помощью gnuplot / matplotlib

Вот версия только для gnuplot. На самом деле, я не видел (пока) примера gnuplot о том, как строить комплексные числа из файла данных. Здесь идея состоит в том, чтобы разделить данные на столбцы с символами (, , и ) с помощью:

set datafile separator '(,)'

Затем вы можете указать свою i-ю действительную и мнимую части в столбце через column(3*i-1) и column(3*i) соответственно.

Вы создаете новый набор данных, многократно отображая данные в двойном цикле, что подходит для небольших данных. Однако я предполагаю, что это решение может стать довольно медленным для больших наборов данных, особенно если вы строите график из файла. Я предполагаю, что если у вас есть данные один раз в блоке данных (а не в файле), это может быть быстрее. Проверьте gnuplot: загрузить файл данных 1: 1 в блок данных. В общем, может быть, более эффективно использовать другой инструмент, например Python, awk и т. Д. Для подготовки данных.

Подумал только: если у вас ок. 3e9 байтов данных и (согласно вашему примеру) прибл. 48-50 байтов на точку данных, и если вы хотите построить квадратный график, то количество пикселей на стороне будет sqrt(3e9/50)=7746 пикселей. Сомневаюсь, что у вас есть дисплей, который сразу это отображает.

Изменить:

В приведенной ниже модифицированной версии теперь используется set print для блокировки данных, и она намного быстрее, чем исходная версия (с использованием двойного цикла plot ... every ...). Улучшение скорости я уже вижу на моем небольшом примере данных. Удачи с вашим огромным набором данных ;-). Для справки и сравнения старая версия снова указана здесь:

# create a new datablock with row,col,Real,Imag,Abs
# using plot ...with table     (pretty slow and inefficient)
set table $Data2
    set datafile separator '(,)'          # now, split your data at these characters
    myReal(i) = column(3*i-1)
    myImag(i) = column(3*i)
    myAbs(i)  = sqrt(myReal(i)**2 + myImag(i)**2)
    plot for [row=0:rowMax-1] for [col=1:colMax] $Data u (row):(col):(myReal(col)):(myImag(col)):(myAbs(col)) every ::row::row w table
    set datafile separator whitespace     # set separator back to whitespace
unset table

Код: (изменен с использованием set print)

### plotting complex numbers
reset session

$Data <<EOD
(0.1,0.1)   (0.2,1.2)   (0.3,2.3)   (0.4,3.4)   (0.5,4.5)
(1.1,0.1)   (1.2,1.2)   (1.3,2.3)   (1.4,3.4)   (1.5,4.5)
(2.1,0.1)   (2.2,1.2)   (2.3,2.3)   (2.4,3.4)   (2.5,4.5)
(3.1,0.1)   (3.2,1.2)   (3.3,2.3)   (3.4,3.4)   (3.5,4.5)
(4.1,0.1)   (4.2,1.2)   (4.3,2.3)   (4.4,3.4)   (4.5,4.5)
(5.1,0.1)   (5.2,1.2)   (5.3,2.3)   (5.4,3.4)   (5.5,4.5)
(6.1,0.1)   (6.2,1.2)   (6.3,2.3)   (6.4,3.4)   (6.5,4.5)
(7.1,0.1)   (7.2,1.2)   (7.3,2.3)   (7.4,3.4)   (7.5,4.5)
EOD

stats $Data u 0 nooutput   # get number of columns and rows, separator is whitespace
colMax = STATS_columns
rowMax = STATS_records

# create a new datablock with row,col,Real,Imag,Abs
# using print to datablock
set print $Data2
    myCmplx(row,col) = word($Data[row+1],col)
    myReal(row,col) = (s=myCmplx(row,col),s[2:strstrt(s,',')-1])
    myImag(row,col) = (s=myCmplx(row,col),s[strstrt(s,',')+1:strlen(s)-1])
    myAbs(row,col)  = sqrt(myReal(row,col)**2 + myImag(row,col)**2)
    do for [row=0:rowMax-1] {
        do for [col=1:colMax] {
            print sprintf("%d %d %s %s %g",row-1,col,myReal(row,col),myImag(row,col),myAbs(row,col))
        }
    }
set print

set key box opaque

set multiplot layout 2,2
    plot $Data2 u 1:2:3 w image ti "Real part"
    plot $Data2 u 1:2:4 w image ti "Imaginary part"
    set origin 0.25,0
    plot $Data2 u 1:2:5 w image ti "Absolute value"
unset multiplot
### end of code

Результат:

Может быть, это не то, о чем вы просили, но я думаю, что удобно строить график непосредственно из вашего кода, и легко изменить то, что вы хотите показать abs(x),real(x),... Вот простой фрагмент для построения матрицы Армадилло как изображения в gnuplot (Linux)

#include <armadillo>
using namespace std;
using namespace arma;

void plot_image(mat& x, FILE* cmd_pipe)
{    
  fputs("set nokey;set yrange [*:*] reverse\n", cmd_pipe);
  fputs("plot '-' matrix with image\n", cmd_pipe);
  for(uword r=0; r<x.n_rows; r++){
    for(uword c=0; c<x.n_cols; c++){
      string str=to_string(x(r,c))+" ";
      fputs(str.c_str(), cmd_pipe);
    }
    fputs("\n", cmd_pipe);
  }
  fputs("e\n", cmd_pipe);
}

int main()
{
  FILE* gnuplot_pipe = popen("gnuplot -persist","w");
    
  mat x={{1,2,3,4,5},
         {2,2,3,4,5},
         {3,3,3,4,5},
         {4,4,4,4,5},
         {5,5,9,9,9}};
       
  plot_image(x,gnuplot_pipe);        
  return 0 ;    
}

Результат: