Как немедленно разорвать соединение при длительном опросе

Магазин имеет дисплей покупателя, подключенный к 192.168.1.68 в локальной сети. Он использует длительный опрос для получения отображаемых данных с использованием http POST.

Он отображает отправленные данные, но для возврата HttpSendRequest требуется 5 отправок. Я установил тайм-ауты на 60 мс и количество повторных попыток на 1, но все равно требуется 5 секунд, прежде чем HttpSendRequest компилируется.

Если тайм-аут имеет большее значение, HttpSendRequest ожидает большее время, как и ожидалось.

Почему HttpSendRequest не может ждать менее 5 секунд?

Как завершить вызов сразу после отправки данных, чтобы однопоточное приложение могло продолжить работу. Команда

curl -d "@duedata.json" -H "Content-Type: application/json; charset=utf-8" --max-time 2 -X POST http://192.168.1.92:8082/poll-command

занимает 2 секунды и показывает данные в PCU. Отправка данных на дисплей занимает 1,2 секунды.

FUNCTION HTTPGetEx
LPARAMETERS tcPage, tcBuffer, tnBufferSize, tcHeaders, tcFileName, lpost


DECLARE INTEGER HttpOpenRequest ;
   IN WININET.DLL ;
   INTEGER hHTTPHandle,;
   STRING lpzReqMethod,;
   STRING lpzPage,;
   STRING lpzVersion,;
   STRING lpzReferer,;
   STRING lpzAcceptTypes,;
   INTEGER dwFlags,;
   INTEGER dwContextw

hHTTPResult=HttpOpenRequest(THIS.hhttpsession,;
   Icase(VARTYPE(lpost)='C', lpost, lpost or  tnPostSize > 0, "POST","GET"),;
   tcPage,;
   NULL,NULL,NULL,;
   INTERNET_FLAG_RELOAD + ;
   IIF(THIS.lsecurelink,INTERNET_FLAG_SECURE,0) + ;
   this.nHTTPServiceFlags,0) 

*** Apply timeout to the HTTP connection handle
THIS.wininetsettimeout(THIS.nConnectTimeOut,hHTTPResult)
THIS.wininetsettimeout(THIS.nConnectTimeOut)

THIS.hhttpsession=hHTTPResult

DECLARE INTEGER HttpSendRequest    ;
   IN WININET.DLL ;
   INTEGER hHTTPHandle,;
   STRING lpzHeaders,;
   INTEGER cbHeaders,;
   STRING lpzPost,;
   INTEGER cbPost

dwTimeoutSecs = 60

llRetVal=InternetSetOption(hHTTPResult,;
   INTERNET_OPTION_RECEIVE_TIMEOUT,;
   @dwTimeoutSecs,4)

llRetVal=InternetSetOption(hHTTPResult,;
   INTERNET_OPTION_SEND_TIMEOUT,;
   @dwTimeoutSecs,4)


dwTimeoutSecs=1  &&// Retry only 1 time
llRetVal=InternetSetOption( hHTTPResult,;
      INTERNET_OPTION_CONNECT_RETRIES,;
      @dwTimeoutSecs,4)

? 'Before HttpSendRequest'
* Todo: why HttpSendRequest takes 5 seconds ?
lnRetval=HttpSendRequest(hHTTPResult,tcHeaders,LEN(tcHeaders),lcPostBuffer,tnPostSize)
? 'After HttpSendRequest'

http winapi long-polling visual-foxpro winsock
person Andrus    schedule 29.03.2021    source источник
comment
С точки зрения клиента вы можете прервать/отключиться от текущей операции только с помощью InternetCloseHandle. См.: Как отменить запрос, отправленный с помощью wininet?   -  person Strive Sun    schedule 31.03.2021
comment
Visual FoxPro является однопоточным. Приложение не получает управления для этого. Он ожидает завершения вызова WinAPI. Почему значение тайм-аута не принимается? Как заставить winapi возвращаться через 2 секунды, а не через 5 секунд?   -  person Andrus    schedule 01.04.2021

Ответы (1)


arrow_upward
1
arrow_downward

Использование winhttprequest:

Проверьте https://docs.microsoft.com/en-us/windows/win32/winhttp/iwinhttprequest-settimeouts

Clear
owinhttp  = Create('winhttp.winhttprequest.5.1')
owinhttph = Create("winhttpH")
Eventhandler(owinhttp,owinhttph)

url = 'https://stackoverflow.com/questions/66857697/how-to-terminate-connection-immediately-on-long-polling'

Try

    With owinhttp
* resolveTimeout,connectTimeout,sendTimeout,receiveTimeout: 
        .setTimeOuts(2000,30000,30000,60000)
        .Open('GET',url,.F.)
        .setrequestheader('Connection','keep-alive')
        .Send()
    Endwith

Catch

    Aerror(ae)
    If ae(1,1) # 1429
        Display Memory Like ae
    Endif

Endtry


*****************************************************
Define Class winhttph As Session OlePublic
*****************************************************

    Implements iwinhttprequestevents In winhttp.winhttprequest.5.1
    bytesrec = 0
    cData = ''

*-------------------------------------------------------------------------------------
Procedure iwinhttprequestevents_onresponsedataavailable(Data As variant) As void
*-------------------------------------------------------------------------------------

    This.bytesrec = This.bytesrec+Len(Data)
    This.cData = This.cData+Data

    ? 'Bytes received:',This.bytesrec
    ? Strconv(Data,11)

    If This.bytesrec > 2000
        owinhttp.abort()
        Strtofile(Ttoc(Datetime())+Chr(13)+This.cData,'test.txt')
        Modify File test.txt Nowait
    Endif

*--------------------------------------------------------------------
Procedure iwinhttprequestevents_onresponsestart(Status As Number, contenttype As String) As void
*--------------------------------------------------------------------

*--------------------------------------------------------------------
Procedure iwinhttprequestevents_onerror(errornumber As Number, errordescription As String) As void
*--------------------------------------------------------------------
if errorNumber # -2147024890
    ? 'ERROR',errornumber,errordescription,'url:'+url
endif

*--------------------------------------------------------------------
Procedure iwinhttprequestevents_onresponsefinished() As void
*--------------------------------------------------------------------

********************************************
Enddefine
********************************************
person mplaza    schedule 07.04.2021