Как обрабатывать делегирование Objective-C из C ++?

Хорошо, чтобы ответить на ваш вопрос:

reportwindow.h дополнительно включается в файл .cpp, если это имеет значение.

Это действительно имеет значение. Любая единица компиляции (в данном случае файл cpp), которая касается кода Objective-C, должна быть переименована в .mm или .m. Включение заголовка, который, в свою очередь, включает материал Objective-C в файл C ++, приведет к проблеме, заключающейся в том, что компилятор C ++ видит код Objective-C, который он не может обработать.

Переименование файла cpp в mm выберет опцию Objective-C во время компиляции (чего нет, когда файл назван cpp или c) и, следовательно, позволит компилировать материал с токенами Objective-C (в основном "@" в вашем случае) .

Альтернативой было бы не включать класс делегата Objective-C в ваш класс C ++, а вместо этого включать указатель на ваш класс C ++ в делегат Objective-C (т.е. реализовать его наоборот). Таким образом можно было расположить вещи так, чтобы код Objective-C не касался кода C ++.

Изменить: На самом деле, я бы предпочел второе предложение. Вот пример:

DelegateClass.h:

class MyCPPClassHandlingStuff;

@interface MyDelegateObject : NSObject <SomeDelegateProtocol> {
  MyCPPClassHandlingStuff *m_handlerInstance;
}

- (id) initWithCPPInstance:(MyCPPClassHandlingStuff*)cppInstance;

- (void) theDelegateProtocolMethod;

@end

DelegateClass.mm

#include "MyCPPClassHandlingStuff.h"

@implementation MyDelegateObject

- (id) initWithCPPInstance:(MyCPPClassHandlingStuff*)cppInstance
{
  self = [super init];
  if (self) {
    m_handlerInstance = cppInstance;
  }
  return self;
}

- (void) theDelegateProtocolMethod
{
  if (m_handlerInstance)
    m_handlerInstance->handleDelegateMethod();
}

@end

Ну и MyCPPClassHandlingStuff.h:

#ifndef __MyCPPClassHandlingStuff_H__
#define __MyCPPClassHandlingStuff_H__

class MyCPPClassHandlingStuff
{
public:
  MyCPPClassHandlingStuff();
  void handleDelegateMethod();
};

#endif /* __MyCPPClassHandlingStuff_H__ */

MyCPPClassHandlingStuff можно инициализировать из Objective-C, но вы не можете инициализировать какой-либо класс Objective-C из кода C ++ там. Если вам нужно использовать Objective-C в вашем коде C ++, вам придется скомпилировать его как Objective-C (т.е. использовать файл .mm). Я оставляю детали .cpp в качестве упражнения для читателя;)

Создайте класс Objective-C, чтобы удовлетворить протокол делегата, и делегируйте его вашему классу C ++. Проблема в том, что AppKit ожидает взаимодействия с объектами Objective-C, поэтому вам нужна прокладка для делегирования вашим объектам C ++. (Да, вы можете злоупотреблять во время выполнения, определяя указатель isa в своем классе C ++, чтобы сделать его несколько совместимым с объектами ObjC (до такой степени, что вы можете отправлять сообщения классам C ++), но не делайте этого. Это неприятно.)

Итак, сделайте прокладку, которая инициализируется вашим классом C ++, имеет это как ivar. Он должен реализовать интересующие вас методы делегата и передать их вашему классу C ++ понятным для него способом. Тада, готово.

Затем я подумал, что попробую продвинуть объявление класса objective-c (именно так я заставил работать другие объекты objective-c). однако это тоже не сработало - если я объявляю его как "class myClassName", я получаю сообщение об ошибке переопределения класса как другого типа символа (предположительно, класс C ++ против протокола objective-c).

Почему бы не объявить его как @class myClassName?

Есть полезная информация о том, как настроить заголовки, чтобы их можно было использовать как из ObjC, так и из C ++ в Могу ли я отделить основную функцию и классы C ++ от подпрограмм Objective-C и / или C при компиляции и компоновке?