Правилно третиране на катастрофални грешки

За да извършите необичайно прекъсване, извикайте Halt(), предавайки изходния код.

if CatastropicErrorDetected then
begin
  ... show error message
  Halt(1);
end;

В Windows това води до извикване на TerminateProcess и ще спре изпълнението там и тогава .

Забелязвате, че не се извършва почистване и обикновено това е, което искате. Тъй като извършвате тази проверка при стартиране на приложението, не трябва да има нищо за почистване.

IMHO единственият чист начин би бил проверката за „Фатални условия“, преди приложението да се стартира.

program Project2;

uses
  Forms,Dialogs,
  Unit1 in 'Unit1.pas' {Form1};

{$R *.res}

begin
  ReportMemoryLeaksOnShutDown := true;
  Application.Initialize;
  if True then // your condition here
    begin
      MessageDLG('Fatal Error',mtError,[mbok],0);
    end
  else
    begin
      Application.CreateForm(TForm1, Form1);
      Application.Run;
    end;
end.

Всеки друг подход ще има странични ефекти

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
  private
    { Private-Deklarationen }
    FSL:TStringList;
  public
   Destructor Destroy;override;
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

destructor TForm1.Destroy;
begin
  FreeAndNil(FSL);
  Showmessage('Will never be seen with Application.Terminate + HALT');
  inherited;
end;

procedure TForm1.FormCreate(Sender: TObject);
const
  Testing=0; // try 1 and 2 too
begin

   FSL:=TStringList.Create;
   Try
      raise Exception.Create('Terminating now');
   except
     case Testing of
         0: begin
             // exception object will not be freed other code will be prevented, Form won't be shown
             Application.Terminate;
             HALT;
            end;
         1: begin
             // exception object will not be freed Form won't be shown
             HALT;
            end;
         2: begin
             // clean but Form will be shown
             Application.Terminate;
            end;

     end;
   end;

end;

end.

Можете да инструктирате глобалния обект на приложението да прекрати програмата, като извикате Application.Terminate< /a>.

Тъй като извикването може да се случи по-дълбоко в стека, можете също да повдигнете изключение, и вие кодирате програмата си така, че да не я обработва, за да позволите на изпълнението да достигне до главния цикъл на приложението и манипулаторът на изключение по подразбиране да го улови.

По този начин вие ефективно предотвратявате изпълнението на повече код във вашето приложение.

В кода може да изглежда така:

if not FileExists(FilePath1) then
  begin
    MessageDlg(FilePath1 + ' does not exist and is required for this program to function.',
               mtWarning, [mbOK], 0);

    Application.Terminate;
    Abort;  //raising a EAbort just as an example
  end;

В зависимост от това къде се извиква този код, съветвам ви да не показвате съобщението директно, а по-скоро да предизвикате изключение със съобщението и да оставите метода HandleException по подразбиране на обекта на приложението да покаже съобщението вместо вас:

if not FileExists(FilePath1) then
  begin
    Application.Terminate;
    raise EMyFatalException.Create(FilePath1 
      + ' does not exist and is required for this program to function.');
  end;

Което ми изглежда по-естествено. EMyFatalException е хипотетичен клас изключение, който можете да декларирате и никога да не обработвате във вашите клаузи за изключение.

Можете да напишете свой собствен Application.OnException манипулатор, например:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    procedure HandleException(Sender: TObject; E: Exception);
  end;

var
  Form1: TForm1;

type
  EMyFatalError = class(Exception);

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
begin
  Application.OnException:= HandleException;
  raise EMyFatalError.Create('OOPS!');
end;

procedure TForm1.HandleException(Sender: TObject; E: Exception);
begin
  Application.ShowException(E);
  if E is EMyFatalError then
    Application.Terminate;
end;

end.