XSLT 1.0 Преобразование строки с разделителями в набор узлов

У меня есть переменная $ colors, которая представляет собой строку

<xsl:variable name="colors" select="'red,green,blue,'" />

Мне нужна новая переменная $ colorElements, которая представляет собой набор узлов

<color>red</color>
<color>green</color>
<color>blue</color>

(Это верно? Может ли набор узлов не иметь корня?)

$colorElements никогда не будет выводиться напрямую. Мне это просто нужно как переменная списка.

XSLT 1.0 без расширений, кроме node-set().


xml xpath xslt xslt-1.0
person JPM    schedule 31.01.2012    source источник

Ответы (2)


arrow_upward
3
arrow_downward

Использовать:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl">
  <xsl:output method="xml" indent="yes"/>

  <xsl:variable name="colors" select="'red,green,blue,'" />

  <xsl:template match="/">

    <xsl:variable name="colorElements">
      <xsl:call-template name="split">
        <xsl:with-param name="pText" select="$colors"/>
      </xsl:call-template>
    </xsl:variable>

    <xsl:for-each select="msxsl:node-set($colorElements)">
      <xsl:copy-of select="color"/>
    </xsl:for-each>

  </xsl:template>

  <xsl:template name="split">
    <xsl:param name="pText"/>

    <xsl:variable name="separator">,</xsl:variable>

    <xsl:choose>
      <xsl:when test="string-length($pText) = 0"/>
      <xsl:when test="contains($pText, $separator)">
        <color>
          <xsl:value-of select="substring-before($pText, $separator)"/>
        </color>
        <xsl:call-template name="split">
          <xsl:with-param name="pText" select="substring-after($pText, $separator)"/>
        </xsl:call-template>
      </xsl:when>
      <xsl:otherwise>
        <color>
          <xsl:value-of select="$pText"/>
        </color>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

</xsl:stylesheet>
person Kirill Polishchuk    schedule 31.01.2012
comment
Почему test = string-length ($ pText), а не просто test = $ pText? - person JPM; 31.01.2012
comment
@JPM, я предоставил более стабильный шаблон. - person Kirill Polishchuk; 31.01.2012

arrow_upward
1
arrow_downward

Как насчет этого?:

<?xml version="1.0"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:xs="http://www.w3.org/2001/XMLSchema" 
                exclude-result-prefixes="xs">
 <xsl:output method="xml" indent="yes" encoding="utf-8" />
 <xsl:variable name="colors" select="'red,green,blue,'" />
 <xsl:template match="/" name="main">
  <csv-to-xml>
   <xsl:for-each select="tokenize($colors, ',')[position()!=last()]">
   <!-- The predicate is needed because of the extraneous comma
        at the end of the red,green,blue, list. -->
    <color><xsl:value-of select="." /></color>
   </xsl:for-each>
  </csv-to-xml>
 </xsl:template>
</xsl:stylesheet>
person Sean B. Durkin    schedule 02.02.2012
comment
Ах соз! Я только что заметил, что вы указали XSLT 1.0, поэтому мой ответ не годится. Я оставлю это для любопытных. Мне не разрешено отмечать свой ответ, поэтому, пожалуйста, опустите его. - person Sean B. Durkin; 02.02.2012
comment
На самом деле это полезно для XSLT 1.0, если у вас есть ExsltStrings. Просто замените функцию tokenize на Exslt.ExsltStrings:tokenize. (Я использую Umbraco, по умолчанию используется очень подробный префикс) - person Eden Townsend; 05.10.2012