Awk итерация на масиви за многомерни масиви

AWK фалшифицира многомерни масиви чрез конкатенация на индексите със знака, съдържащ се в променливата SUBSEP (0x1c). Можете да итерирате през двуизмерен масив, като използвате split по този начин (въз основа на пример във файла info gawk):

awk 'BEGIN { OFS=","; array[1,2]=3; array[2,3]=5; array[3,4]=8; 
  for (comb in array) {split(comb,sep,SUBSEP);
    print sep[1], sep[2], array[sep[1],sep[2]]}}'

Изход:

2,3,5
3,4,8
1,2,3

Можете обаче да обхождате числено индексиран масив, като използвате вложени цикли for:

for (i = 1; i <= width; i++)
    for (j = 1; j < = height; j++)
        print array[i, j]

Друга забележителна информация от ръководството на GAWK:

За да проверите дали определена индексна последователност съществува в многомерен масив, използвайте същия оператор (in), който се използва за едномерни масиви. Запишете цялата последователност от индекси в скоби, разделени със запетаи, като ляв операнд:

     (subscript1, subscript2, ...) in array

Gawk 4 добавя масиви от масиви. От този линк:

for (i in array) {
    if (isarray(array[i])) {
        for (j in array[i]) {
            print array[i][j]
        }
    }
    else
        print array[i]
}

Вижте също Преминаване на масиви от масиви за информация относно следната функция, която обхожда произволно оразмерен масив от масиви, включително назъбени:

function walk_array(arr, name,      i)
{
    for (i in arr) {
        if (isarray(arr[i]))
            walk_array(arr[i], (name "[" i "]"))
        else
            printf("%s[%s] = %s\n", name, i, arr[i])
    }
} 

Не, синтаксисът

for(index1 in arr2) for(index2 in arr2) {
    print arr2[index1][index2];
}

няма да работи. Awk не поддържа наистина многоизмерни масиви. Какво прави, ако направите нещо подобно

x[1,2] = 5;

е да свържете двата индекса (1 и 2), за да направите низ, разделен от стойността на променливата SUBSEP. Ако това е равно на "*", тогава ще имате същия ефект като

x["1*2"] = 5;

Стойността по подразбиране на SUBSEP е непечатаем знак, съответстващ на Ctrl+\. Можете да видите това със следния скрипт:

BEGIN {
    x[1,2]=5;
    x[2,4]=7;
    for (ix in x) {
        print ix;
    }
}

Изпълнението на това дава:

% awk -f scriptfile | cat -v
1^\2
2^\4

И така, в отговор на вашия въпрос - как да итерирате многоизмерен масив - просто използвайте един цикъл for(a in b), но може да се нуждаете от допълнителна работа, за да разделите a на неговите x и y части.

Настоящите версии на gawk (gnu awk, по подразбиране в linux и е възможно да се инсталира навсякъде, където пожелаете), има реални многоизмерни масиви.

for(b in a)
   for(c in a[b])
      print a[b][c], c , b

Вижте също функция isarray()

Ще дам пример за това как използвам това в работата си, обработвайки данни от заявки. Да предположим, че имате извлечен файл, пълен с транзакции по продуктова категория и идентификатор на клиента:

customer_id  category  sales
1111         parts     100.01
1212         parts       5.20
2211         screws      1.33
...etc...

Неговият лесен за използване awk за преброяване на всички различни клиенти с покупка:

awk 'NR>1 {a[$1]++} END {for (i in a) total++; print "customers: " total}' \ 
datafile.txt

Въпреки това, изчисляването на броя на отделните клиенти с покупка във всяка категория предполага двуизмерен масив:

awk 'NR>1 {a[$2,$1]++} 
      END {for (i in a) {split(i,arr,SUBSEP); custs[arr[1]]++}
           for (k in custs) printf "category: %s customers:%d\n", k, custs[k]}' \
datafile.txt

Увеличаването на custs[arr[1]]++ работи, защото всяка двойка категория/customer_id е уникална като индекс към асоциативния масив, използван от awk.

В интерес на истината, аз използвам gnu awk, който е по-бърз и може да направи array[i][j] както спомена Д. Уилямсън. Но исках да съм сигурен, че мога да направя това в стандартен awk.

awk(1) първоначално е проектиран -- отчасти -- да бъде учебен инструмент за езика C, а многомерните масиви са били както в C, така и в awk(1) почти завинаги. като такива POSIX IEEE 1003.2 ги стандартизира.

За да изследвате синтаксиса и семантиката, ако създадете следния файл, наречен "test.awk":

BEGIN {
  KEY["a"]="a";
  KEY["b"]="b";
  KEY["c"]="c";
  MULTI["a"]["test_a"]="date a";
  MULTI["b"]["test_b"]="dbte b";
  MULTI["c"]["test_c"]="dcte c";
}
END {
  for(k in KEY) {
    kk="test_" k ;
    print MULTI[k][kk]
  }
  for(q in MULTI) {
    print q
  }
  for(p in MULTI) {
    for( pp in MULTI[p] ) {
      print MULTI[p][pp]
    }
  }
}

и го стартирайте с тази команда:

awk -f test.awk /dev/null

ще получите следния изход:

date a
dbte b
dcte c
a
b
c
date a
dbte b
dcte c

поне на Linux Mint 18 Cinnamon 64-bit 4.4.0-21-generic #37-Ubuntu SMP