Основен преобразувател от двоично към осмично

Обикновено бих използвал низове или масиви от знаци и битова аритметика за такива преобразувания. Например:

function Int2Oct(invalue: integer): ShortString;
  const
    tt: array[0..7] of char = ('0', '1', '2', '3', '4', '5', '6', '7');
  var
    tempval: integer;
  begin
    Result := '';
    tempval := invalue;
    if tempval = 0 then
      Result := '0'
    else
      while (tempval <> 0) do
        begin
          Result := tt[(tempval and $7)] + Result;
          tempval := (tempval shr 3);
        end;
  end;

Изглежда, че работи за краткото време, през което го тествах, стига да не очаквате да обработва отрицателни числа. Редактиране: Сега обработва нула.

Ето една функция, която работи донякъде като функцията itoa на библиотеката за изпълнение на C, преобразувайки стойност на положително цяло число (Cardinal в Delphi) в определен радикс между 2 и 36. Тя е тествана под Delphi 2007 и XE4.

type
  TRadixRange = 2..36;

function ConvertIntToBase(value : Cardinal; Radix : TRadixRange) : string;
const
  Digits: array[0..35] of Char = ('0', '1', '2', '3',
                                  '4', '5', '6', '7',
                                  '8', '9', 'A', 'B',
                                  'C', 'D', 'E', 'F',
                                  'G', 'H', 'I', 'J',
                                  'K', 'L', 'M', 'N',
                                  'O', 'P', 'Q', 'R',
                                  'S', 'T', 'U', 'V',
                                  'W', 'X', 'Y', 'Z');
var
  nIndex : Integer;
begin
  Result := '';
  repeat
    nIndex := value mod radix;
    Result := Digits[nIndex] + Result;
    Value := Value div radix;
  until Value = 0;
end;

Просто за забавление реших да напиша функция за "отмяна" на преобразуването (преобразуване от друга основа обратно в десетична (база 10)). Също така е моделиран (много свободно) след функцията C RTL atoi, с изключение на това, че изисква да подадете основата на предаваното число.

function ConvertBaseToInt(const Value: string; const Radix: TRadixRange): Cardinal;
var
  i: Integer;
  Increment: Byte;
begin
  Result := 0;
  for i := 1 to Length(Value) do
  begin
    case Value[i] of
      '0'..'9': Increment := Ord(Value[i]) - Ord('0');
      'A'..'Z',
      'a'..'z': Increment := Ord(Value[i]) - Ord('A') + 10;
    else
      Increment := 0;
    end;
  end;
  Result := Result * Radix + Increment;
end;

Обърнете внимание, че ConvertIntToBase беше тестван с много цифрови входове, но мога да валидирам само тези бази, поддържани от калкулатора на Windows в режим на програмист (двоичен (база 2), осмичен (база 8), десетичен (база 10, която не тествах) и шестнадесетичен (база 16)), тъй като нямам калкулатор, който да поддържа други стойности на радикса и не исках да върша работата на ръка. ;-)

ConvertBaseToInt беше тестван чрез предаване на тестовите стойности на ConvertIntToBase и потвърждаване, че това, което влезе в едното, е това, което се върна от другото; IOW, че число, преобразувано в двоично от ConvertIntToBase, ще доведе до същото число, когато се върне обратно през ConvertBaseToInt.

Можете да го тествате с нещо подобно на това в конзолно приложение:

var
  TempStr: string;
  Reversed: Integer;
  i: Integer;
  Base: Byte;
const
  FmtStr = 'Value (base %d): %d  %s and back %d';
begin
  for i := 0 to 16 do
  begin
    for Base in [2, 8, 16] do  
    begin
      // Test bin, oct, and hex for a range of values from 0..65536
      TempStr := ConvertIntToBase(1 shl i, Base);
      Reversed := ConvertBaseToInt(TempStr, Base);
      Writeln(Format(FmtStr, [Base, 1 shl i, TempStr, Reversed]));
    end;
  end;
  Readln;
end.

program project1;

uses
    SysUtils, StrUtils;

begin
    // StrToInt function supports constants syntax: 
    // & - octal notation
    // $ - hexadecimal notation
    // % - binary notation
    Writeln(StrToInt('123'));
    Writeln(StrToInt('&173'))
    Writeln(StrToInt('$7B'));
    Writeln(StrToInt('%01111011'));

    // There are three functions for converting integer value to decimal, hexadecimal and binary notation
    Writeln(IntToStr(123));
    Writeln(IntToHex(123, 2));
    Writeln(intToBin(123, 8));

    Readln;
end.

За други бази отговорът на Кен Уайт е много полезен.

Но в модула StrUtils такива функции вече съществуват:

Dec2Numb
Synopsis: Convert a decimal number to a string representation, using given a base.
Declaration: function Dec2Numb(N: LongInt;Len: Byte;Base: Byte) : string
Visibility: default
Description: Dec2Numb converts N to its representation using base Base. The resulting string is left-padded
with zeroes till it has length Len. Base must be in the range 2-36 to be meaningful, but no checking
on this is performed.
Errors: If Base is out of range, the resulting string will contain unreadable (non-alphanumeric) characters.


Numb2Dec
Synopsis: Converts a string representation of a number to its numerical value, given a certain base.
Declaration: function Numb2Dec(S: string;Base: Byte) : LongInt
Visibility: default
Description: Numb2Dec converts the number in string S to a decimal value. It assumes the number is represented
using Base as the base. No checking is performed to see whether S contains a valid number using
base Base.
Errors: None.