xml - xslt - трансформира избран елемент в атрибут

Опитвам се да трансформирам XML документ в нов, където единственият от елементите се трансформира в атрибут и запазва останалата част от дървото на документа по същия начин... Ето XML документа

    <?xml version="1.0" encoding="UTF-8"?>
    <cities>
    <city>
        <cityID>c1</cityID>
        <cityName>Atlanta</cityName>
        <cityCountry>USA</cityCountry>
        <cityPop>4000000</cityPop>
        <cityHostYr>1996</cityHostYr>   

    </city>

    <city>
        <cityID>c2</cityID>
        <cityName>Sydney</cityName>
        <cityCountry>Australia</cityCountry>
        <cityPop>4000000</cityPop>
        <cityHostYr>2000</cityHostYr>   
        <cityPreviousHost>c1</cityPreviousHost >   
    </city>

    <city>
        <cityID>c3</cityID>
        <cityName>Athens</cityName>
        <cityCountry>Greece</cityCountry>
        <cityPop>3500000</cityPop>
        <cityHostYr>2004</cityHostYr>   
        <cityPreviousHost>c2</cityPreviousHost >   
    </city>

    </cities>

Опитвам се да вкарам елемента „cityID“ в атрибут на „city“ и да запазя останалото. Ето моят .xsl досега. За съжаление изглежда, че губи останалите елементи:

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes" encoding="UTF-8"/>

    <xsl:template match="/">
        <cities>
            <xsl:apply-templates/>
        </cities>
    </xsl:template>


    <xsl:template match="city">
        <xsl:element name="city" use-attribute-sets="NameAttributes"/>
    </xsl:template>


    <xsl:attribute-set name="NameAttributes">
        <xsl:attribute name="cityID">
            <xsl:value-of select="cityID"/>
        </xsl:attribute>
    </xsl:attribute-set>

    <xsl:template match="/ | @* | node()">
         <xsl:copy>
             <xsl:apply-templates select="@* | node()" />
        </xsl:copy>
    </xsl:template>


</xsl:stylesheet>

xml xslt transform stylesheet elements
person Ivan M    schedule 03.01.2016    source източник

Отговори (3)


arrow_upward
0
arrow_downward

Бих използвал

<xsl:template match="city">
    <city cityID="{cityID}">
       <xsl:apply-templates select="node() except cityID"/> <!-- except is XSLT 2.0, use select="node()[not(self::cityID)]" for XSLT 1.0 -->
    </city>
</xsl:template>

или напишете шаблон за

<xsl:template match="cityID">
  <xsl:attribute name="{name()}" select="."/>
  <!-- XSLT 1.0 <xsl:attribute name="{name()}"><xsl:value-of select="."/></xsl:attribute> -->
</xsl:template>

Всички атрибути трябва да бъдат създадени преди дъщерни възли, така че използването на <xsl:strip-space elements="*"/> може да е необходимо, за да работи този подход.

И двете предложения предполагат наличието на шаблона за трансформация на идентичност, който имате.

person Martin Honnen    schedule 03.01.2016
comment
Този отговор е елегантен, но изисква XSLT 2. Изглежда, че оригиналният плакат използва XSLT 1. - person Elliotte Rusty Harold; 03.01.2016
comment
Отговорът споменава XSLT 1.0 алтернативи за тези XSLT/XPath 2.0 конструкции. - person Martin Honnen; 03.01.2016
comment
Благодаря, Мартин, страхотен отговор - всъщност използвам 1.0, но ти ми даде и правилното решение .... 10x Bro - person Ivan M; 03.01.2016

arrow_upward
0
arrow_downward

Шаблонът, който съответства на градския елемент, не обработва децата на този елемент. Заменете го със следното:

<xsl:template match="city">
    <xsl:element name="city" use-attribute-sets="NameAttributes">
      <xsl:apply-templates select="node()[name()!='cityID']" />
    </xsl:element>
</xsl:template>
person Elliotte Rusty Harold    schedule 03.01.2016
comment
благодаря Харолд, този го направи :) страхотно и най-вече просто, без да променя твърде много в кода - person Ivan M; 03.01.2016

arrow_upward
0
arrow_downward

Толкова просто като тази (пълна XSLT 1.0) трансформация:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="city">
    <city cityID="{cityID}">
      <xsl:apply-templates select="@*|node()"/>
    </city>
  </xsl:template>
  <xsl:template match="cityID"/>
</xsl:stylesheet>
person Dimitre Novatchev    schedule 03.01.2016