EXCEL - Множество масиви във формулата COUNTIF

Опит за преброяване:

Именуван диапазон „СТАТУС“, ако стойността на клетките е равна на Резервирани, Блокирани, Чакащи ИЛИ Архив

И

Наименуван диапазон „КОМПАНИЯ“ е равен на Компания A, Компания B ИЛИ Компания C.

Отчитам и множество други критерии, всички от които работят. Когато добавих масива за компанията, формулата вече не отчита състоянието.

Ето формулата, която използвам:

=SUM((COUNTIFS(DATES,">="&A19,DATES,"<"&EDATE(A19,1),AGENT,"JOHN DOE",COMPANY,{"COMPANY A","COMPANY B","COMPANY C"},STATUS,{"Reserved","Blocked","Pending","Archive"})))

Всяка помощ е много ценена и ви благодаря предварително!


arrays excel countif excel-formula sum
person DimWSH    schedule 06.07.2017    source източник
comment
едно число ли сумираш? =SUM((3))   -  person Aprillion    schedule 06.07.2017
comment
Да, очаквам изходът да бъде едно число   -  person DimWSH    schedule 06.07.2017
comment
COUNTIFS вече връща едно число, няма нужда да го сумирате с нищо друго   -  person Aprillion    schedule 06.07.2017

Отговори (2)


arrow_upward
1
arrow_downward

Опитайте тази

=SUM((COUNTIFS(DATES,">="&A19,DATES,"<"&EDATE(A19,1),AGENT,"JOHN DOE",COMPANY,{"COMPANY A";"COMPANY B";"COMPANY C"},STATUS,{"Reserved","Blocked","Pending","Archive"})))

or 

=SUM((COUNTIFS(DATES,">="&A19,DATES,"<"&EDATE(A19,1),AGENT,"JOHN DOE",COMPANY,{"COMPANY A","COMPANY B","COMPANY C"},STATUS,{"Reserved";"Blocked";"Pending";"Archive"})))

Обърнете внимание на ; вместо , в масивите. За подробности защо да използвате точка и запетая вместо запетая вижте това.

Ако искате да използвате вашата формула, тя трябва да бъде както следва

=SUM((COUNTIFS(DATES,">="&A19,DATES,"<"&EDATE(A19,1),AGENT,"JOHN DOE",COMPANY,"COMPANY A",STATUS,{"Reserved","Blocked","Pending","Archive"}))) +
SUM((COUNTIFS(DATES,">="&A19,DATES,"<"&EDATE(A19,1),AGENT,"JOHN DOE",COMPANY,"COMPANY B",STATUS,{"Reserved","Blocked","Pending","Archive"}))) + 
SUM((COUNTIFS(DATES,">="&A19,DATES,"<"&EDATE(A19,1),AGENT,"JOHN DOE",COMPANY,"COMPANY C",STATUS,{"Reserved","Blocked","Pending","Archive"})))
person Mrig    schedule 07.07.2017
comment
Използвайки ; вместо , в масивите работи! Много благодаря - person DimWSH; 10.07.2017

arrow_upward
0
arrow_downward

можете да създадете допълнителна колона с всички условия, от които се нуждаете, сякаш вътре в условие IF, напр.

=(A2>=A19) * ((B2="COMPANY A") + (B2="COMPANY B")))

и след това =COUNTIF(ALL_CONDITIONS, ">0")

person Aprillion    schedule 06.07.2017
comment
Благодаря ви, това е добро решение, но се надявах да избегна всякакви странични колони. - person DimWSH; 06.07.2017