Как работи синтаксисът за използване на Perl?

Първо, прочетете perldoc perlmod.

Вие не декларирате пространство от имена в нито един модул, така че всичко е в пространството от имена main. Декларирайте package m1; в m1.pm и package m2; в m2.pm.

Най-малкото трябва да приложите import метод (или да наследите този, който Exporter предоставя), така че програмите, които използват модули, да могат да решат какво от къде да импортират.

Също така ми се струва, че изследвате около краищата на OO.

Освен това:

• Избягвайте да използвате $a и $b като имена на променливи, защото е лесно да ги объркате с пакетните променливи $a и $b, използвани от sort.

• Не използвайте малки имена на модули: Те са запазени за pragmata.

Минимално внедряване (всичко в един файл за удобство при тестване) изглежда така:

package My::M1;

use strict; use warnings;

sub new { my $class = shift; bless { @_ } => $class }

sub a {
    my $self = shift;
    my ($v) = @_;
    $self->{a} = $v if @_;
    return $self->{a};
}

sub b {
    my $self = shift;
    my ($v) = @_;
    $self->{b} = $v if @_;
    return $self->{b};
}

package My::M2;

use strict; use warnings;
use base 'My::M1';

sub printtab {
    my $self = shift;
    for my $x (qw(a b)) {
        printf "%s = -%s-\n", $x, $self->$x;
    }
}

package main;

my $m = My::M2->new(a => 'hello', 'b' => 'world');
$m->printtab;

В Perl ключовата дума use е точно еквивалентна на следното:

use Mymodule;

#is the same as

BEGIN {
   require Mymodule;
   Mymodule->import();
}

Така че, ако не дефинирате процедура за импортиране във вашия код (или наследявате от Exporter), тогава вашите модули не импортират нищо в test.pl

Както разбра Синан, вие не декларирате пакет във вашите модули, така че те са по подразбиране към пакета main. В този случай всичките ви подпрограми са в main, но лексикалните променливи (декларирани с my) са обхванати само от файла, в който са декларирани.

Така m1 дефинира sub init и sub printab, към които лексикалните $a и $b са в обхвата. Но когато test.pl зареди m2, рутината init се презаписва с новата дефиниция, която вече не е затворена около двата лексикала. Така че той записва в променливите на пакета $main::a и $main::b вместо в лексикалните, към които printab е обвързан.

Ако сте имали активирани предупреждения (което винаги трябва да правите, когато учите), щяхте да бъдете предупредени за предефинирането на подпрограмата.

Трябва да започнете всеки от вашите модули с:

package Some::Package::Name;
use warnings;
use strict;

и след това завършете всеки модул с:

1;

Това е така, защото когато use/require модул, той трябва да върне истинска стойност в края, така че Perl да знае, че е зареден правилно.

printab() е дефиниран във файла m1.pm и има достъп само до променливите $a и $b, които са обхванати от този файл. Променливите $a и $b в m2.pm са обхванати от този файл и те са различни променливи от $a и $b в m1.pm.

init() задава променливите с обхват в m2.pm (тъй като това е последното място, където е дефинирана функцията &init), така че не задава същите променливи, които printab() ще се опитва да отпечата.