Как да нулирам $.?

Знам, че $. показва номера на реда, когато $/ е зададено на "\n".

Исках да емулирам командата Unix tail в Perl и да отпечатам последните 10 реда от файл, но $. не работи. Ако файлът съдържа 14 реда, той започва от 15 в следващия цикъл.

#!/usr/bin/perl
use strict;
use warnings;

my $i;

open my $fh, '<', $ARGV[0] or die "unable to open file $ARGV[0] :$! \n";
do { local $.; $i = $. } while (<$fh>);
seek $fh, 0, 0;

if ($i > 10) {
    $i = $i - 10;
    print "$i \n";
    while (<$fh>) {

        #local $.;# tried doesn't work
        #undef $.; #tried doesn't work

        print "$. $_" if ($. > $i);
    }
}
else {
    print "$_" while (<$fh>);
}

close($fh);

Искам да нулирам $., за да може да се използва полезно в следващия цикъл.


perl file-handling
person Arunesh Singh    schedule 10.06.2015    source източник
comment
Не отговор на въпроса ви, а алтернативно решение на първоначалния ви проблем. За да отпечатате последните десет реда, можете да използвате това: perl -nle 'push @tail, $_; shift @tail if @tail > 10; END {print foreach (@tail)}' input.txt   -  person Dmitry Egorov    schedule 10.06.2015
comment
Тази дискусия може да ви помогне: stackoverflow.com/questions/6036244/   -  person chipou    schedule 10.06.2015
comment
Ето друга реализация на tail в Perl 5: metacpan.org/source/ BDFOY/PerlPowerTools-1.006/bin/tail#L142   -  person dolmen    schedule 10.06.2015

Отговори (2)


arrow_upward
5
arrow_downward

Използването на local с $. прави нещо друго, отколкото си мислите:

Локализиране на $. няма да локализира броя на редовете на манипулатора на файла. Вместо това ще локализира представата на perl за това кой файлов манипулатор $. в момента е свързан с.

$. не е само за четене, може да се присвои нормално.

1 while <$fh>;
my $i = $.;
seek $fh, $. = 0, 0;
person choroba    schedule 10.06.2015
comment
но можем да използваме local за $/, за да зададем стойността му, но за $. защо не можем да използваме местни? - person Arunesh Singh; 10.06.2015
comment
@ArruneshSingh: Вижте $. в perlvar. Цитатът е от там. - person choroba; 10.06.2015

arrow_upward
0
arrow_downward

Трябва да отворите отново манипулатора на файла. В противен случай, както установихте, номерът на реда просто продължава да се увеличава

#!/usr/bin/perl
use strict;
use warnings;

my ($filename) = @ARGV;

my $num_lines;
open my $fh, '<', $filename or die qq{Unable to open file "$filename" for input: $!\n};
++$num_lines while <$fh>;

open $fh, '<', $filename or die qq{Unable to open file "$filename" for input: $!\n};

print "$num_lines lines\n";
while ( <$fh> ) {
    print "$. $_" if $. > $num_lines - 10;
}

Ето един по-спретнат начин

#!/usr/bin/perl
use strict;
use warnings;

my ($filename) = @ARGV;

my @lines;
open my $fh, '<', $filename or die qq{Unable to open file "$filename" for input: $!\n};

while ( <$fh> ) {
  push @lines, $_;
  shift @lines while @lines > 10;
}

print @lines;
person Borodin    schedule 10.06.2015