Я знаю, что вы хотите sed, но sed это совсем не нравится, кажется, что конкретно (см. здесь) не будет делать то, что вы хотите. Однако Perl сделает это (AFAIK):

perl -pe 'while (s#\t\t#\t\n\t#) {}' <filename>

В качестве обходного пути замените каждую вкладку на tab + \N; затем удалите все вхождения \N, за которыми сразу не следует табуляция.

sed -e 's/\t/\t\\N/g' -e 's/\\N\([^\t]\)/\1/g'

... при условии, что ваш sed использует обратную косую черту перед группировкой круглых скобок (существуют диалекты sed, которым не нужна обратная косая черта; попробуйте без них, если это не работает для вас.)

Не отличается от решения Perl, это работает для меня, используя чистый sed

С улучшением @Robin A. Meade

sed ':repeat;
     s|\t\t|\t\n\t|g;
     t repeat'

Объяснение

• :repeat — это метка, используемая для команд ветвления, аналогичная пакетной
• s|\t\t|\t\n\t|g; - Стандартная замена 2 вкладок на вкладку-новая строка-вкладка. Я по-прежнему использую глобальный флаг, потому что если у вас, скажем, 15 вкладок, вам нужно будет зациклиться только дважды, а не 14 раз.
• t repeat означает, что если команда s произвела какие-либо замены, то переходит к метке repeat, в противном случае она переходит на следующую строку и начинается заново.

Так что это происходит так. Продолжайте повторять (перейдите к repeat), пока не будет найдено совпадение с шаблоном из двух вкладок.

Хотя можно возразить, что можно просто сделать две одинаковые глобальные замены и назвать это хорошим, этот же метод может работать и в более сложных сценариях.

Как указывает @thorn-blake, sed просто не поддерживает расширенные функции, такие как просмотр вперед, поэтому вам нужно сделать такой цикл.

Исходный ответ

sed ':repeat;
     /\t\t/{
       s|\t\t|\t\n\t|g;
       b repeat
     }'

Объяснение

• :repeat — это метка, используемая для команд ветвления, аналогичная пакетной
• /\t\t/ означает совпадение вкладок шаблона 2. Если шаблон совпал, выполняется команда, следующая за второй /.
• {} - В этом случае команда, следующая за командой match, является группой. Таким образом, все команды в группе выполняются, если встречается шаблон соответствия.
• s|\t\t|\t\n\t|g; - Стандартная замена 2 вкладок на вкладку-новая строка-вкладка. Я по-прежнему использую глобальный, потому что если у вас, скажем, 15 вкладок, вам нужно будет выполнить цикл только дважды, а не 14 раз.
• b repeat означает всегда переходить (ветвь) к метке repeat

Укороченная версия

Который можно сократить до

sed ':r;s|\t\t|\t\n\t|g; t r'

# Original answer
# sed ':r;/\t\t/{s|\t\t|\t\n\t|g; b r}'

MacOS

И версия для Mac (но все еще совместимая с Linux/Windows):

sed $':r\ns|\t\t|\t\\\n\t|g; t r'

# Original answer
# sed $':r\n/\t\t/{ s|\t\t|\t\\\n\t|g; b r\n}'

• Вкладки должны быть буквальными в BSD sed
• Новые строки должны быть как буквальными, так и экранированными одновременно, поэтому одинарная косая черта (это \ до того, как она будет обработана $, что делает ее одной буквальной косой чертой) плюс \n, который становится фактической новой строкой.
• И имена меток (:r), и команды ветвления (b r, если не конец выражения) должны заканчиваться новой строкой. Специальные символы, такие как точки с запятой и пробелы, используются командой label name/branch в BSD, что делает ее очень запутанной.

Правильно, даже с /g sed не будет соответствовать тексту, который он заменил снова. Таким образом, он считывает <TAB><TAB> и выводит <TAB>\N<TAB>, а затем считывает следующее из входного потока. См. http://www.grymoire.com/Unix/Sed.html#uh- 7

Что ж, sed просто работает так, как задумано. Строка ввода сканируется один раз, а не несколько раз. Может быть, полезно посмотреть на последствия, если sed использовал повторное сканирование входной строки для обработки перекрывающихся шаблонов по умолчанию: в этом случае даже простые замены будут работать совершенно по-другому - некоторые могут сказать, что это нелогично - например.

• s/^/ / вставка пробела в начале строки никогда не завершалась
• s/$/foo/ добавление foo к каждой строке - аналогично
• s/[A-Z][A-Z]*/CENSORED/ замена слов в верхнем регистре на CENSORED - аналогично

Вероятно, есть много других ситуаций. Конечно, все это можно исправить, скажем, с помощью модификатора замены, но во время разработки sed было выбрано текущее поведение.