Създайте атрибут xmlns в XML с помощта на XSLT трансформация

Първо, в XSLT модела на данни вие не искате да създадете възел на атрибут, а искате да създадете възел на пространство от имена.

Възлите на пространството от имена обикновено се създават автоматично: ако създадете елемент или атрибут в конкретно пространство от имена, необходимият възел от пространство от имена (и следователно, когато се сериализира, декларацията за пространство от имена) се добавят автоматично от процесора.

Ако искате да създадете възел на пространство от имена, който не е необходим (защото не се използва в името на който и да е елемент или атрибут), тогава в XSLT 2.0 можете да използвате xsl:namespace. Ако сте останали с XSLT 1.0, тогава има заобиколно решение, което включва създаване на елемент в съответното пространство от имена и след това копиране на неговия възел от пространство от имена:

<xsl:variable name="ns">
  <xsl:element name="neil:dummy" namespace="{$param}"/>
</xsl:variable>
<process>
  <xsl:copy-of select="$ns/*/namespace::neil"/>
</process>

Майкъл Кей ви даде правилния отговор, но въз основа на вашите коментари не сте сигурни как да го използвате във вашата трансформация.

Ето пълна трансформация:

 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common" exclude-result-prefixes="ext">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:param name="pNamespace" select="'neilghosh.com'"/>

 <xsl:variable name="vDummy">
   <xsl:element name="neil:x" namespace="{$pNamespace}"/>
 </xsl:variable>

 <xsl:template match="/*">
  <xsl:element name="process" namespace="http://example.com">
    <xsl:copy-of select="namespace::*"/>
    <xsl:copy-of select="ext:node-set($vDummy)/*/namespace::*[.=$pNamespace]"/>
  </xsl:element>
 </xsl:template>
 </xsl:stylesheet>

Когато тази трансформация се приложи към предоставения XML документ:

<test/>

желаният правилен резултат се получава:

<process xmlns="http://example.com" xmlns:neil="neilghosh.com" />

Декларациите за пространство на имена в XML не са атрибути, въпреки че изглеждат като атрибути. В XSLT 2.0 можете да използвате <xsl:namespace name="neil" select="$myNameSpace" /> за динамично добавяне на декларация за пространство от имена към резултантното дърво, но тази функция не е налична в XSLT 1.0.

Не се опитвайте сами да създавате атрибути "xmlns". Създайте пространствата от имена в XSLT и те ще бъдат направени автоматично. Този XSLT работи (тестван със Saxon 9.4):

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:neil="neilghosh.com"    
xpath-default-namespace="http://example.com"
xmlns="http://example.com" version="2.0">

<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:param name="myDynamicNamespace" select="'http://neilghosh.com'"/>

<xsl:template match="/">
    <xsl:element name="process">   
        <xsl:namespace name="neil" select="$myDynamicNamespace"/>
    </xsl:element>
</xsl:template>
</xsl:stylesheet>

И дава следния резултат:

<?xml version="1.0" encoding="UTF-8"?>
<process xmlns="http://example.com" xmlns:neil="http://neilghosh.com"/>

Най-накрая получих заобиколно решение, което работи с моя XSLT процесор (Oracle XML V2 Parser)

Трябваше да да го трансформирам в DOM документ и след това да запазя този DOM в файлова система, вместо да извежда директно към StreamResult

Използвах DOMResult в метод на трансформация

Следващият XSLT фрагмент работи, но имаше допълнителен xmlns:xmlns="http://www.w3.org/2000/xmlns/", който вероятно беше погълнат от Документ и не се появи в крайния изход, когато продължих към файловата система.

 <process>    
      <xsl:attribute name="xmlns">
        <xsl:value-of select="'http://example.com'"/>
      </xsl:attribute> 
 <process>

Знам, че това не е най-добрият начин, но като се има предвид ограничението за анализ, това е единственият избор, който имам сега.