Как мога да задам цвят на прозрачност за импортирано изображение в AS2

Забележка: Това е отговор в ActionScript 3, в случай че решите да мигрирате към ActionScript 3, но повече за други хора и обща информация.

Можете да създадете нов BitmapData от източника BitmapData с премахнати черни пиксели (преобразувани в алфа канал).

Създадох тази функция за вас:

// Takes a source BitmapData and converts it to a new BitmapData, ignoring
// dark pixels below the specified sensitivity.
function removeDarkness(source:BitmapData, sensitivity:uint = 10000):BitmapData
{
    // Define new BitmapData, with some size constraints to ensure the loop
    // doesn't time out / crash.
    // This is for demonstration only, consider creating a class that manages
    // portions of the BitmapData at a time (up to say 50,000 iterations per
    // frame) and then dispatches an event with the new BitmapData when done.
    var fresh:BitmapData = new BitmapData(
        Math.min(600, source.width),
        Math.min(400, source.height),
        true, 0xFFFFFFFF
    );

    fresh.lock();

    // Remove listed colors.
    for(var v:int = 0; v < fresh.height; v++)
    {
        for(var h:int = 0; h < fresh.width; h++)
        {
            // Select relevant pixel for this iteration.
            var pixel:uint = source.getPixel(h, v);

            // Check against colors to remove.
            if(pixel <= sensitivity)
            {
                // Match - delete pixel (fill with transparent pixel).
                fresh.setPixel32(h, v, 0x00000000);

                continue;
            }

            // No match, fill with expected color.
            fresh.setPixel(h, v, pixel);
        }
    }


    // We're done modifying the new BitmapData.
    fresh.unlock();


    return fresh;
}

Както можете да видите, това отнема:

• BitmapData, от които искате да премахнете по-тъмните пиксели.
• uint представлява колко нюанса на черно/сиво искате да премахнете.

И ето демонстрация, използваща вашето изходно изображение:

var original:Loader = new Loader();
original.load( new URLRequest("http://j.imagehost.org/0829/WoodyGX_0.jpg") );
original.contentLoaderInfo.addEventListener(Event.COMPLETE, imageLoaded);


// Original image has loaded, continue.
function imageLoaded(e:Event):void
{
    // Capture pixels from loaded Bitmap.
    var obmd:BitmapData = new BitmapData(original.width, original.height, false, 0);
    obmd.draw(original);


    // Create new BitmapData without black pixels.
    var heroSheet:BitmapData = removeDarkness(obmd, 1200000);
    addChild( new Bitmap(heroSheet) );
}

Вероятно е по-добре в този момент просто да го пренесете във Fireworks, да използвате магическата пръчка, за да изберете черните пиксели, да ги изтриете и да го запишете като прозрачен png. Тогава използвайте това.

Въпреки това, ако искате да направите живота си по-труден, отколкото трябва, потенциално можете да използвате getPixel, за да получите всичките си черни пиксели и след това да използвате setPixel, за да ги настроите на прозрачни. Но целият смисъл на блитинга е скоростта, а не бавните операции пиксел по пиксел.