Проверить, существует ли каталог или нет

Следующее должно работать:

INQUIRE (DIRECTORY=dir, EXIST=ex [, DIRSPEC=dirspec] [, ERR=label] [, IOSTAT=i-var] )

У меня нет ifort на этой машине, поэтому я не могу его проверить.

Приложение: опубликованный код изначально работает с gfortran. Оператор DIRECTORY работает с ifort, но не с gfortran.

И в случае дополнительной информации проверьте: http://software.intel.com/sites/products/documentation/hpc/compilerpro/en-us/fortran/win/compiler_f/lref_for/source_files/rfinquir.htm#rfinquir

Стандарт Fortran 95, 2003 и 2008 не указывает, как следует обращаться с каталогами. По моему опыту работы с Linux, gfortran обрабатывает их как файлы, а ifort — нет. Оператор directory является частной функцией ifort, и поэтому его следует избегать.

Самым безопасным было бы проверить наличие файла в указанном каталоге.

В большинстве случаев проверяют, существует ли каталог, чтобы что-то в него записать. Что я делаю, так это просто создаю каталог. Если он уже есть, то проблем нет.

     CALL system("mkdir video")
     CALL chdir("video")
     CALL getcwd(path)

Вот подпрограмма, которую я часто использую — она использует условное выражение, о котором вы спрашивали:

subroutine create_directory( newDirPath )
    ! Author:  Jess Vriesema
    ! Date:    Spring 2011
    ! Purpose: Creates a directory at ./newDirPath

    implicit none

    character(len=*), intent(in) :: newDirPath
    character(len=256)           :: mkdirCmd
    logical                      :: dirExists

    ! Check if the directory exists first
!   inquire( file=trim(newDirPath)//'/.', exist=dirExists )  ! Works with gfortran, but not ifort
    inquire( directory=newDirPath, exist=dirExists )         ! Works with ifort, but not gfortran


    if (dirExists) then
!      write (*,*) "Directory already exists: '"//trim(newDirPath)//"'"
    else
        mkdirCmd = 'mkdir -p '//trim(newDirPath)
        write(*,'(a)') "Creating new directory: '"//trim(mkdirCmd)//"'"
        call system( mkdirCmd )
    endif
end subroutine create_directory

В зависимости от того, какой компилятор вы используете, вам придется решить, какое из этих условий подходит именно вам.

К сожалению, у меня нет доступа к nagfor и я не знаю, как он работает с каталогами.

Вы можете использовать подпрограммы C для проверки файлов:

Сторона C (можно использовать ifort и gfortran на Win32 и Linux 32/64)

#include <stdlib.h>
#include <stdio.h>
#include <string.h>
#include <errno.h>
#include <sys/stat.h>
#if defined(_WIN32) && defined(__INTEL_COMPILER)
#  include "dirent_windows.h"
#else
#  include <dirent.h>
#endif

void file_info(const char*filename,int*mode,int*exist,int*time){
  int k;
  struct stat buf;
  k=stat(filename,&buf);
  if(k != 0) {
    *mode=0;
    *exist=0;
    *time=0;
  }else{
    *mode=buf.st_mode;
    if(*mode == 0) *exist=0; else *exist=1;
    *time=buf.st_mtime;
  }
}

Фортран сторона:

MODULE file

  USE iso_c_binding

  INTERFACE
    SUBROUTINE file_info(filename,mode,exist,time) BIND(C,name="file_info")
      USE iso_c_binding
      CHARACTER(kind=C_CHAR),INTENT(in) :: filename(*)
      INTEGER(C_INT),INTENT(out) :: mode,exist,time
    END SUBROUTINE
  END INTERFACE

END MODULE

Как использовать в подпрограмме Fortran:

..
use file
use iso_c_binding
...
integer(c_int) :: mode,exist,time
...
call file_info("./docs"//char(0),mode,exist,time)

Преимущество: он работает для любого типа файлов и предоставляет дополнительную информацию, такую ​​как режим (разрешение на чтение/запись/выполнение) и время создания.

Еще одно непереносимое решение — позволить оболочке (в данном случае Bash) выполнять всю работу:

call system('[[ ! -e docs ]] && mkdir docs')

У меня такая же проблема. Если вам нужен независимый от компилятора способ сделать это, вы можете попробовать открыть небольшой файл в каталоге. Оператор open позволяет коду перейти к определенной строке (указанной err=), если оператор open терпит неудачу:

! Tests whether the directory exists
subroutine checkdir(dir)
       implicit none
       character(len=*), intent(in) :: dir
       integer :: unitno

       ! Test whether the directory exists
       open(newunit=unitno,file=trim(dir)//'deleteme.txt',status='replace',err=1234)
       close (unitno)
       return

       ! If doesn't exist, end gracefully
1234   write(*,*) 'Data directory, '//trim(dir)//' does not exist or could not write there!'
       STOP

end subroutine

Обратите внимание, что это не является надежным, поскольку предполагается, что «dir» имеет завершающий «/» или «\» в зависимости от используемой ОС.