Обработка на последователност по двойки за сравняване на db таблици

Ето моето (напълно непроверено) представяне, което прави едно минаване през двете маси:

let findDifferences readerA readerB =
    let idsA, idsB =
        let getIds (reader:System.Data.Common.DbDataReader) =
            reader |> LazyList.unfold (fun reader ->
                if reader.Read ()
                then Some (reader.GetInt32 0, reader)
                else None)
        getIds readerA, getIds readerB

    let onlyInA, onlyInB = ResizeArray<_>(), ResizeArray<_>()
    let rec impl a b =
        let inline handleOnlyInA idA as' = onlyInA.Add idA; impl as' b
        let inline handleOnlyInB idB bs' = onlyInB.Add idB; impl a bs'
        match a, b with
        | LazyList.Cons (idA, as'), LazyList.Cons (idB, bs') ->
                if   idA < idB then handleOnlyInA idA as'
                elif idA > idB then handleOnlyInB idB bs'
                else impl as' bs'
        | LazyList.Nil, LazyList.Nil  -> () // termination condition
        | LazyList.Cons (idA, as'), _ -> handleOnlyInA idA as'
        | _, LazyList.Cons (idB, bs') -> handleOnlyInB idB bs'
    impl idsA idsB
    onlyInA.ToArray (), onlyInB.ToArray ()

Това отнема две DataReaders (по една за всяка таблица) и връща две int[]s, които показват идентификаторите, които присъстват само в съответната им таблица. Кодът предполага, че ID полето е от тип int и е на пореден индекс 0.

Също така имайте предвид, че този код използва LazyList от F# PowerPack, така че ще трябва да го получите, ако не вече го нямам. Ако се насочвате към .NET 4.0, тогава силно препоръчвам да вземете двоичните файлове на .NET 4.0, които създадох и хоствах тук, тъй като двоичните файлове от сайта на F# PowerPack са насочени само към .NET 2.0 и понякога не работят добре с VS2010 SP1 (вижте тази тема за повече информация: Проблем с F# Powerpack. Методът не е намерен грешка).

Когато използвате последователности, всяка мързелива функция добавя малко допълнителни разходи към последователността. Извикването на Seq.skip хиляди пъти на една и съща последователност очевидно ще бъде бавно.

Можете да използвате Seq.zip или Seq.map2 за обработка на две последователности едновременно:

> Seq.map2 (+) [1..3] [10..12];;
val it : seq<int> = seq [11; 13; 15]

Ако модулът Seq не е достатъчен, може да се наложи да напишете своя собствена функция. Не съм сигурен дали разбирам какво се опитвате да направите, но тази примерна функция може да ви помогне:

let fct (s1: seq<_>) (s2: seq<_>) =
    use e1 = s1.GetEnumerator()
    use e2 = s2.GetEnumerator()
    let rec walk () =

        // do some stuff with the element of both sequences
        printfn "%d %d" e1.Current e2.Current

        if cond1 then // move in both sequences
            if e1.MoveNext() && e2.MoveNext() then walk ()
            else () // end of a sequence

        elif cond2 then // move to the next element of s1
            if e1.MoveNext() then walk()
            else () // end of s1

        elif cond3 then // move to the next element of s2
            if e2.MoveNext() then walk ()
            else () // end of s2

    // we need at least one element in each sequence
    if e1.MoveNext() && e2.MoveNext() then walk()

Редактиране:

Предишната функция имаше за цел да разшири функционалността на модула Seq и вероятно ще искате да я направите функция от висок ред. Както каза ildjarn, използването на LazyList може да доведе до по-чист код:

let rec merge (l1: LazyList<_>) (l2: LazyList<_>) =
    match l1, l2 with
    | LazyList.Cons(h1, t1), LazyList.Cons(h2, t2) ->
        if h1 <= h2 then LazyList.cons h1 (merge t1 l2)
        else LazyList.cons h2 (merge l1 t2)
    | LazyList.Nil, l2 -> l2
    | _ -> l1

merge (LazyList.ofSeq [1; 4; 5; 7]) (LazyList.ofSeq [1; 2; 3; 6; 8; 9])

Но все пак смятам, че трябва да отделите итерацията на вашите данни от обработката. Писането на функция от висок ред за итериране е добра идея (в крайна сметка не е досадно, ако кодът на функцията на итератора използва променливи изброители).