Как да тествам за текстове, които не отговарят на граматика на Instaparse (Clojure)?

Написах проект за анализиране на низове, използвайки контекстно-свободна граматика в Instaparse (Clojure). Сега бих искал да тествам няколко входни низа за техните резултати от анализ. Някои входни низове може да не се вписват в граматиката. Досега тествах само за "анализирани низове, които не отговарят на очакванията". Но мисля, че би било по-точно да се тества за изключения с помощта на (is (thrown? ...)). Има ли изключения? Струва ми се, че се генерира някакъв изход (съдържащ Parse error...), но не се хвърля изключение.

Моят project.clj е:

(defproject com.stackoverflow.clojure/tests "0.1.0-SNAPSHOT"
  :description "Tests of Clojure test-framework."
  :url "http://example.com/FIXME"
  :license {:name "Eclipse Public License"
            :url "http://www.eclipse.org/legal/epl-v10.html"}
  :dependencies [[org.clojure/clojure "1.6.0"]
                 [instaparse "1.3.4"]])

Моят основен източник е:

(ns com.stackoverflow.clojure.testInstaparseWrongGrammar
  (:require [instaparse.core :as insta]))

(def parser (insta/parser "
    <sentence> = words <DOT>
    DOT        = '.'
    <words>    = word (<SPACE> word)*
    SPACE      = ' '
    word     = #'(?U)\\w+'
"))

(defn formatter [expr] 
  (->> (parser expr)
       (insta/transform {:word identity})
       (apply str)))

Моят тестов източник е:

(ns com.stackoverflow.clojure.testInstaparseWrongGrammar-test
  (:require [clojure.test :refer :all]
            [com.stackoverflow.clojure.testInstaparseWrongGrammar :refer :all]))

(deftest parser-tests
  (is (= [[:word "Hello"] [:word "World"]] (parser "Hello World.")))
  (is (not (= [[:word "Hello"] [:word "World"]] (parser "Hello World?"))))
  ;(parser "Hello World?")     gives:
  ;
  ;Parse error at line 1, column 12:
  ;Hello World?
  ;           ^
  ;Expected one of:
  ;"." (followed by end-of-string)
  ;" "
)

(deftest formatter-tests
  (is (= "HelloWorld" (formatter "Hello World.")))
  (is (not (= "HelloWorld" (formatter "Hello World?"))))
  ;(formatter "Hello World?")     gives:
  ;"[:index 11][:reason [{:tag :string, :expecting \".\", :full true} {:tag :string, :expecting \" \"}]][:text \"Hello World?\"][:column 12][:line 1]"
)

; run the tests
(run-tests)

Как трябва да тествам за грешки (Тук: когато изречението не завършва с ., а с !)?


exception parsing clojure context-free-grammar instaparse
person Edward    schedule 13.10.2014    source източник

Отговори (1)


arrow_upward
6
arrow_downward

Instaparse не хвърля изключение при грешка при анализ; вместо това връща „неуспешен обект“ (справка: грешки при анализиране). Можете да тествате за неуспешен обект с (insta/failure? result).

Ако искате вашият парсер/форматър да хвърля изключение при неочакван вход, добавете това към ядрото си:

(ns com.stackoverflow.clojure.testInstaparseWrongGrammar
  (:require [instaparse.core :as insta])
  (:require [instaparse.failure :as fail]))

(def raw-parser (insta/parser "
    <sentence> = words <DOT>
    DOT        = '.'
    <words>    = word (<SPACE> word)*
    SPACE      = ' '
    word     = #'(?U)\\w+'
"))

; pretty-print a failure as a string
(defn- failure->string [result]
  (with-out-str (fail/pprint-failure result)))

; create an Exception with the pretty-printed failure message
(defn- failure->exn [result]
  (Exception. (failure->string result)))  

(defn parser [expr]
  (let [result (raw-parser expr)]
    (if (insta/failure? result)
      (throw (failure->exn result))
      result)))

(defn formatter [expr]
  (->> (parser expr)
       (insta/transform {:word identity})
       (apply str)))

...и сега можете да използвате (is (thrown? ...)) в теста:

(deftest parser-tests
  (is (= [[:word "Hello"] [:word "World"]] (parser "Hello World.")))
  (is (thrown? Exception (= [[:word "Hello"] [:word "World"]] (parser "Hello World?"))))

Този подход използва instaparse за красиво отпечатване на грешката и обгръща това в изключение. Друг подход е да използвате ex-info, както е посочено в този отговор.

person lnmx    schedule 13.10.2014
comment
Как да получа информацията от неуспешния обект? Като начало бих искал да направя две неща (ако е възможно). Първо: Добавете номера на реда към моя метод за изключение. Второ: Добавяне на добре форматирано съобщение за грешка към моето изключение. Освен това, за създаването на нов клас Exception изглежда най-лесният начин да се имплементира в Java - така ли е? - person Edward; 14.10.2014
comment
... и какво точно имаш предвид под failure object. Мислех, че в Clojure няма обекти (с методи и променливи). И така, как мога (като цяло) да получа достъп до методи и променливи на тези обекти? - person Edward; 14.10.2014
comment
@Edward кодът по-горе сега включва текстово описание на грешката при анализ (ред, колона и т.н.) в изключението. Обектът на грешка е карта (технически record, създадена от defrecord), която има някои добре известни ключове; например номерът на ред може да бъде достъпен с (:line result). - person lnmx; 14.10.2014